[gentoo-commits] gentoo-x86 commit in kde-base/kwin: kwin-4.11.19.ebuild ChangeLog

["Michael Palimaka (kensington)" <kensington@gentoo.org>]

kensington    15/05/15 15:53:07

  Modified:             ChangeLog
  Added:                kwin-4.11.19.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.19/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

Revision  Changes    Path
1.403                kde-base/kwin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kwin/ChangeLog?rev=1.403&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kwin/ChangeLog?rev=1.403&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kwin/ChangeLog?r1=1.402&r2=1.403

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kwin/ChangeLog,v
retrieving revision 1.402
retrieving revision 1.403
diff -u -r1.402 -r1.403
--- ChangeLog	29 Mar 2015 11:33:07 -0000	1.402
+++ ChangeLog	15 May 2015 15:53:07 -0000	1.403
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kwin
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kwin/ChangeLog,v 1.402 2015/03/29 11:33:07 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kwin/ChangeLog,v 1.403 2015/05/15 15:53:07 kensington Exp $
+
+*kwin-4.11.19 (15 May 2015)
+
+  15 May 2015; Michael Palimaka <kensington@gentoo.org> +kwin-4.11.19.ebuild:
+  Version bump.
 
 *kwin-4.11.17 (29 Mar 2015)
 



1.1                  kde-base/kwin/kwin-4.11.19.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kwin/kwin-4.11.19.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/kde-base/kwin/kwin-4.11.19.ebuild?rev=1.1&content-type=text/plain

Index: kwin-4.11.19.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kwin/kwin-4.11.19.ebuild,v 1.1 2015/05/15 15:53:07 kensington Exp $

EAPI=5

KMNAME="kde-workspace"
DECLARATIVE_REQUIRED="always"
OPENGL_REQUIRED="always"

#VIRTUALX_REQUIRED=test
RESTRICT=test
# test 8: kwin-TestVirtualDesktops hangs even with virtualx

inherit flag-o-matic kde4-meta

DESCRIPTION="KDE window manager"
HOMEPAGE+=" http://userbase.kde.org/KWin"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug gles opengl wayland"

COMMONDEPEND="
	$(add_kdebase_dep kactivities)
	$(add_kdebase_dep kdelibs opengl)
	$(add_kdebase_dep kephal)
	$(add_kdebase_dep libkworkspace)
	$(add_kdebase_dep liboxygenstyle)
	x11-libs/libICE
	x11-libs/libSM
	x11-libs/libX11
	x11-libs/libxcb
	x11-libs/xcb-util-image
	x11-libs/xcb-util-keysyms
	x11-libs/libXcomposite
	x11-libs/libXcursor
	x11-libs/libXdamage
	x11-libs/libXext
	x11-libs/libXfixes
	>=x11-libs/libXrandr-1.2.1
	x11-libs/libXrender
	x11-libs/libXxf86vm
	opengl? ( >=media-libs/mesa-7.10 )
	gles? ( >=media-libs/mesa-7.12[egl(+),gles2] )
	wayland? ( >=media-libs/mesa-9.0[egl(+),wayland] )
"
DEPEND="${COMMONDEPEND}
	x11-libs/xcb-util-renderutil
	x11-proto/compositeproto
	x11-proto/damageproto
	x11-proto/fixesproto
	x11-proto/randrproto
	x11-proto/renderproto
"
RDEPEND="${COMMONDEPEND}
	x11-apps/scripts
"

KMEXTRACTONLY="
	ksmserver/
	libs/kephal/
	libs/oxygen/
"

# you need one of these
REQUIRED_USE="!opengl? ( gles ) !gles? ( opengl ) wayland? ( gles )"

src_configure() {
	# FIXME Remove when activity API moved away from libkworkspace
	append-cppflags "-I${EPREFIX}/usr/include/kworkspace"

	local mycmakeargs=(
		$(cmake-utils_use_with gles OpenGLES)
		$(cmake-utils_use gles KWIN_BUILD_WITH_OPENGLES)
		$(cmake-utils_use_with opengl OpenGL)
		$(cmake-utils_use_with wayland Wayland)
		-DWITH_X11_Xcomposite=ON
	)

	kde4-meta_src_configure
}