* [gentoo-commits] gentoo-x86 commit in media-libs/libsdl: libsdl-1.2.15-r9.ebuild ChangeLog
@ 2015-05-12 19:56 Michael Sterrett (mr_bones_)
0 siblings, 0 replies; only message in thread
From: Michael Sterrett (mr_bones_) @ 2015-05-12 19:56 UTC (permalink / raw
To: gentoo-commits
mr_bones_ 15/05/12 19:56:33
Modified: ChangeLog
Added: libsdl-1.2.15-r9.ebuild
Log:
add backported patch from upstream report by Rafał Mużyło via bug #499180 to fix input in some conditions
(Portage version: 2.2.18/cvs/Linux x86_64, unsigned Manifest commit)
Revision Changes Path
1.239 media-libs/libsdl/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libsdl/ChangeLog?rev=1.239&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libsdl/ChangeLog?rev=1.239&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libsdl/ChangeLog?r1=1.238&r2=1.239
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libsdl/ChangeLog,v
retrieving revision 1.238
retrieving revision 1.239
diff -u -r1.238 -r1.239
--- ChangeLog 31 Mar 2015 20:24:44 -0000 1.238
+++ ChangeLog 12 May 2015 19:56:33 -0000 1.239
@@ -1,6 +1,13 @@
# ChangeLog for media-libs/libsdl
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/ChangeLog,v 1.238 2015/03/31 20:24:44 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/ChangeLog,v 1.239 2015/05/12 19:56:33 mr_bones_ Exp $
+
+*libsdl-1.2.15-r9 (12 May 2015)
+
+ 12 May 2015; Michael Sterrett <mr_bones_@gentoo.org>
+ +files/libsdl-1.2.15-SDL_EnableUNICODE.patch, +libsdl-1.2.15-r9.ebuild:
+ add backported patch from upstream report by Rafał Mużyło via bug #499180 to
+ fix input in some conditions
31 Mar 2015; Michael Sterrett <mr_bones_@gentoo.org> metadata.xml:
clean unused ps3 use flag
1.1 media-libs/libsdl/libsdl-1.2.15-r9.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libsdl/libsdl-1.2.15-r9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libsdl/libsdl-1.2.15-r9.ebuild?rev=1.1&content-type=text/plain
Index: libsdl-1.2.15-r9.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libsdl/libsdl-1.2.15-r9.ebuild,v 1.1 2015/05/12 19:56:33 mr_bones_ Exp $
EAPI=5
inherit autotools flag-o-matic multilib toolchain-funcs eutils multilib-minimal
DESCRIPTION="Simple Direct Media Layer"
HOMEPAGE="http://www.libsdl.org/"
SRC_URI="http://www.libsdl.org/release/SDL-${PV}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
# WARNING:
# If you turn on the custom-cflags use flag in USE and something breaks,
# you pick up the pieces. Be prepared for bug reports to be marked INVALID.
IUSE="oss alsa nas X dga xv xinerama fbcon tslib aalib opengl libcaca +sound +video +joystick custom-cflags pulseaudio static-libs"
RDEPEND="
abi_x86_32? (
!app-emulation/emul-linux-x86-sdl[-abi_x86_32(-)]
!<=app-emulation/emul-linux-x86-sdl-20140406
)
sound? ( >=media-libs/audiofile-0.3.5[${MULTILIB_USEDEP}] )
alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
nas? (
>=media-libs/nas-1.9.4[${MULTILIB_USEDEP}]
>=x11-libs/libXt-1.1.4[${MULTILIB_USEDEP}]
>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
)
X? (
>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
)
aalib? ( >=media-libs/aalib-1.4_rc5-r6[${MULTILIB_USEDEP}] )
libcaca? ( >=media-libs/libcaca-0.99_beta18-r1[${MULTILIB_USEDEP}] )
opengl? (
>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
>=virtual/glu-9.0-r1[${MULTILIB_USEDEP}]
)
tslib? ( >=x11-libs/tslib-1.0-r3[${MULTILIB_USEDEP}] )
pulseaudio? ( >=media-sound/pulseaudio-2.1-r1[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
nas? (
>=x11-proto/xextproto-7.2.1-r1[${MULTILIB_USEDEP}]
>=x11-proto/xproto-7.0.24[${MULTILIB_USEDEP}]
)
X? (
>=x11-proto/xextproto-7.2.1-r1[${MULTILIB_USEDEP}]
>=x11-proto/xproto-7.0.24[${MULTILIB_USEDEP}]
)
x86? ( || ( >=dev-lang/yasm-0.6.0 >=dev-lang/nasm-0.98.39-r3 ) )"
S=${WORKDIR}/SDL-${PV}
pkg_setup() {
if use custom-cflags ; then
ewarn "Since you've chosen to use possibly unsafe CFLAGS,"
ewarn "don't bother filing libsdl-related bugs until trying to remerge"
ewarn "libsdl without the custom-cflags use flag in USE."
fi
}
src_prepare() {
epatch \
"${FILESDIR}"/${P}-sdl-config.patch \
"${FILESDIR}"/${P}-resizing.patch \
"${FILESDIR}"/${P}-joystick.patch \
"${FILESDIR}"/${P}-bsd-joystick.patch \
"${FILESDIR}"/${P}-gamma.patch \
"${FILESDIR}"/${P}-const-xdata32.patch \
"${FILESDIR}"/${P}-caca.patch \
"${FILESDIR}"/${P}-SDL_EnableUNICODE.patch
AT_M4DIR="/usr/share/aclocal acinclude" eautoreconf
}
multilib_src_configure() {
local myconf=
if use !x86 ; then
myconf="${myconf} --disable-nasm"
else
myconf="${myconf} --enable-nasm"
fi
use custom-cflags || strip-flags
use sound || myconf="${myconf} --disable-audio"
use video \
&& myconf="${myconf} --enable-video-dummy" \
|| myconf="${myconf} --disable-video"
use joystick || myconf="${myconf} --disable-joystick"
ECONF_SOURCE="${S}" econf \
--disable-rpath \
--disable-arts \
--disable-esd \
--enable-events \
--enable-cdrom \
--enable-threads \
--enable-timers \
--enable-file \
--enable-cpuinfo \
--disable-alsa-shared \
--disable-esd-shared \
--disable-pulseaudio-shared \
--disable-arts-shared \
--disable-nas-shared \
--disable-osmesa-shared \
$(use_enable oss) \
$(use_enable alsa) \
$(use_enable pulseaudio) \
$(use_enable nas) \
$(use_enable X video-x11) \
$(use_enable dga) \
$(use_enable xv video-x11-xv) \
$(use_enable xinerama video-x11-xinerama) \
$(use_enable X video-x11-xrandr) \
$(use_enable dga video-dga) \
$(use_enable fbcon video-fbcon) \
--disable-video-ggi \
--disable-video-svga \
$(use_enable aalib video-aalib) \
$(use_enable libcaca video-caca) \
$(use_enable opengl video-opengl) \
--disable-video-ps3 \
$(use_enable tslib input-tslib) \
$(use_with X x) \
$(use_enable static-libs static) \
--disable-video-x11-xme \
--disable-video-directfb \
${myconf}
}
multilib_src_install() {
emake DESTDIR="${D}" install
}
multilib_src_install_all() {
use static-libs || prune_libtool_files --all
dodoc BUGS CREDITS README README-SDL.txt README.HG TODO WhatsNew
dohtml -r ./
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-05-12 19:56 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-05-12 19:56 [gentoo-commits] gentoo-x86 commit in media-libs/libsdl: libsdl-1.2.15-r9.ebuild ChangeLog Michael Sterrett (mr_bones_)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox