[gentoo-commits] gentoo-x86 commit in games-board/scid: scid-4.6.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in games-board/scid: scid-4.6.0.ebuild ChangeLog

[Michael Sterrett (mr_bones_)]

mr_bones_    15/05/09 05:19:31

  Modified:             ChangeLog
  Added:                scid-4.6.0.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.18/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.48                 games-board/scid/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/scid/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/scid/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/scid/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-board/scid/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog	13 Nov 2014 17:13:53 -0000	1.47
+++ ChangeLog	9 May 2015 05:19:31 -0000	1.48
@@ -1,6 +1,12 @@
 # ChangeLog for games-board/scid
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-board/scid/ChangeLog,v 1.47 2014/11/13 17:13:53 mr_bones_ Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-board/scid/ChangeLog,v 1.48 2015/05/09 05:19:31 mr_bones_ Exp $
+
+*scid-4.6.0 (09 May 2015)
+
+  09 May 2015; Michael Sterrett <mr_bones_@gentoo.org>
+  +files/scid-4.6.0-gentoo.patch, +scid-4.6.0.ebuild:
+  version bump
 
   13 Nov 2014; Michael Sterrett <mr_bones_@gentoo.org>
   -files/scid-4.4-gentoo.patch, -files/scid-4.4-parallelmake.patch,



1.1                  games-board/scid/scid-4.6.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/scid/scid-4.6.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-board/scid/scid-4.6.0.ebuild?rev=1.1&content-type=text/plain

Index: scid-4.6.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-board/scid/scid-4.6.0.ebuild,v 1.1 2015/05/09 05:19:31 mr_bones_ Exp $

EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit eutils toolchain-funcs gnome2-utils python-any-r1 games

DESCRIPTION="a free chess database application"
HOMEPAGE="http://scid.sourceforge.net/"
SRC_URI="mirror://sourceforge/scid/${P}-ae199eb3496714b50d2cbd204492d61022b2da76.zip -> ${P}.zip
	mirror://sourceforge/scid/spelling.zip
	mirror://sourceforge/scid/ratings.zip
	mirror://sourceforge/scid/photos.zip
	mirror://sourceforge/scid/scidlet40k.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""

CDEPEND="dev-lang/tk
	dev-tcltk/tkimg
	>=sys-libs/zlib-1.1.3"
RDEPEND="${CDEPEND}
	!games-board/chessdb"
DEPEND="${CDEPEND}
	${PYTHON_DEPS}
	app-arch/unzip"

pkg_setup() {
	python-any-r1_pkg_setup
	games_pkg_setup
}

src_unpack() {
	default
	mv scid-code-* ${P} || die
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-gentoo.patch
	edos2unix engines/togaII1.2.1a/src/Makefile
	sed -i \
		-e "s:@GENTOO_DATADIR@:${GAMES_DATADIR}/${PN}:" \
		tcl/start.tcl || die
	sed -i \
		-e "/COMPILE.*testzlib/s:\$var(COMPILE):$(tc-getCXX):" \
		configure || die
	gzip ../ratings.ssp || die
	python_fix_shebang .
}

src_configure() {
	# configure is not an autotools script
	./configure \
		COMPILE="$(tc-getCXX)" \
		LINK="$(tc-getCXX) ${CXXFLAGS} ${LDFLAGS}" \
		CC="$(tc-getCC)" \
		OPTIMIZE="${CXXFLAGS}" \
		TCL_INCLUDE="" \
		BINDIR="${GAMES_BINDIR}" \
		SHAREDIR="${GAMES_DATADIR}/${PN}" || die
}

src_compile() {
	emake all_scid
}

src_install() {
	emake DESTDIR="${D}" install_scid
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r sounds

	dodoc ChangeLog TODO
	dohtml help/*.html

	newicon -s scalable svg/scid_app.svg ${PN}.svg
	make_desktop_entry scid Scid

	doins ../spelling.ssp ../ratings.ssp.gz ../*.spf
	newins ../scidlet40k.sbk scidlet.sbk

	prepgamesdirs
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	gnome2_icon_cache_update
	elog "To enable speech, emerge dev-tcltk/snack"
	elog "To enable Xfcc support, emerge dev-tcltk/tdom"
}

pkg_postrm() {
	gnome2_icon_cache_update
}