[gentoo-commits] gentoo-x86 commit in net-firewall/fwknop: metadata.xml fwknop-2.6.6.ebuild ChangeLog fwknop-2.6.2.ebuild

[gentoo-commits] gentoo-x86 commit in net-firewall/fwknop: metadata.xml fwknop-2.6.6.ebuild ChangeLog fwknop-2.6.2.ebuild

[Ian Delaney (idella4)]

idella4     15/04/29 23:18:49

  Modified:             metadata.xml ChangeLog
  Added:                fwknop-2.6.6.ebuild
  Removed:              fwknop-2.6.2.ebuild
  Log:
  bump; ebuild supplied by Coacher in bug #519716, newinitd and newconfd files updated, removed prior version to avoid any mismatch, closes bug #519716
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.2                  net-firewall/fwknop/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/fwknop/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	27 Apr 2014 10:50:49 -0000	1.1
+++ metadata.xml	29 Apr 2015 23:18:49 -0000	1.2
@@ -12,5 +12,6 @@
 		<flag name="gpg">Enable GPG support via <pkg>app-crypt/gpgme</pkg></flag>
 		<flag name="server">Build fwknopd server</flag>
 		<flag name="extras">Install example apparmor policy</flag>
+		<flag name="udp-server">Build fwknopd with UDP server mode only</flag>
 	</use>
 </pkgmetadata>



1.4                  net-firewall/fwknop/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/ChangeLog?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/ChangeLog?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/ChangeLog?r1=1.3&r2=1.4

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/fwknop/ChangeLog,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- ChangeLog	28 May 2014 16:19:46 -0000	1.3
+++ ChangeLog	29 Apr 2015 23:18:49 -0000	1.4
@@ -1,6 +1,14 @@
 # ChangeLog for net-firewall/fwknop
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwknop/ChangeLog,v 1.3 2014/05/28 16:19:46 swift Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwknop/ChangeLog,v 1.4 2015/04/29 23:18:49 idella4 Exp $
+
+*fwknop-2.6.6 (29 Apr 2015)
+
+  29 Apr 2015; Ian Delaney <idella4@gentoo.org> +fwknop-2.6.6.ebuild,
+  -files/fwknop-2.6.0-remove-extra-run-from-paths.patch, -fwknop-2.6.2.ebuild,
+  files/fwknopd.confd, files/fwknopd.init, metadata.xml:
+  bump; ebuild supplied by Coacher in bug #519716, newinitd and newconfd files
+  updated, removed prior version to avoid any mismatch, closes bug #519716
 
   28 May 2014; Sven Vermeulen <swift@gentoo.org> -fwknop-2.6.1.ebuild:
   Remove 2.6.1 ebuild (double free bug). Thanks to Coacher (itumaykin@)



1.1                  net-firewall/fwknop/fwknop-2.6.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/fwknop-2.6.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/fwknop/fwknop-2.6.6.ebuild?rev=1.1&content-type=text/plain

Index: fwknop-2.6.6.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/fwknop/fwknop-2.6.6.ebuild,v 1.1 2015/04/29 23:18:49 idella4 Exp $

EAPI=5

# Does work with python 2.7, does not work with python 3.3 on my machine
# More feedback is welcome
PYTHON_COMPAT=( python2_7 )
DISTUTILS_OPTIONAL=1
AUTOTOOLS_AUTORECONF=1
AUTOTOOLS_IN_SOURCE_BUILD=1
inherit autotools-utils distutils-r1 systemd

DESCRIPTION="Single Packet Authorization and Port Knocking application"
HOMEPAGE="http://www.cipherdyne.org/fwknop/"
SRC_URI="https://github.com/mrash/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="client extras gdbm gpg python server udp-server"

RDEPEND="python? ( ${PYTHON_DEPS} )
	client? ( net-misc/wget[ssl] )
	gpg? (
		dev-libs/libassuan
		dev-libs/libgpg-error
	)"

DEPEND="${RDEPEND}
	gdbm? ( sys-libs/gdbm )
	gpg? ( app-crypt/gpgme )
	server? (
		!udp-server? ( net-libs/libpcap )
		net-firewall/iptables
	)"

REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
	udp-server? ( server )"

DOCS=( ChangeLog README.md )

src_prepare() {
	# Install example configs with .example suffix
	if use server; then
		sed -i 's/conf;/conf.example;/g' "${S}"/Makefile.am || die
	fi

	autotools-utils_src_prepare

	if use python; then
		cd "${S}"/python || die
		distutils-r1_src_prepare
	fi
}

src_configure() {
	local myeconfargs=(
		--localstatedir=/run
		--enable-digest-cache
		$(use_enable client)
		$(use_enable !gdbm file-cache)
		$(use_enable server)
		$(use_enable udp-server)
		$(use_with gpg gpgme)
	)
	autotools-utils_src_configure
}

src_compile() {
	autotools-utils_src_compile

	if use python; then
		cd "${S}"/python || die
		distutils-r1_src_compile
	fi
}

src_install() {
	autotools-utils_src_install
	prune_libtool_files --modules

	if use server; then
		newinitd "${FILESDIR}/fwknopd.init" fwknopd
		newconfd "${FILESDIR}/fwknopd.confd" fwknopd
		systemd_newtmpfilesd "${FILESDIR}/fwknopd.tmpfiles.conf" fwknopd.conf
	fi

	use extras && dodoc "${S}/extras/apparmor/usr.sbin.fwknopd"

	if use python; then
		# Unset DOCS since distutils-r1.eclass interferes
		local DOCS=()
		cd "${S}"/python || die
		distutils-r1_src_install
	fi
}