[gentoo-commits] gentoo-x86 commit in net-libs/libvncserver: ChangeLog libvncserver-0.9.10-r1.ebuild

["Ulrich Mueller (ulm)" <ulm@gentoo.org>]

ulm         15/04/26 17:16:42

  Modified:             ChangeLog
  Added:                libvncserver-0.9.10-r1.ebuild
  Log:
  Add missing econf option, bug 523590 comment 18. Proxy commit for Alex Xu.
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)

Revision  Changes    Path
1.95                 net-libs/libvncserver/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libvncserver/ChangeLog?rev=1.95&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libvncserver/ChangeLog?rev=1.95&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libvncserver/ChangeLog?r1=1.94&r2=1.95

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/libvncserver/ChangeLog,v
retrieving revision 1.94
retrieving revision 1.95
diff -u -r1.94 -r1.95
--- ChangeLog	21 Apr 2015 18:43:19 -0000	1.94
+++ ChangeLog	26 Apr 2015 17:16:42 -0000	1.95
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/libvncserver
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libvncserver/ChangeLog,v 1.94 2015/04/21 18:43:19 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libvncserver/ChangeLog,v 1.95 2015/04/26 17:16:42 ulm Exp $
+
+*libvncserver-0.9.10-r1 (26 Apr 2015)
+
+  26 Apr 2015; Ulrich Müller <ulm@gentoo.org> +libvncserver-0.9.10-r1.ebuild:
+  Add missing econf option, bug 523590 comment 18. Proxy commit for Alex Xu.
 
   21 Apr 2015; Pacho Ramos <pacho@gentoo.org> libvncserver-0.9.10.ebuild:
   ppc stable wrt bug #523590



1.1                  net-libs/libvncserver/libvncserver-0.9.10-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libvncserver/libvncserver-0.9.10-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/libvncserver/libvncserver-0.9.10-r1.ebuild?rev=1.1&content-type=text/plain

Index: libvncserver-0.9.10-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libvncserver/libvncserver-0.9.10-r1.ebuild,v 1.1 2015/04/26 17:16:42 ulm Exp $

EAPI="5"

inherit autotools multilib-minimal

DESCRIPTION="library for creating vnc servers"
HOMEPAGE="http://libvncserver.sourceforge.net/"
SRC_URI="https://github.com/LibVNC/libvncserver/archive/LibVNCServer-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
IUSE="+24bpp gcrypt gnutls ipv6 +jpeg +png ssl static-libs test threads vaapi +zlib"

DEPEND="
	gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
	gnutls? (
		>=net-libs/gnutls-2.12.23-r6[${MULTILIB_USEDEP}]
		>=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}]
	)
	!gnutls? (
		ssl? ( >=dev-libs/openssl-1.0.1h-r2[${MULTILIB_USEDEP}] )
	)
	jpeg? ( >=virtual/jpeg-0-r2:0[${MULTILIB_USEDEP}] )
	png? ( >=media-libs/libpng-1.6.10:0[${MULTILIB_USEDEP}] )
	vaapi? ( >=x11-libs/libva-1.2.1-r1[${MULTILIB_USEDEP}] )
	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
RDEPEND="${DEPEND}"

S="${WORKDIR}"/${PN}-LibVNCServer-${PV}

DOCS=( AUTHORS ChangeLog NEWS README TODO )

src_prepare() {
	# https://github.com/LibVNC/libvncserver/issues/11
	epatch "${FILESDIR}/${P}-libva-1.0.patch"

	sed -i -r \
		-e "/^SUBDIRS/s:\<$(usex test 'test|' '')client_examples|examples\>::g" \
		Makefile.am || die

	eautoreconf
}

multilib_src_configure() {
	ECONF_SOURCE=${S} \
	econf \
		--disable-silent-rules \
		$(use_enable static-libs static) \
		$(use_with 24bpp) \
		$(use_with gnutls) \
		$(usex gnutls --with-gcrypt $(use_with gcrypt)) \
		$(usex gnutls --without-ssl $(use_with ssl)) \
		$(use_with ipv6) \
		$(use_with jpeg) \
		$(use_with png) \
		$(use_with threads pthread) \
		$(use_with vaapi libva) \
		$(use_with zlib)
}

multilib_src_install_all() {
	einstalldocs
	prune_libtool_files
}