[gentoo-commits] gentoo-x86 commit in x11-wm/i3: i3-4.10.2.ebuild ChangeLog i3-4.10.1.ebuild

[gentoo-commits] gentoo-x86 commit in x11-wm/i3: i3-4.10.2.ebuild ChangeLog i3-4.10.1.ebuild

[Kacper Kowalik (xarthisius)]

xarthisius    15/04/20 16:06:54

  Modified:             ChangeLog
  Added:                i3-4.10.2.ebuild
  Removed:              i3-4.10.1.ebuild
  Log:
  Version bump, fixes #546832 by <contact@ryper.org>
  
  (Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key 0x5D21B852895192F9)

Revision  Changes    Path
1.67                 x11-wm/i3/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/i3/ChangeLog?rev=1.67&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/i3/ChangeLog?rev=1.67&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/i3/ChangeLog?r1=1.66&r2=1.67

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/i3/ChangeLog,v
retrieving revision 1.66
retrieving revision 1.67
diff -u -r1.66 -r1.67
--- ChangeLog	29 Mar 2015 18:38:20 -0000	1.66
+++ ChangeLog	20 Apr 2015 16:06:54 -0000	1.67
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/i3
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/i3/ChangeLog,v 1.66 2015/03/29 18:38:20 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/i3/ChangeLog,v 1.67 2015/04/20 16:06:54 xarthisius Exp $
+
+*i3-4.10.2 (20 Apr 2015)
+
+  20 Apr 2015; Kacper Kowalik <xarthisius@gentoo.org> +i3-4.10.2.ebuild,
+  -i3-4.10.1.ebuild:
+  Version bump, fixes #546832 by <contact@ryper.org>
 
 *i3-4.10.1 (29 Mar 2015)
 



1.1                  x11-wm/i3/i3-4.10.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/i3/i3-4.10.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/i3/i3-4.10.2.ebuild?rev=1.1&content-type=text/plain

Index: i3-4.10.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/i3/i3-4.10.2.ebuild,v 1.1 2015/04/20 16:06:54 xarthisius Exp $

EAPI=5

inherit eutils toolchain-funcs

DESCRIPTION="An improved dynamic tiling window manager"
HOMEPAGE="http://i3wm.org/"
SRC_URI="http://i3wm.org/downloads/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="+pango"

CDEPEND="dev-libs/libev
	dev-libs/libpcre
	>=dev-libs/yajl-2.0.3
	x11-libs/libxcb[xkb]
	x11-libs/libxkbcommon[X]
	x11-libs/startup-notification
	x11-libs/xcb-util
	x11-libs/xcb-util-cursor
	x11-libs/xcb-util-keysyms
	x11-libs/xcb-util-wm
	pango? (
		>=x11-libs/pango-1.30.0[X]
		>=x11-libs/cairo-1.12.2[X,xcb]
	)"
DEPEND="${CDEPEND}
	virtual/pkgconfig"
RDEPEND="${CDEPEND}
	dev-lang/perl
	dev-perl/AnyEvent-I3
	dev-perl/JSON-XS"

DOCS=( RELEASE-NOTES-${PV} )

src_prepare() {
	if ! use pango; then
		sed -i common.mk -e '/PANGO/d' || die
	fi

	cat <<- EOF > "${T}"/i3wm
		#!/bin/sh
		exec /usr/bin/i3
	EOF

	epatch_user #471716
}

src_compile() {
	emake V=1 CC="$(tc-getCC)" AR="$(tc-getAR)"
}

src_install() {
	default
	dohtml -r docs/*
	doman man/*.1
	exeinto /etc/X11/Sessions
	doexe "${T}"/i3wm
}

pkg_postinst() {
	einfo "There are several packages that you may find useful with ${PN} and"
	einfo "their usage is suggested by the upstream maintainers, namely:"
	einfo "  x11-misc/dmenu"
	einfo "  x11-misc/i3status"
	einfo "  x11-misc/i3lock"
	einfo "Please refer to their description for additional info."
}