[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-tweak-tool: ChangeLog gnome-tweak-tool-3.14.3.ebuild

[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-tweak-tool: ChangeLog gnome-tweak-tool-3.14.3.ebuild

[Gilles Dartiguelongue (eva)]

eva         15/04/19 13:59:49

  Modified:             ChangeLog
  Added:                gnome-tweak-tool-3.14.3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key C6085806)

Revision  Changes    Path
1.41                 gnome-extra/gnome-tweak-tool/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog?rev=1.41&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog?rev=1.41&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog?r1=1.40&r2=1.41

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog,v
retrieving revision 1.40
retrieving revision 1.41
diff -u -r1.40 -r1.41
--- ChangeLog	15 Mar 2015 13:26:20 -0000	1.40
+++ ChangeLog	19 Apr 2015 13:59:49 -0000	1.41
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-extra/gnome-tweak-tool
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog,v 1.40 2015/03/15 13:26:20 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog,v 1.41 2015/04/19 13:59:49 eva Exp $
+
+*gnome-tweak-tool-3.14.3 (19 Apr 2015)
+
+  19 Apr 2015; Gilles Dartiguelongue <eva@gentoo.org>
+  +gnome-tweak-tool-3.14.3.ebuild:
+  Version bump.
 
   15 Mar 2015; Pacho Ramos <pacho@gentoo.org> gnome-tweak-tool-3.14.2.ebuild:
   x86 stable, bug 534012



1.1                  gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.14.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.14.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.14.3.ebuild?rev=1.1&content-type=text/plain

Index: gnome-tweak-tool-3.14.3.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.14.3.ebuild,v 1.1 2015/04/19 13:59:49 eva Exp $

EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python2_7 )

inherit eutils gnome2 python-r1

DESCRIPTION="Tool to customize GNOME 3 options"
HOMEPAGE="https://wiki.gnome.org/action/show/Apps/GnomeTweakTool"

LICENSE="GPL-2+"
SLOT="0"
IUSE=""
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"

# Newer pygobject needed due upstream bug #723951
COMMON_DEPEND="
	${PYTHON_DEPS}
	>=gnome-base/gsettings-desktop-schemas-3.4
	>=dev-python/pygobject-3.10.2:3[${PYTHON_USEDEP}]
"
# g-s-d, gnome-desktop, gnome-shell etc. needed at runtime for the gsettings schemas
RDEPEND="${COMMON_DEPEND}
	>=gnome-base/gnome-desktop-3.6.0.1:3=[introspection]
	>=x11-libs/gtk+-3.12:3[introspection]

	net-libs/libsoup[introspection]
	x11-libs/libnotify[introspection]

	>=gnome-base/gnome-settings-daemon-3
	gnome-base/gnome-shell
	>=gnome-base/nautilus-3
"
DEPEND="${COMMON_DEPEND}
	>=dev-util/intltool-0.40.0
	virtual/pkgconfig
"

src_prepare() {
	# Add contents of Gentoo's cursor theme directory to cursor theme list
	epatch "${FILESDIR}/${PN}-3.10.1-gentoo-cursor-themes.patch"

	# Prevent problems setting WM preferences, upstream bug #706834
	epatch "${FILESDIR}/${PN}-3.8.1-wm-preferences.patch"

	gnome2_src_prepare
	python_copy_sources
}

src_configure() {
	python_foreach_impl run_in_build_dir gnome2_src_configure
}

src_compile() {
	python_foreach_impl run_in_build_dir gnome2_src_compile
}

src_test() {
	python_foreach_impl run_in_build_dir default
}

src_install() {
	install_python() {
		gnome2_src_install
		python_doscript gnome-tweak-tool || die
	}
	python_foreach_impl run_in_build_dir install_python
}