[gentoo-commits] gentoo-x86 commit in net-ftp/lftp: ChangeLog lftp-4.6.2.ebuild lftp-4.6.1.ebuild lftp-4.6.1.20150401-r1.ebuild

[gentoo-commits] gentoo-x86 commit in net-ftp/lftp: ChangeLog lftp-4.6.2.ebuild lftp-4.6.1.ebuild lftp-4.6.1.20150401-r1.ebuild

[Jeroen Roovers (jer)]

jer         15/04/16 15:47:19

  Modified:             ChangeLog
  Added:                lftp-4.6.2.ebuild
  Removed:              lftp-4.6.1.ebuild lftp-4.6.1.20150401-r1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.512                net-ftp/lftp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?rev=1.512&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?rev=1.512&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?r1=1.511&r2=1.512

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v
retrieving revision 1.511
retrieving revision 1.512
diff -u -r1.511 -r1.512
--- ChangeLog	3 Apr 2015 19:28:59 -0000	1.511
+++ ChangeLog	16 Apr 2015 15:47:19 -0000	1.512
@@ -1,6 +1,12 @@
 # ChangeLog for net-ftp/lftp
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.511 2015/04/03 19:28:59 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.512 2015/04/16 15:47:19 jer Exp $
+
+*lftp-4.6.2 (16 Apr 2015)
+
+  16 Apr 2015; Jeroen Roovers <jer@gentoo.org> -lftp-4.6.1.ebuild,
+  -lftp-4.6.1.20150401-r1.ebuild, +lftp-4.6.2.ebuild:
+  Version bump.
 
 *lftp-4.6.1.20150401-r1 (03 Apr 2015)
 



1.1                  net-ftp/lftp/lftp-4.6.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/lftp-4.6.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/lftp-4.6.2.ebuild?rev=1.1&content-type=text/plain

Index: lftp-4.6.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/lftp-4.6.2.ebuild,v 1.1 2015/04/16 15:47:19 jer Exp $

EAPI=5
inherit autotools eutils libtool

DESCRIPTION="A sophisticated ftp/sftp/http/https/torrent client and file transfer program"
HOMEPAGE="http://lftp.yar.ru/"
SRC_URI="${HOMEPAGE}ftp/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"

IUSE="convert-mozilla-cookies +gnutls idn nls openssl socks5 +ssl verify-file"
LFTP_LINGUAS=( cs de es fr it ja ko pl pt_BR ru uk zh_CN zh_HK zh_TW )
IUSE+=" ${LFTP_LINGUAS[@]/#/linguas_}"

REQUIRED_USE="
	ssl? ( ^^ ( openssl gnutls ) )
"

RDEPEND="
	>=sys-libs/ncurses-5.1
	>=sys-libs/readline-5.1
	dev-libs/expat
	sys-libs/zlib
	convert-mozilla-cookies? ( dev-perl/DBI )
	idn? ( net-dns/libidn )
	socks5? (
		>=net-proxy/dante-1.1.12
		virtual/pam
	)
	ssl? (
		gnutls? ( >=net-libs/gnutls-1.2.3 )
		openssl? ( >=dev-libs/openssl-0.9.6 )
	)
	verify-file? (
		dev-perl/string-crc32
		virtual/perl-Digest-MD5
	)
"

DEPEND="
	${RDEPEND}
	=sys-devel/libtool-2*
	app-arch/xz-utils
	nls? ( sys-devel/gettext )
	virtual/pkgconfig
"

DOCS=(
	BUGS ChangeLog FAQ FEATURES MIRRORS NEWS README README.debug-levels
	README.dnssec README.modules THANKS TODO
)

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-4.0.2.91-lafile.patch \
		"${FILESDIR}"/${PN}-4.3.8-gets.patch \
		"${FILESDIR}"/${PN}-4.5.3-autopoint.patch \
		"${FILESDIR}"/${PN}-4.5.5-am_config_header.patch \
		"${FILESDIR}"/${PN}-4.6.1-liblftp-tasks.patch

	eautoreconf
	elibtoolize # for Darwin bundles

	# bug #536036
	printf 'set fish:auto-confirm no\nset sftp:auto-confirm no\n' >> ${PN}.conf || die
}

src_configure() {
	econf \
		$(use_enable nls) \
		$(use_with gnutls) \
		$(use_with idn libidn) \
		$(use_with openssl openssl "${EPREFIX}"/usr) \
		$(use_with socks5 socksdante "${EPREFIX}"/usr) \
		--enable-packager-mode \
		--sysconfdir="${EPREFIX}"/etc/${PN} \
		--with-modules \
		--without-included-regex
}

src_install() {
	default
	local script
	for script in {convert-mozilla-cookies,verify-file}; do
		use ${script} || { rm "${ED}"/usr/share/${PN}/${script} || die ;}
	done
}