[gentoo-commits] gentoo-x86 commit in sys-libs/cracklib: cracklib-2.9.4.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-libs/cracklib: cracklib-2.9.4.ebuild ChangeLog

[Lars Wendler (polynomial-c)]

polynomial-c    15/04/16 08:41:43

  Modified:             ChangeLog
  Added:                cracklib-2.9.4.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.211                sys-libs/cracklib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/cracklib/ChangeLog?rev=1.211&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/cracklib/ChangeLog?rev=1.211&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/cracklib/ChangeLog?r1=1.210&r2=1.211

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/cracklib/ChangeLog,v
retrieving revision 1.210
retrieving revision 1.211
diff -u -r1.210 -r1.211
--- ChangeLog	15 Apr 2015 11:44:04 -0000	1.210
+++ ChangeLog	16 Apr 2015 08:41:43 -0000	1.211
@@ -1,6 +1,11 @@
 # ChangeLog for sys-libs/cracklib
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/cracklib/ChangeLog,v 1.210 2015/04/15 11:44:04 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/cracklib/ChangeLog,v 1.211 2015/04/16 08:41:43 polynomial-c Exp $
+
+*cracklib-2.9.4 (16 Apr 2015)
+
+  16 Apr 2015; Lars Wendler <polynomial-c@gentoo.org> +cracklib-2.9.4.ebuild:
+  Version bump.
 
 *cracklib-2.9.3 (15 Apr 2015)
 



1.1                  sys-libs/cracklib/cracklib-2.9.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/cracklib/cracklib-2.9.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/cracklib/cracklib-2.9.4.ebuild?rev=1.1&content-type=text/plain

Index: cracklib-2.9.4.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/cracklib/cracklib-2.9.4.ebuild,v 1.1 2015/04/16 08:41:43 polynomial-c Exp $

EAPI="5"
PYTHON_COMPAT=( python2_7 )
DISTUTILS_OPTIONAL=1

inherit eutils distutils-r1 libtool multilib-minimal toolchain-funcs

MY_P=${P/_}
DESCRIPTION="Password Checking Library"
HOMEPAGE="http://sourceforge.net/projects/cracklib"
SRC_URI="mirror://sourceforge/cracklib/${MY_P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x86-macos ~m68k-mint"
IUSE="nls python static-libs test zlib"

RDEPEND="zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
	python? (
		dev-python/setuptools[${PYTHON_USEDEP}]
		test? ( dev-python/nose[${PYTHON_USEDEP}] )
	)"
RDEPEND="${RDEPEND}
	abi_x86_32? (
		!<=app-emulation/emul-linux-x86-baselibs-20140508-r6
		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
	)"

S=${WORKDIR}/${MY_P}

do_python() {
	multilib_is_native_abi || return 0
	use python || return 0
	pushd python > /dev/null || die
	distutils-r1_src_${EBUILD_PHASE}
	popd > /dev/null
}

pkg_setup() {
	# workaround #195017
	if has unmerge-orphans ${FEATURES} && has_version "<${CATEGORY}/${PN}-2.8.10" ; then
		eerror "Upgrade path is broken with FEATURES=unmerge-orphans"
		eerror "Please run: FEATURES=-unmerge-orphans emerge cracklib"
		die "Please run: FEATURES=-unmerge-orphans emerge cracklib"
	fi
}

src_prepare() {
	elibtoolize #269003
	do_python
}

multilib_src_configure() {
	export ac_cv_header_zlib_h=$(usex zlib)
	export ac_cv_search_gzopen=$(usex zlib -lz no)
	# use /usr/lib so that the dictionary is shared between ABIs
	ECONF_SOURCE=${S} \
	econf \
		--with-default-dict='/usr/lib/cracklib_dict' \
		--without-python \
		$(use_enable nls) \
		$(use_enable static-libs static)
}

multilib_src_compile() {
	default
	do_python
}

multilib_src_test() {
	do_python
}

python_test() {
	nosetests -w "${S}"/python || die "Tests fail with ${EPYTHON}"
}

multilib_src_install() {
	default
	# move shared libs to /
	multilib_is_native_abi && gen_usr_ldscript -a crack

	do_python
}

multilib_src_install_all() {
	einstalldocs
	prune_libtool_files
	rm -r "${ED}"/usr/share/cracklib

	insinto /usr/share/dict
	doins dicts/cracklib-small || die
}

pkg_postinst() {
	if [[ ${ROOT} == "/" ]] ; then
		ebegin "Regenerating cracklib dictionary"
		create-cracklib-dict "${EPREFIX}"/usr/share/dict/* > /dev/null
		eend $?
	fi
}