[gentoo-commits] gentoo-x86 commit in sys-apps/etckeeper: etckeeper-1.18.ebuild ChangeLog etckeeper-1.12.ebuild

[gentoo-commits] gentoo-x86 commit in sys-apps/etckeeper: etckeeper-1.18.ebuild ChangeLog etckeeper-1.12.ebuild

[Manuel Rueger (mrueg)]

mrueg       15/04/12 21:43:56

  Modified:             ChangeLog
  Added:                etckeeper-1.18.ebuild
  Removed:              etckeeper-1.12.ebuild
  Log:
  Version bump. Remove old.
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key )

Revision  Changes    Path
1.49                 sys-apps/etckeeper/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	8 Apr 2015 18:27:32 -0000	1.48
+++ ChangeLog	12 Apr 2015 21:43:56 -0000	1.49
@@ -1,6 +1,13 @@
 # ChangeLog for sys-apps/etckeeper
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/ChangeLog,v 1.48 2015/04/08 18:27:32 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/ChangeLog,v 1.49 2015/04/12 21:43:56 mrueg Exp $
+
+*etckeeper-1.18 (12 Apr 2015)
+
+  12 Apr 2015; Manuel Rüger <mrueg@gentoo.org> +etckeeper-1.18.ebuild,
+  +files/etckeeper-1.18-gentoo.patch, -etckeeper-1.12.ebuild,
+  -files/etckeeper-1.12-gentoo.patch:
+  Version bump. Remove old.
 
   08 Apr 2015; Michał Górny <mgorny@gentoo.org> etckeeper-1.11-r1.ebuild,
   etckeeper-1.12.ebuild:



1.1                  sys-apps/etckeeper/etckeeper-1.18.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/etckeeper-1.18.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/etckeeper-1.18.ebuild?rev=1.1&content-type=text/plain

Index: etckeeper-1.18.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/etckeeper-1.18.ebuild,v 1.1 2015/04/12 21:43:56 mrueg Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )

inherit eutils bash-completion-r1 prefix python-r1

DESCRIPTION="A collection of tools to let /etc be stored in a repository"
HOMEPAGE="https://etckeeper.branchable.com/"
SRC_URI="https://github.com/joeyh/etckeeper/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~arm ~x86"
SLOT="0"
IUSE="bazaar cron"
REQUIRED_USE="bazaar? ( ${PYTHON_REQUIRED_USE} )"

VCS_DEPEND="dev-vcs/git
	dev-vcs/mercurial
	dev-vcs/darcs"
DEPEND="bazaar? ( dev-vcs/bzr )"
RDEPEND="${DEPEND}
	app-portage/portage-utils
	cron? ( virtual/cron )
	bazaar? ( ${PYTHON_DEPS} )
	!bazaar? ( || ( ${VCS_DEPEND} ) )"

src_prepare(){
	epatch "${FILESDIR}"/${P}-gentoo.patch
}

src_compile() {
	:
}

src_install(){
	emake DESTDIR="${ED}" install

	bzr_install() {
		${PYTHON} ./${PN}-bzr/__init__.py install --root="${ED}" ||
			die "bzr support installation failed!"
	}
	use bazaar && python_foreach_impl bzr_install

	if use prefix; then
		doenvd "${FILESDIR}"/99${PN}
		eprefixify "${ED%/}"/etc/env.d/99${PN}
	fi

	newbashcomp bash_completion ${PN}
	dodoc doc/README.mdwn
	docinto examples
	newdoc "${FILESDIR}"/bashrc-r1 bashrc

	if use cron ; then
		exeinto /etc/cron.daily
		newexe debian/cron.daily etckeeper
	fi
}

pkg_postinst(){
	elog "${PN} supports the following VCS: ${VCS_DEPEND}"
	elog "	dev-vcs/bzr"
	elog "This ebuild just ensures at least one is installed!"
	elog "For dev-vcs/bzr you need to enable 'bazaar' useflag."
	elog
	elog "You may want to adjust your /etc/portage/bashrc"
	elog "see the example file in /usr/share/doc/${PF}/examples"
	elog
	elog "To initialise your etc-dir as a repository run:"
	elog "${PN} init -d /etc"
}