[gentoo-commits] gentoo-x86 commit in app-text/dos2unix: ChangeLog dos2unix-7.2.1.ebuild dos2unix-7.1.ebuild

[gentoo-commits] gentoo-x86 commit in app-text/dos2unix: ChangeLog dos2unix-7.2.1.ebuild dos2unix-7.1.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    15/04/05 21:41:04

  Modified:             ChangeLog
  Added:                dos2unix-7.2.1.ebuild
  Removed:              dos2unix-7.1.ebuild
  Log:
  Version bump. Removed old
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.156                app-text/dos2unix/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/dos2unix/ChangeLog?rev=1.156&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/dos2unix/ChangeLog?rev=1.156&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/dos2unix/ChangeLog?r1=1.155&r2=1.156

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/dos2unix/ChangeLog,v
retrieving revision 1.155
retrieving revision 1.156
diff -u -r1.155 -r1.156
--- ChangeLog	2 Mar 2015 09:30:30 -0000	1.155
+++ ChangeLog	5 Apr 2015 21:41:04 -0000	1.156
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/dos2unix
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/dos2unix/ChangeLog,v 1.155 2015/03/02 09:30:30 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/dos2unix/ChangeLog,v 1.156 2015/04/05 21:41:04 polynomial-c Exp $
+
+*dos2unix-7.2.1 (05 Apr 2015)
+
+  05 Apr 2015; Lars Wendler <polynomial-c@gentoo.org> -dos2unix-7.1.ebuild,
+  +dos2unix-7.2.1.ebuild:
+  Version bump. Removed old.
 
   02 Mar 2015; Agostino Sarubbo <ago@gentoo.org> dos2unix-6.0.6.ebuild:
   Stable for ppc, wrt bug #522520



1.1                  app-text/dos2unix/dos2unix-7.2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/dos2unix/dos2unix-7.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/dos2unix/dos2unix-7.2.1.ebuild?rev=1.1&content-type=text/plain

Index: dos2unix-7.2.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/dos2unix/dos2unix-7.2.1.ebuild,v 1.1 2015/04/05 21:41:04 polynomial-c Exp $

EAPI=5

inherit eutils toolchain-funcs

DESCRIPTION="Convert DOS or MAC text files to UNIX format or vice versa"
HOMEPAGE="http://www.xs4all.nl/~waterlan/dos2unix.html http://sourceforge.net/projects/dos2unix/"
SRC_URI="
	http://www.xs4all.nl/~waterlan/${PN}/${P}.tar.gz
	mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~sparc64-solaris"
IUSE="debug nls test"

RDEPEND="
	!app-text/hd2u
	!app-text/unix2dos
	virtual/libintl"
DEPEND="
	${RDEPEND}
	nls? ( sys-devel/gettext )
	test? ( virtual/perl-Test-Simple )
	dev-lang/perl"

src_prepare() {
	sed \
		-e '/^LDFLAGS/s|=|+=|' \
		-e '/CFLAGS_OS \+=/d' \
		-e '/LDFLAGS_EXTRA \+=/d' \
		-e "/^CFLAGS/s|-O2|${CFLAGS}|" \
		-i Makefile || die

	if use debug ; then
		sed -e "/^DEBUG/s:0:1:" \
			-e "/EXTRA_CFLAGS +=/s:-g::" \
			-i Makefile || die
	fi

	tc-export CC
}

lintl() {
	# same logic as from virtual/libintl
	use !elibc_glibc && use !elibc_uclibc && echo "-lintl"
}

src_compile() {
	emake prefix="${EPREFIX}/usr" \
		$(usex nls "LDFLAGS_EXTRA=$(lintl)" "ENABLE_NLS=")
}

src_install() {
	emake DESTDIR="${D}" prefix="${EPREFIX}/usr" \
		$(usex nls "" "ENABLE_NLS=") install
}