[gentoo-commits] gentoo-x86 commit in sys-process/glances: glances-2.3.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-process/glances: glances-2.3.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     15/04/05 08:26:15

  Modified:             ChangeLog
  Added:                glances-2.3.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.18/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.25                 sys-process/glances/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/glances/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/glances/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/glances/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-process/glances/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	31 Dec 2014 04:03:30 -0000	1.24
+++ ChangeLog	5 Apr 2015 08:26:15 -0000	1.25
@@ -1,6 +1,11 @@
 # ChangeLog for sys-process/glances
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-process/glances/ChangeLog,v 1.24 2014/12/31 04:03:30 idella4 Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-process/glances/ChangeLog,v 1.25 2015/04/05 08:26:15 patrick Exp $
+
+*glances-2.3 (05 Apr 2015)
+
+  05 Apr 2015; Patrick Lauer <patrick@gentoo.org> +glances-2.3.ebuild:
+  Bump
 
 *glances-2.2.1 (31 Dec 2014)
 



1.1                  sys-process/glances/glances-2.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/glances/glances-2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/glances/glances-2.3.ebuild?rev=1.1&content-type=text/plain

Index: glances-2.3.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-process/glances/glances-2.3.ebuild,v 1.1 2015/04/05 08:26:15 patrick Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_3,3_4} )
PYTHON_REQ_USE="ncurses"

inherit distutils-r1 linux-info

MYPN=Glances
MYP=${MYPN}-${PV}

DESCRIPTION="CLI curses based monitoring tool"
HOMEPAGE="https://github.com/nicolargo/glances"
SRC_URI="mirror://pypi/${MYPN:0:1}/${MYPN}/${MYP}.tar.gz"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
IUSE="chart doc hddtemp snmp web"

DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
# There is another optional extra batinfo, absent from portage
RDEPEND="${DEPEND}
	>=dev-python/psutil-2.0.0[${PYTHON_USEDEP}]
	hddtemp? ( app-admin/hddtemp )
	snmp? ( dev-python/pysnmp[${PYTHON_USEDEP}] )
	web? ( dev-python/bottle[${PYTHON_USEDEP}] )
	chart? ( dev-python/matplotlib[${PYTHON_USEDEP}] )"

CONFIG_CHECK="~TASK_IO_ACCOUNTING ~TASK_DELAY_ACCT ~TASKSTATS"

S="${WORKDIR}/${MYP}"

pkg_setup() {
	linux-info_pkg_setup
}

python_prepare_all() {
	sed -e "s:share/doc/glances:share/doc/${PF}:g" \
		-e "s/'COPYING',//" \
		-e "s:/etc:${EPREFIX}/etc:" \
		-i setup.py || die

	distutils-r1_python_prepare_all
}

python_install_all() {
	# Abnormal setup for pre-built html docs in setup.py
	use doc && local HTML_DOCS=( docs/_build/html/. )
	rm -rf "${D}"usr/share/doc/${PF}/{glances-doc.html,images/} || die

	distutils-r1_python_install_all
}

pkg_postinst() {
	if [[ -z ${REPLACING_VERSIONS} ]]; then
		elog "${PN} can gain additional functionality with following packages:"
		elog "   dev-python/jinja - export statistics to HTML"
		elog "   app-admin/hddtemp - monitor hard drive temperatures"
		elog "   dev-python/pysnmp - enable Python SNMP library support"
		elog "   dev-python/bottle - for Web server mode"
		elog "   dev-python/matplotlib - for graphical / chart support"
	fi
}