[gentoo-commits] gentoo-x86 commit in dev-python/pytest: pytest-2.7.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-python/pytest: pytest-2.7.0.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     15/04/05 04:36:42

  Modified:             ChangeLog
  Added:                pytest-2.7.0.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.18/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.114                dev-python/pytest/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pytest/ChangeLog?rev=1.114&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pytest/ChangeLog?rev=1.114&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pytest/ChangeLog?r1=1.113&r2=1.114

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pytest/ChangeLog,v
retrieving revision 1.113
retrieving revision 1.114
diff -u -r1.113 -r1.114
--- ChangeLog	3 Apr 2015 20:35:13 -0000	1.113
+++ ChangeLog	5 Apr 2015 04:36:42 -0000	1.114
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pytest
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pytest/ChangeLog,v 1.113 2015/04/03 20:35:13 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pytest/ChangeLog,v 1.114 2015/04/05 04:36:42 patrick Exp $
+
+*pytest-2.7.0 (05 Apr 2015)
+
+  05 Apr 2015; Patrick Lauer <patrick@gentoo.org> +pytest-2.7.0.ebuild:
+  Bump
 
   03 Apr 2015; Mike Frysinger <vapier@gentoo.org> pytest-2.6.3.ebuild:
   Mark s390/sh stable.



1.1                  dev-python/pytest/pytest-2.7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pytest/pytest-2.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pytest/pytest-2.7.0.ebuild?rev=1.1&content-type=text/plain

Index: pytest-2.7.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pytest/pytest-2.7.0.ebuild,v 1.1 2015/04/05 04:36:42 patrick Exp $

EAPI="5"
PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy pypy3 )
inherit distutils-r1

DESCRIPTION="py.test: simple powerful testing with Python"
HOMEPAGE="http://pytest.org/ http://pypi.python.org/pypi/pytest"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="doc test"

# When bumping, please check setup.py for the proper py version
PY_VER="1.4.25"
RDEPEND=">=dev-python/py-${PY_VER}[${PYTHON_USEDEP}]"

#pexpect dep based on https://bitbucket.org/hpk42/pytest/issue/386/tests-fail-with-pexpect-30
DEPEND="${RDEPEND}
	dev-python/setuptools[${PYTHON_USEDEP}]
	test? (
		dev-python/pexpect[${PYTHON_USEDEP}]
		dev-python/pyyaml[${PYTHON_USEDEP}] )
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"

python_prepare_all() {
	# Disable versioning of py.test script to avoid collision with
	# versioning performed by the eclass.
	sed -e "s/return points/return {'py.test': target}/" -i setup.py || die "sed failed"
	grep -qF "py>=${PY_VER}" setup.py || die "Incorrect dev-python/py dependency"

	# Prevent un-needed d'loading
	sed -e "s/'sphinx.ext.intersphinx', //" -i doc/en/conf.py || die
	distutils-r1_python_prepare_all
}

python_compile_all() {
	if use doc; then
		mkdir doc/en/.build || die
		emake -C doc/en html
	fi
}

python_test() {
	"${PYTHON}" "${BUILD_DIR}"/lib/pytest.py \
		--ignore=doc/en/example/nonpython/test_simple.yml \
		|| die "tests failed with ${EPYTHON}"
}

python_install_all() {
	use doc && dohtml -r doc/en/_build/html/
	distutils-r1_python_install_all
}