* [gentoo-commits] gentoo-x86 commit in x11-wm/xmonad: xmonad-0.11.1.ebuild ChangeLog
@ 2015-04-03 4:46 Mark Wright (gienah)
0 siblings, 0 replies; only message in thread
From: Mark Wright (gienah) @ 2015-04-03 4:46 UTC (permalink / raw
To: gentoo-commits
gienah 15/04/03 04:46:15
Modified: ChangeLog
Added: xmonad-0.11.1.ebuild
Log:
Bump xmonad to 0.11.1
(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 618E971F)
Revision Changes Path
1.39 x11-wm/xmonad/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/xmonad/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/xmonad/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/xmonad/ChangeLog?r1=1.38&r2=1.39
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/xmonad/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog 20 Mar 2015 09:02:35 -0000 1.38
+++ ChangeLog 3 Apr 2015 04:46:15 -0000 1.39
@@ -1,6 +1,11 @@
# ChangeLog for x11-wm/xmonad
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/xmonad/ChangeLog,v 1.38 2015/03/20 09:02:35 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/xmonad/ChangeLog,v 1.39 2015/04/03 04:46:15 gienah Exp $
+
+*xmonad-0.11.1 (03 Apr 2015)
+
+ 03 Apr 2015; Mark Wright <gienah@gentoo.org> +xmonad-0.11.1.ebuild:
+ Bump xmonad to 0.11.1
20 Mar 2015; Justin Lecher <jlec@gentoo.org> files/xmonad.desktop:
Fix desktop file
1.1 x11-wm/xmonad/xmonad-0.11.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/xmonad/xmonad-0.11.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/xmonad/xmonad-0.11.1.ebuild?rev=1.1&content-type=text/plain
Index: xmonad-0.11.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/xmonad/xmonad-0.11.1.ebuild,v 1.1 2015/04/03 04:46:15 gienah Exp $
EAPI=5
# ebuild generated by hackport 0.4.4.9999
CABAL_FEATURES="bin lib profile haddock hoogle hscolour"
inherit haskell-cabal
DESCRIPTION="A tiling window manager"
HOMEPAGE="http://xmonad.org"
SRC_URI="mirror://hackage/packages/archive/${PN}/${PV}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0/${PV}"
KEYWORDS="~amd64 ~ppc64 ~sparc ~x86"
IUSE="+default-term no-autorepeat-keys"
RDEPEND="dev-haskell/extensible-exceptions:=[profile?]
dev-haskell/mtl:=[profile?]
>=dev-haskell/utf8-string-0.3:=[profile?]
>=dev-haskell/x11-1.5:=[profile?] <dev-haskell/x11-1.7:=[profile?]
>=dev-lang/ghc-7.4.1:=
"
DEPEND="${RDEPEND}
>=dev-haskell/cabal-1.6
"
PDEPEND="default-term? ( x11-terms/xterm )
x11-apps/xmessage
"
SAMPLE_CONFIG="xmonad.hs"
SAMPLE_CONFIG_LOC="man"
src_prepare() {
epatch "$FILESDIR"/${PN}-0.11-sample.patch
use no-autorepeat-keys && epatch "$FILESDIR"/${PN}-check-repeat.patch
cabal_chdeps \
"utf8-string >= 0.3 && < 0.4" "utf8-string >= 0.3 && < 1.1"
# allow user patches
epatch_user
}
src_install() {
cabal_src_install
echo -e "#!/bin/sh\n/usr/bin/xmonad" > "${T}/${PN}"
exeinto /etc/X11/Sessions
doexe "${T}/${PN}"
insinto /usr/share/xsessions
doins "${FILESDIR}/${PN}.desktop"
doman man/xmonad.1
dohtml man/xmonad.1.html
dodoc CONFIG README
}
pkg_postinst() {
ghc-package_pkg_postinst
elog "A sample ${SAMPLE_CONFIG} configuration file can be found here:"
elog " /usr/share/${PF}/ghc-$(ghc-version)/${SAMPLE_CONFIG_LOC}/${SAMPLE_CONFIG}"
elog "The parameters in this file are the defaults used by xmonad."
elog "To customize xmonad, copy this file to:"
elog " ~/.xmonad/${SAMPLE_CONFIG}"
elog "After editing, use 'mod-q' to dynamically restart xmonad "
elog "(where the 'mod' key defaults to 'Alt')."
elog ""
elog "Read the README or man page for more information, and to see "
elog "other possible configurations go to:"
elog " http://haskell.org/haskellwiki/Xmonad/Config_archive"
elog "Please note that many of these configurations will require the "
elog "x11-wm/xmonad-contrib package to be installed."
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-04-03 4:46 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-04-03 4:46 [gentoo-commits] gentoo-x86 commit in x11-wm/xmonad: xmonad-0.11.1.ebuild ChangeLog Mark Wright (gienah)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox