[gentoo-commits] gentoo-x86 commit in net-analyzer/tcpreplay: tcpreplay-4.1.0.ebuild ChangeLog tcpreplay-3.4.4-r1.ebuild

[gentoo-commits] gentoo-x86 commit in net-analyzer/tcpreplay: tcpreplay-4.1.0.ebuild ChangeLog tcpreplay-3.4.4-r1.ebuild

[Jeroen Roovers (jer)]

jer         15/03/31 05:21:19

  Modified:             ChangeLog
  Added:                tcpreplay-4.1.0.ebuild
  Removed:              tcpreplay-3.4.4-r1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.58                 net-analyzer/tcpreplay/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/tcpreplay/ChangeLog?rev=1.58&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/tcpreplay/ChangeLog?rev=1.58&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/tcpreplay/ChangeLog?r1=1.57&r2=1.58

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/tcpreplay/ChangeLog,v
retrieving revision 1.57
retrieving revision 1.58
diff -u -r1.57 -r1.58
--- ChangeLog	30 Oct 2014 09:54:08 -0000	1.57
+++ ChangeLog	31 Mar 2015 05:21:19 -0000	1.58
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/tcpreplay
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/tcpreplay/ChangeLog,v 1.57 2014/10/30 09:54:08 ago Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/tcpreplay/ChangeLog,v 1.58 2015/03/31 05:21:19 jer Exp $
+
+*tcpreplay-4.1.0 (31 Mar 2015)
+
+  31 Mar 2015; Jeroen Roovers <jer@gentoo.org> -tcpreplay-3.4.4-r1.ebuild,
+  +tcpreplay-4.1.0.ebuild, -files/tcpreplay-3.4.4-crash.patch:
+  Version bump.
 
   30 Oct 2014; Agostino Sarubbo <ago@gentoo.org> tcpreplay-4.0.4.ebuild:
   Stable for x86, wrt bug #509058



1.1                  net-analyzer/tcpreplay/tcpreplay-4.1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/tcpreplay/tcpreplay-4.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/tcpreplay/tcpreplay-4.1.0.ebuild?rev=1.1&content-type=text/plain

Index: tcpreplay-4.1.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/tcpreplay/tcpreplay-4.1.0.ebuild,v 1.1 2015/03/31 05:21:19 jer Exp $

EAPI=5
inherit autotools eutils flag-o-matic

DESCRIPTION="a suite of utilities for editing and replaying previously captured network traffic"
HOMEPAGE="http://tcpreplay.appneta.com/ https://github.com/appneta/tcpreplay"
LICENSE="BSD GPL-3"
SRC_URI="https://github.com/appneta/${PN}/releases/download/v${PV}/${P}.tar.gz"

SLOT="0"
KEYWORDS="~amd64 ~sparc ~x86"
IUSE="debug pcapnav +tcpdump"

DEPEND="
	>=sys-devel/autogen-5.16.2[libopts]
	dev-libs/libdnet
	>=net-libs/libpcap-0.9
	tcpdump? ( net-analyzer/tcpdump )
	pcapnav? ( net-libs/libpcapnav )
"

RDEPEND="${DEPEND}"

DOCS=( docs/{CHANGELOG,CREDIT,HACKING,TODO} )

src_prepare() {
	sed -i \
		-e 's|-O3||g' \
		-e 's|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|g' \
		configure.ac || die
	sed -i \
		-e 's|#include <dnet.h>|#include <dnet/eth.h>|g' \
		src/common/sendpacket.c || die
	sed -i \
		-e 's|@\([A-Z_]*\)@|$(\1)|g' \
		-e '/tcpliveplay_CFLAGS/s|$| $(LDNETINC)|g' \
		-e '/tcpliveplay_LDADD/s|$| $(LDNETLIB)|g' \
		src/Makefile.am || die

	eautoreconf
}

src_configure() {
	# By default it uses static linking. Avoid that, bug 252940
	econf \
		$(use_enable debug) \
		$(use_with pcapnav pcapnav-config /usr/bin/pcapnav-config) \
		$(use_with tcpdump tcpdump /usr/sbin/tcpdump) \
		--disable-local-libopts \
		--enable-dynamic-link \
		--enable-shared \
		--with-libdnet \
		--with-testnic2=lo \
		--with-testnic=lo
}

src_test() {
	if [[ ! ${EUID} -eq 0 ]]; then
		ewarn "Some tests were disabled due to FEATURES=userpriv"
		ewarn "To run all tests issue the following command as root:"
		ewarn " # make -C ${S}/test"
		emake -j1 -C test tcpprep || die "self test failed - see ${S}/test/test.log"
	else
		emake -j1 test || {
			ewarn "Note, that some tests require eth0 iface to be UP." ;
			die "self test failed - see ${S}/test/test.log" ; }
	fi
}