[gentoo-commits] gentoo-x86 commit in dev-python/sip: sip-4.16.7.ebuild ChangeLog sip-4.16.5.ebuild

[gentoo-commits] gentoo-x86 commit in dev-python/sip: sip-4.16.7.ebuild ChangeLog sip-4.16.5.ebuild

[Davide Pesavento (pesa)]

pesa        15/03/29 21:17:15

  Modified:             ChangeLog
  Added:                sip-4.16.7.ebuild
  Removed:              sip-4.16.5.ebuild
  Log:
  Version bump, remove old.
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0xDADED6B2671CB57D!)

Revision  Changes    Path
1.305                dev-python/sip/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sip/ChangeLog?rev=1.305&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sip/ChangeLog?rev=1.305&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sip/ChangeLog?r1=1.304&r2=1.305

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/sip/ChangeLog,v
retrieving revision 1.304
retrieving revision 1.305
diff -u -r1.304 -r1.305
--- ChangeLog	2 Mar 2015 03:14:52 -0000	1.304
+++ ChangeLog	29 Mar 2015 21:17:15 -0000	1.305
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/sip
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/sip/ChangeLog,v 1.304 2015/03/02 03:14:52 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sip/ChangeLog,v 1.305 2015/03/29 21:17:15 pesa Exp $
+
+*sip-4.16.7 (29 Mar 2015)
+
+  29 Mar 2015; Davide Pesavento <pesa@gentoo.org> +sip-4.16.7.ebuild,
+  -sip-4.16.5.ebuild:
+  Version bump, remove old.
 
 *sip-4.16.6 (02 Mar 2015)
 



1.1                  dev-python/sip/sip-4.16.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sip/sip-4.16.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sip/sip-4.16.7.ebuild?rev=1.1&content-type=text/plain

Index: sip-4.16.7.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/sip/sip-4.16.7.ebuild,v 1.1 2015/03/29 21:17:15 pesa Exp $

EAPI=5
PYTHON_COMPAT=( python{2_7,3_3,3_4} )

inherit eutils python-r1 toolchain-funcs

DESCRIPTION="Python extension module generator for C and C++ libraries"
HOMEPAGE="http://www.riverbankcomputing.com/software/sip/intro https://pypi.python.org/pypi/SIP"
LICENSE="|| ( GPL-2 GPL-3 SIP )"

if [[ ${PV} == *9999* ]]; then
	# live version from mercurial repo
	EHG_REPO_URI="http://www.riverbankcomputing.com/hg/sip"
	inherit mercurial
elif [[ ${PV} == *_pre* ]]; then
	# development snapshot
	HG_REVISION=
	MY_P=${PN}-${PV%_pre*}-snapshot-${HG_REVISION}
	SRC_URI="http://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
	S=${WORKDIR}/${MY_P}
else
	# official release
	SRC_URI="mirror://sourceforge/pyqt/${P}.tar.gz"
fi

# Sub-slot based on SIP_API_MAJOR_NR from siplib/sip.h.in
SLOT="0/11"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="debug doc"

DEPEND="${PYTHON_DEPS}"
RDEPEND="${DEPEND}"

[[ ${PV} == *9999* ]] && DEPEND+="
	=dev-lang/python-2*
	sys-devel/bison
	sys-devel/flex
	doc? ( dev-python/sphinx[$(python_gen_usedep 'python2*')] )
"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-4.15.5-darwin.patch

	if [[ ${PV} == *9999* ]]; then
		python2 build.py prepare || die
		if use doc; then
			python2 build.py doc || die
		fi
	fi

	# Sub-slot sanity check
	local sub_slot=${SLOT#*/}
	local sip_api_major_nr=$(sed -nre 's:^#define SIP_API_MAJOR_NR\s+([0-9]+):\1:p' siplib/sip.h.in)
	if [[ ${sub_slot} != ${sip_api_major_nr} ]]; then
		eerror
		eerror "Ebuild sub-slot (${sub_slot}) does not match SIP_API_MAJOR_NR (${sip_api_major_nr})"
		eerror "Please update SLOT variable as follows:"
		eerror "    SLOT=\"${SLOT%%/*}/${sip_api_major_nr}\""
		eerror
		die "sub-slot sanity check failed"
	fi
}

src_configure() {
	configuration() {
		local myconf=(
			"${PYTHON}"
			"${S}"/configure.py
			--destdir="$(python_get_sitedir)"
			--incdir="$(python_get_includedir)"
			$(use debug && echo --debug)
			AR="$(tc-getAR) cqs"
			CC="$(tc-getCC)"
			CFLAGS="${CFLAGS}"
			CFLAGS_RELEASE=
			CXX="$(tc-getCXX)"
			CXXFLAGS="${CXXFLAGS}"
			CXXFLAGS_RELEASE=
			LINK="$(tc-getCXX)"
			LINK_SHLIB="$(tc-getCXX)"
			LFLAGS="${LDFLAGS}"
			LFLAGS_RELEASE=
			RANLIB=
			STRIP=
		)
		echo "${myconf[@]}"
		"${myconf[@]}" || die
	}
	python_foreach_impl run_in_build_dir configuration
}

src_compile() {
	python_foreach_impl run_in_build_dir default
}

src_install() {
	installation() {
		emake DESTDIR="${D}" install
		python_optimize
	}
	python_foreach_impl run_in_build_dir installation

	dodoc ChangeLog NEWS
	use doc && dodoc -r doc/html
}