[gentoo-commits] gentoo-x86 commit in app-accessibility/caribou: caribou-0.4.18.ebuild ChangeLog caribou-0.4.16.ebuild

[gentoo-commits] gentoo-x86 commit in app-accessibility/caribou: caribou-0.4.18.ebuild ChangeLog caribou-0.4.16.ebuild

[Pacho Ramos (pacho)]

pacho       15/03/28 09:00:26

  Modified:             ChangeLog
  Added:                caribou-0.4.18.ebuild
  Removed:              caribou-0.4.16.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.40                 app-accessibility/caribou/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/caribou/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/caribou/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/caribou/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-accessibility/caribou/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	15 Mar 2015 13:13:49 -0000	1.39
+++ ChangeLog	28 Mar 2015 09:00:26 -0000	1.40
@@ -1,6 +1,12 @@
 # ChangeLog for app-accessibility/caribou
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-accessibility/caribou/ChangeLog,v 1.39 2015/03/15 13:13:49 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/caribou/ChangeLog,v 1.40 2015/03/28 09:00:26 pacho Exp $
+
+*caribou-0.4.18 (28 Mar 2015)
+
+  28 Mar 2015; Pacho Ramos <pacho@gentoo.org> +caribou-0.4.18.ebuild,
+  -caribou-0.4.16.ebuild:
+  Version bump, drop old
 
   15 Mar 2015; Pacho Ramos <pacho@gentoo.org> caribou-0.4.17.ebuild:
   x86 stable, bug 534012



1.1                  app-accessibility/caribou/caribou-0.4.18.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/caribou/caribou-0.4.18.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-accessibility/caribou/caribou-0.4.18.ebuild?rev=1.1&content-type=text/plain

Index: caribou-0.4.18.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-accessibility/caribou/caribou-0.4.18.ebuild,v 1.1 2015/03/28 09:00:26 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="xml"

inherit gnome2 python-r1

DESCRIPTION="Input assistive technology intended for switch and pointer users"
HOMEPAGE="https://wiki.gnome.org/Projects/Caribou"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"

IUSE=""
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

COMMON_DEPEND="
	app-accessibility/at-spi2-core
	>=dev-python/pygobject-2.90.3:3[${PYTHON_USEDEP}]
	>=x11-libs/gtk+-3:3[introspection]
	x11-libs/gtk+:2
	>=dev-libs/gobject-introspection-0.10.7:=
	dev-libs/libgee:0.8
	dev-libs/libxml2
	>=media-libs/clutter-1.5.11:1.0[introspection]
	x11-libs/libX11
	x11-libs/libxklavier
	x11-libs/libXtst
"
# gsettings-desktop-schemas is needed for the 'toolkit-accessibility' key
# pyatspi-2.1.90 needed to run caribou if pygobject:3 is installed
# librsvg needed to load svg images in css styles
RDEPEND="${COMMON_DEPEND}
	dev-libs/glib[dbus]
	>=dev-python/pyatspi-2.1.90[${PYTHON_USEDEP}]
	>=gnome-base/gsettings-desktop-schemas-3
	gnome-base/librsvg:2
	sys-apps/dbus
"
DEPEND="${COMMON_DEPEND}
	dev-libs/libxslt
	>=dev-util/intltool-0.35.5
	virtual/pkgconfig
"

src_prepare() {
	# delete custom PYTHONPATH, useless on Gentoo and potential bug source
	# + caribou is python2 only so fix the shell scripts
	sed -e '/export PYTHONPATH=.*python/ d' \
		-e "s:@PYTHON@:${EPREFIX}/usr/bin/python2:" \
		-i bin/{antler-keyboard,caribou-preferences}.in ||
		die "sed failed"

	gnome2_src_prepare

	prepare_caribou() {
		mkdir -p "${BUILD_DIR}" || die
	}
	python_foreach_impl prepare_caribou
}

src_configure() {
	ECONF_SOURCE="${S}" python_foreach_impl run_in_build_dir \
		gnome2_src_configure \
			--disable-docs \
			--disable-static \
			--enable-gtk3-module \
			--enable-gtk2-module \
			VALAC=$(type -P true)
	# vala is not needed for tarball builds, but configure checks for it...
}

src_compile() {
	python_foreach_impl run_in_build_dir gnome2_src_compile
}

src_test() {
	python_foreach_impl run_in_build_dir default
}

src_install() {
	python_foreach_impl run_in_build_dir gnome2_src_install
	dodoc AUTHORS NEWS README # ChangeLog simply points to git log
}