[gentoo-commits] gentoo-x86 commit in dev-libs/ntl: ntl-8.1.2.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-libs/ntl: ntl-8.1.2.ebuild ChangeLog

[Thomas Kahle (tomka)]

tomka       15/03/26 10:19:22

  Modified:             ChangeLog
  Added:                ntl-8.1.2.ebuild
  Log:
  bump to 8.1.2
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 565C32BC)

Revision  Changes    Path
1.26                 dev-libs/ntl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ntl/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ntl/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ntl/ChangeLog?r1=1.25&r2=1.26

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/ntl/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -u -r1.25 -r1.26
--- ChangeLog	19 Jun 2014 13:08:44 -0000	1.25
+++ ChangeLog	26 Mar 2015 10:19:22 -0000	1.26
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/ntl
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/ntl/ChangeLog,v 1.25 2014/06/19 13:08:44 jauhien Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/ntl/ChangeLog,v 1.26 2015/03/26 10:19:22 tomka Exp $
+
+*ntl-8.1.2 (26 Mar 2015)
+
+  26 Mar 2015; Thomas Kahle <tomka@gentoo.org>
+  +files/ntl-8.1.2-sanitize-makefile.patch, +ntl-8.1.2.ebuild:
+  bump to 8.1.2
 
   19 Jun 2014; Jauhien Piatlicki <jauhien@gentoo.org>
   +files/ntl-5.5.2-shared-r1.patch:



1.1                  dev-libs/ntl/ntl-8.1.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ntl/ntl-8.1.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/ntl/ntl-8.1.2.ebuild?rev=1.1&content-type=text/plain

Index: ntl-8.1.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/ntl/ntl-8.1.2.ebuild,v 1.1 2015/03/26 10:19:22 tomka Exp $

EAPI=5
inherit toolchain-funcs eutils multilib flag-o-matic

DESCRIPTION="High-performance and portable Number Theory C++ library"
HOMEPAGE="http://shoup.net/ntl/"
SRC_URI="http://www.shoup.net/ntl/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-macos"
IUSE="doc static-libs test"

RDEPEND=">=dev-libs/gmp-4.3
	>=dev-libs/gf2x-0.9"
DEPEND="${RDEPEND}
	dev-lang/perl"

S="${WORKDIR}/${P}/src"

src_prepare() {
	# fix parallel make
	sed -i -e "s/make/make ${MAKEOPTS}/g" WizardAux || die
	cd ..
	# enable compatibility with singular
	epatch "$FILESDIR/${PN}-6.0.0-singular.patch"
	# sanitize the makefile and allow the building of shared library
	epatch "$FILESDIR/${PN}-8.1.2-sanitize-makefile.patch"
	replace-flags -O[3-9] -O2
}

src_configure() {
	perl DoConfig \
		PREFIX="${EPREFIX}"/usr \
		CXXFLAGS="${CXXFLAGS}" \
		LDFLAGS="${LDFLAGS}" \
		CXX="$(tc-getCXX)" \
		AR="$(tc-getAR)" \
		RANLIB="$(tc-getRANLIB)" \
		NTL_GMP_LIP=on NTL_GF2X_LIB=on \
		|| die "DoConfig failed"
}

src_compile() {
	# split the targets to allow parallel make to run properly
	emake setup1 setup2 || die "emake setup failed"
	emake setup3 || die "emake setup failed"
	sh Wizard on || die "Tuning wizard failed"
	if use static-libs || use test; then
		emake ntl.a  || die "emake static failed"
	fi
	local trg=so
	[[ ${CHOST} == *-darwin* ]] && trg=dylib
	emake shared${trg} || die "emake shared failed"
}

src_install() {
	if use static-libs; then
		newlib.a ntl.a libntl.a || die "installation of static library failed"
	fi
	dolib.so lib*$(get_libname) || die "installation of shared library failed"

	cd ..
	insinto /usr/include
	doins -r include/NTL || die "installation of the headers failed"

	dodoc README
	if use doc ; then
		dodoc doc/*.txt || die
		dohtml doc/* || die
	fi
}