* [gentoo-commits] gentoo-x86 commit in sys-apps/file: file-9999.ebuild file-5.22-r1.ebuild ChangeLog
@ 2015-03-21 9:42 Michal Gorny (mgorny)
0 siblings, 0 replies; only message in thread
From: Michal Gorny (mgorny) @ 2015-03-21 9:42 UTC (permalink / raw
To: gentoo-commits
mgorny 15/03/21 09:42:37
Modified: file-9999.ebuild ChangeLog
Added: file-5.22-r1.ebuild
Log:
EAPI bump, bug #543160.
(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)
Revision Changes Path
1.9 sys-apps/file/file-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/file-9999.ebuild?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/file-9999.ebuild?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/file-9999.ebuild?r1=1.8&r2=1.9
Index: file-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/file/file-9999.ebuild,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- file-9999.ebuild 7 Sep 2014 18:55:10 -0000 1.8
+++ file-9999.ebuild 21 Mar 2015 09:42:37 -0000 1.9
@@ -1,9 +1,9 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/file/file-9999.ebuild,v 1.8 2014/09/07 18:55:10 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/file/file-9999.ebuild,v 1.9 2015/03/21 09:42:37 mgorny Exp $
-EAPI="4"
-PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3,3_4} pypy2_0 )
+EAPI="5"
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
DISTUTILS_OPTIONAL=1
inherit eutils distutils-r1 libtool toolchain-funcs multilib-minimal
@@ -25,7 +25,9 @@
IUSE="python static-libs zlib"
DEPEND="python? ( ${PYTHON_DEPS} )
- zlib? ( sys-libs/zlib )"
+ zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
+ abi_x86_32? ( !<=app-emulation/emul-linux-x86-baselibs-20131008-r21
+ !app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)] )"
RDEPEND="${DEPEND}
python? ( !dev-python/python-magic )"
1.310 sys-apps/file/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/ChangeLog?rev=1.310&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/ChangeLog?rev=1.310&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/ChangeLog?r1=1.309&r2=1.310
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/file/ChangeLog,v
retrieving revision 1.309
retrieving revision 1.310
diff -u -r1.309 -r1.310
--- ChangeLog 5 Feb 2015 22:41:25 -0000 1.309
+++ ChangeLog 21 Mar 2015 09:42:37 -0000 1.310
@@ -1,6 +1,12 @@
# ChangeLog for sys-apps/file
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/file/ChangeLog,v 1.309 2015/02/05 22:41:25 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/file/ChangeLog,v 1.310 2015/03/21 09:42:37 mgorny Exp $
+
+*file-5.22-r1 (21 Mar 2015)
+
+ 21 Mar 2015; Michał Górny <mgorny@gentoo.org> +file-5.22-r1.ebuild,
+ file-9999.ebuild:
+ EAPI bump, bug #543160.
05 Feb 2015; Mike Frysinger <vapier@gentoo.org> file-5.22.ebuild:
Mark arm64/m68/s390/sh stable.
1.1 sys-apps/file/file-5.22-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/file-5.22-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/file/file-5.22-r1.ebuild?rev=1.1&content-type=text/plain
Index: file-5.22-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/file/file-5.22-r1.ebuild,v 1.1 2015/03/21 09:42:37 mgorny Exp $
EAPI="5"
PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
DISTUTILS_OPTIONAL=1
inherit eutils distutils-r1 libtool toolchain-funcs multilib-minimal
if [[ ${PV} == "9999" ]] ; then
EGIT_REPO_URI="git://github.com/glensc/file.git"
inherit autotools git-r3
else
SRC_URI="ftp://ftp.astron.com/pub/file/${P}.tar.gz
ftp://ftp.gw.com/mirrors/pub/unix/file/${P}.tar.gz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
fi
DESCRIPTION="identify a file's format by scanning binary data for patterns"
HOMEPAGE="http://www.darwinsys.com/file/"
LICENSE="BSD-2"
SLOT="0"
IUSE="python static-libs zlib"
DEPEND="python? ( ${PYTHON_DEPS} )
zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
abi_x86_32? ( !<=app-emulation/emul-linux-x86-baselibs-20131008-r21
!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)] )"
RDEPEND="${DEPEND}
python? ( !dev-python/python-magic )"
src_prepare() {
[[ ${PV} == "9999" ]] && eautoreconf
elibtoolize
# don't let python README kill main README #60043
mv python/README{,.python}
}
multilib_src_configure() {
ECONF_SOURCE=${S} \
ac_cv_header_zlib_h=$(usex zlib) \
ac_cv_lib_z_gzopen=$(usex zlib)
econf \
$(use_enable static-libs static)
}
src_configure() {
# when cross-compiling, we need to build up our own file
# because people often don't keep matching host/target
# file versions #362941
if tc-is-cross-compiler && ! ROOT=/ has_version ~${CATEGORY}/${P} ; then
mkdir -p "${WORKDIR}"/build
cd "${WORKDIR}"/build
tc-export_build_env BUILD_C{C,XX}
ECONF_SOURCE=${S} \
ac_cv_header_zlib_h=no \
ac_cv_lib_z_gzopen=no \
CHOST=${CBUILD} \
CFLAGS=${BUILD_CFLAGS} \
CXXFLAGS=${BUILD_CXXFLAGS} \
CPPFLAGS=${BUILD_CPPFLAGS} \
LDFLAGS="${BUILD_LDFLAGS} -static" \
CC=${BUILD_CC} \
CXX=${BUILD_CXX} \
econf --disable-shared
fi
multilib-minimal_src_configure
}
multilib_src_compile() {
if multilib_is_native_abi ; then
emake
else
emake -C src libmagic.la
fi
}
src_compile() {
if tc-is-cross-compiler && ! ROOT=/ has_version ~${CATEGORY}/${P} ; then
emake -C "${WORKDIR}"/build/src file
PATH="${WORKDIR}/build/src:${PATH}"
fi
multilib-minimal_src_compile
use python && cd python && distutils-r1_src_compile
}
multilib_src_install() {
if multilib_is_native_abi ; then
default
else
emake -C src install-{includeHEADERS,libLTLIBRARIES} DESTDIR="${D}"
fi
}
multilib_src_install_all() {
dodoc ChangeLog MAINT README
use python && cd python && distutils-r1_src_install
prune_libtool_files
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-03-21 9:42 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-03-21 9:42 [gentoo-commits] gentoo-x86 commit in sys-apps/file: file-9999.ebuild file-5.22-r1.ebuild ChangeLog Michal Gorny (mgorny)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox