[gentoo-commits] gentoo-x86 commit in net-misc/stunnel: stunnel-5.13.ebuild ChangeLog stunnel-5.12.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/stunnel: stunnel-5.13.ebuild ChangeLog stunnel-5.12.ebuild

[Anthony G. Basile (blueness)]

blueness    15/03/20 16:16:04

  Modified:             ChangeLog
  Added:                stunnel-5.13.ebuild
  Removed:              stunnel-5.12.ebuild
  Log:
  Follow upstream's rapid version bump.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

Revision  Changes    Path
1.211                net-misc/stunnel/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/ChangeLog?rev=1.211&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/ChangeLog?rev=1.211&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/ChangeLog?r1=1.210&r2=1.211

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v
retrieving revision 1.210
retrieving revision 1.211
diff -u -r1.210 -r1.211
--- ChangeLog	19 Mar 2015 20:18:38 -0000	1.210
+++ ChangeLog	20 Mar 2015 16:16:04 -0000	1.211
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/stunnel
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v 1.210 2015/03/19 20:18:38 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/ChangeLog,v 1.211 2015/03/20 16:16:04 blueness Exp $
+
+*stunnel-5.13 (20 Mar 2015)
+
+  20 Mar 2015; Anthony G. Basile <blueness@gentoo.org> +stunnel-5.13.ebuild,
+  -stunnel-5.12.ebuild:
+  Follow upstream's rapid version bump.
 
   19 Mar 2015; Anthony G. Basile <blueness@gentoo.org> ChangeLog:
   Fix failed gpg signiture



1.1                  net-misc/stunnel/stunnel-5.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/stunnel-5.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/stunnel/stunnel-5.13.ebuild?rev=1.1&content-type=text/plain

Index: stunnel-5.13.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/stunnel/stunnel-5.13.ebuild,v 1.1 2015/03/20 16:16:04 blueness Exp $

EAPI="5"

inherit ssl-cert eutils systemd user

DESCRIPTION="TLS/SSL - Port Wrapper"
HOMEPAGE="http://www.stunnel.org/index.html"
SRC_URI="ftp://ftp.stunnel.org/stunnel/archive/${PV%%.*}.x/${P}.tar.gz
	http://www.usenix.org.uk/mirrors/stunnel/archive/${PV%%.*}.x/${P}.tar.gz
	http://ftp.nluug.nl/pub/networking/stunnel/archive/${PV%%.*}.x/${P}.tar.gz
	http://www.namesdir.com/mirrors/stunnel/archive/${PV%%.*}.x/${P}.tar.gz
	http://stunnel.cybermirror.org/archive/${PV%%.*}.x/${P}.tar.gz
	http://mirrors.zerg.biz/stunnel/archive/${PV%%.*}.x/${P}.tar.gz
	ftp://mirrors.go-parts.com/stunnel/archive/${PV%%.*}.x/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="ipv6 selinux tcpd"

DEPEND="tcpd? ( sys-apps/tcp-wrappers )
	dev-libs/openssl"
RDEPEND="${DEPEND}
	selinux? ( sec-policy/selinux-stunnel )"

pkg_setup() {
	enewgroup stunnel
	enewuser stunnel -1 -1 -1 stunnel
}

src_prepare() {
	# Hack away generation of certificate
	sed -i -e "s/^install-data-local:/do-not-run-this:/" \
		tools/Makefile.in || die "sed failed"
}

src_configure() {
	econf \
		$(use_enable ipv6) \
		$(use_enable tcpd libwrap) \
		--with-ssl="${EPREFIX}"/usr \
		--disable-fips
}

src_install() {
	emake DESTDIR="${D}" install
	rm -rf "${ED}"/usr/share/doc/${PN}
	rm -f "${ED}"/etc/stunnel/stunnel.conf-sample "${ED}"/usr/bin/stunnel3 \
		"${ED}"/usr/share/man/man8/stunnel.{fr,pl}.8

	# The binary was moved to /usr/bin with 4.21,
	# symlink for backwards compatibility
	dosym ../bin/stunnel /usr/sbin/stunnel

	dodoc AUTHORS BUGS CREDITS PORTS README TODO ChangeLog
	dohtml doc/stunnel.html doc/en/VNC_StunnelHOWTO.html tools/ca.html \
		tools/importCA.html

	insinto /etc/stunnel
	doins "${FILESDIR}"/stunnel.conf
	doinitd "${FILESDIR}"/stunnel

	systemd_dounit "${S}/tools/stunnel.service"
	systemd_newtmpfilesd "${FILESDIR}"/stunnel.tmpfiles.conf stunnel.conf
}

pkg_postinst() {
	if [ ! -f "${EROOT}"/etc/stunnel/stunnel.key ]; then
		install_cert /etc/stunnel/stunnel
		chown stunnel:stunnel "${EROOT}"/etc/stunnel/stunnel.{crt,csr,key,pem}
		chmod 0640 "${EROOT}"/etc/stunnel/stunnel.{crt,csr,key,pem}
	fi

	einfo "If you want to run multiple instances of stunnel, create a new config"
	einfo "file ending with .conf in /etc/stunnel/. **Make sure** you change "
	einfo "\'pid= \' with a unique filename."
}