[gentoo-commits] gentoo-x86 commit in net-libs/rb_libtorrent: rb_libtorrent-0.16.19.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-libs/rb_libtorrent: rb_libtorrent-0.16.19.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    15/03/17 20:30:26

  Modified:             ChangeLog
  Added:                rb_libtorrent-0.16.19.ebuild
  Log:
  Version bump. Bug #542196
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 09BF4F54C2BA7F3C!)

Revision  Changes    Path
1.190                net-libs/rb_libtorrent/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/ChangeLog?rev=1.190&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/ChangeLog?rev=1.190&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/ChangeLog?r1=1.189&r2=1.190

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v
retrieving revision 1.189
retrieving revision 1.190
diff -u -r1.189 -r1.190
--- ChangeLog	17 Mar 2015 20:08:16 -0000	1.189
+++ ChangeLog	17 Mar 2015 20:30:26 -0000	1.190
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/rb_libtorrent
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v 1.189 2015/03/17 20:08:16 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v 1.190 2015/03/17 20:30:26 hwoarang Exp $
+
+*rb_libtorrent-0.16.19 (17 Mar 2015)
+
+  17 Mar 2015; Markos Chandras <hwoarang@gentoo.org>
+  +rb_libtorrent-0.16.19.ebuild:
+  Version bump. Bug #542196
 
   17 Mar 2015; Markos Chandras <hwoarang@gentoo.org>
   rb_libtorrent-0.16.17-r2.ebuild:



1.1                  net-libs/rb_libtorrent/rb_libtorrent-0.16.19.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.16.19.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.16.19.ebuild?rev=1.1&content-type=text/plain

Index: rb_libtorrent-0.16.19.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.16.19.ebuild,v 1.1 2015/03/17 20:30:26 hwoarang Exp $

EAPI=5
PYTHON_COMPAT=( python{2_7,3_3,3_4} )
PYTHON_REQ_USE="threads"

inherit multilib python-r1 versionator

MY_P=${P/rb_/}
MY_P=${MY_P/torrent/torrent-rasterbar}
S=${WORKDIR}/${MY_P}

DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
HOMEPAGE="http://www.rasterbar.com/products/libtorrent/"
SRC_URI="mirror://sourceforge/libtorrent/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc examples python ssl static-libs test"
RESTRICT="test"

RDEPEND=">=dev-libs/boost-1.48:=[threads]
	sys-libs/zlib
	examples? ( !net-p2p/mldonkey )
	ssl? ( dev-libs/openssl:= )
	python? (
		${PYTHON_DEPS}
		dev-libs/boost[python,${PYTHON_USEDEP}]
	)"
DEPEND="${RDEPEND}
	>=sys-devel/libtool-2.2"

REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

src_prepare() {
	use python && python_copy_sources
}

src_configure() {
	local myconf=(
		--disable-silent-rules # bug 441842
		$(use_enable debug)
		$(use_enable test tests)
		$(use_enable examples)
		$(use_enable ssl encryption)
		$(use_enable static-libs static)
		--with-boost-libdir=/usr/$(get_libdir)
	)

	use debug && myconf+=( --enable-logging=verbose )

	econf "${myconf[@]}" --disable-python-binding

	if use python; then
		python_configure() {
			run_in_build_dir econf "${myconf[@]}" --enable-python-binding --with-boost-python=boost_python-${EPYTHON#python}
		}

		python_foreach_impl python_configure
	fi
}

src_install() {
	emake DESTDIR="${D}" install

	if use python; then
		python_install() {
			emake -C "${BUILD_DIR}"/bindings/python \
				DESTDIR="${D}" install
		}

		python_foreach_impl python_install
	fi

	use static-libs || find "${D}" -name '*.la' -exec rm -f {} +
	dodoc ChangeLog AUTHORS NEWS README
	if use doc; then
		dohtml docs/*
	fi
}