public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in dev-libs/glib: glib-2.42.2.ebuild ChangeLog
@ 2015-02-26 19:24 Pacho Ramos (pacho)
  0 siblings, 0 replies; 6+ messages in thread
From: Pacho Ramos (pacho) @ 2015-02-26 19:24 UTC (permalink / raw
  To: gentoo-commits

pacho       15/02/26 19:24:49

  Modified:             ChangeLog
  Added:                glib-2.42.2.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.640                dev-libs/glib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.640&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.640&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.639&r2=1.640

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.639
retrieving revision 1.640
diff -u -r1.639 -r1.640
--- ChangeLog	11 Feb 2015 04:20:44 -0000	1.639
+++ ChangeLog	26 Feb 2015 19:24:49 -0000	1.640
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.639 2015/02/11 04:20:44 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.640 2015/02/26 19:24:49 pacho Exp $
+
+*glib-2.42.2 (26 Feb 2015)
+
+  26 Feb 2015; Pacho Ramos <pacho@gentoo.org> +glib-2.42.2.ebuild:
+  Version bump, drop old
 
   11 Feb 2015; Mike Frysinger <vapier@gentoo.org> glib-2.40.2.ebuild:
   Mark arm64/m68k/s390/sh stable.



1.1                  dev-libs/glib/glib-2.42.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?rev=1.1&content-type=text/plain

Index: glib-2.42.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v 1.1 2015/02/26 19:24:49 pacho Exp $

# Until bug #537330 glib is a reverse dependency of pkgconfig and, then
# adding new dependencies end up making stage3 to grow. Every addition needs
# then to be think very closely.

EAPI="5"
PYTHON_COMPAT=( python2_7 )
# Building with --disable-debug highly unrecommended.  It will build glib in
# an unusable form as it disables some commonly used API.  Please do not
# convert this to the use_enable form, as it results in a broken build.
GCONF_DEBUG="yes"
# Completely useless with or without USE static-libs, people need to use
# pkg-config
GNOME2_LA_PUNT="yes"

inherit autotools bash-completion-r1 gnome2 libtool eutils flag-o-matic	multilib \
	pax-utils python-r1 toolchain-funcs versionator virtualx linux-info multilib-minimal

DESCRIPTION="The GLib library of C routines"
HOMEPAGE="http://www.gtk.org/"
SRC_URI="${SRC_URI}
	http://pkgconfig.freedesktop.org/releases/pkg-config-0.28.tar.gz" # pkg.m4 for eautoreconf

LICENSE="LGPL-2+"
SLOT="2"
IUSE="dbus fam kernel_linux +mime selinux static-libs systemtap test utils xattr"
REQUIRED_USE="
	utils? ( ${PYTHON_REQUIRED_USE} )
	test? ( ${PYTHON_REQUIRED_USE} )
"

KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"

RDEPEND="
	!<dev-util/gdbus-codegen-${PV}
	>=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
	>=virtual/libffi-3.0.13-r1[${MULTILIB_USEDEP}]
	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
	|| (
		>=dev-libs/elfutils-0.142
		>=dev-libs/libelf-0.8.12
		>=sys-freebsd/freebsd-lib-9.2_rc1
		)
	selinux? ( >=sys-libs/libselinux-2.2.2-r5[${MULTILIB_USEDEP}] )
	xattr? ( >=sys-apps/attr-2.4.47-r1[${MULTILIB_USEDEP}] )
	fam? ( >=virtual/fam-0-r1[${MULTILIB_USEDEP}] )
	utils? (
		${PYTHON_DEPS}
		>=dev-util/gdbus-codegen-${PV}[${PYTHON_USEDEP}] )
	abi_x86_32? (
		!<=app-emulation/emul-linux-x86-baselibs-20130224-r9
		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
	)
"
DEPEND="${RDEPEND}
	app-text/docbook-xml-dtd:4.1.2
	>=dev-libs/libxslt-1.0
	>=sys-devel/gettext-0.11
	>=dev-util/gtk-doc-am-1.20
	systemtap? ( >=dev-util/systemtap-1.3 )
	test? (
		sys-devel/gdb
		${PYTHON_DEPS}
		>=dev-util/gdbus-codegen-${PV}[${PYTHON_USEDEP}]
		>=sys-apps/dbus-1.2.14 )
	!<dev-util/gtk-doc-1.15-r2
"
# gobject-introspection blocker to ensure people don't mix
# different g-i and glib major versions

PDEPEND="!<gnome-base/gvfs-1.6.4-r990
	dbus? ( gnome-base/dconf )
	mime? ( x11-misc/shared-mime-info )
"
# shared-mime-info needed for gio/xdgmime, bug #409481
# dconf is needed to be able to save settings, bug #498436
# Earlier versions of gvfs do not work with glib

pkg_setup() {
	if use kernel_linux ; then
		CONFIG_CHECK="~INOTIFY_USER"
		if use test; then
			CONFIG_CHECK="~IPV6"
			WARNING_IPV6="Your kernel needs IPV6 support for running some tests, skipping them."
			export IPV6_DISABLED="yes"
		fi
		linux-info_pkg_setup
	fi
}

src_prepare() {
	# Prevent build failure in stage3 where pkgconfig is not available, bug #481056
	mv -f "${WORKDIR}"/pkg-config-*/pkg.m4 "${S}"/m4macros/ || die

	if use test; then
		# Disable tests requiring dev-util/desktop-file-utils when not installed, bug #286629, upstream bug #629163
		if ! has_version dev-util/desktop-file-utils ; then
			ewarn "Some tests will be skipped due dev-util/desktop-file-utils not being present on your system,"
			ewarn "think on installing it to get these tests run."
			sed -i -e "/appinfo\/associations/d" gio/tests/appinfo.c || die
			sed -i -e "/desktop-app-info\/default/d" gio/tests/desktop-app-info.c || die
			sed -i -e "/desktop-app-info\/fallback/d" gio/tests/desktop-app-info.c || die
			sed -i -e "/desktop-app-info\/lastused/d" gio/tests/desktop-app-info.c || die
		fi

		# gdesktopappinfo requires existing terminal (gnome-terminal or any
		# other), falling back to xterm if one doesn't exist
		if ! has_version x11-terms/xterm && ! has_version x11-terms/gnome-terminal ; then
			ewarn "Some tests will be skipped due to missing terminal program"
			sed -i -e "/appinfo\/launch/d" gio/tests/appinfo.c || die
		fi

		# Disable tests requiring dbus-python and pygobject; bugs #349236, #377549, #384853
		if ! has_version dev-python/dbus-python || ! has_version 'dev-python/pygobject:3' ; then
			ewarn "Some tests will be skipped due to dev-python/dbus-python or dev-python/pygobject:3"
			ewarn "not being present on your system, think on installing them to get these tests run."
			sed -i -e "/connection\/filter/d" gio/tests/gdbus-connection.c || die
			sed -i -e "/connection\/large_message/d" gio/tests/gdbus-connection-slow.c || die
			sed -i -e "/gdbus\/proxy/d" gio/tests/gdbus-proxy.c || die
			sed -i -e "/gdbus\/proxy-well-known-name/d" gio/tests/gdbus-proxy-well-known-name.c || die
			sed -i -e "/gdbus\/introspection-parser/d" gio/tests/gdbus-introspection.c || die
			sed -i -e "/g_test_add_func/d" gio/tests/gdbus-threading.c || die
			sed -i -e "/gdbus\/method-calls-in-thread/d" gio/tests/gdbus-threading.c || die
			# needed to prevent gdbus-threading from asserting
			ln -sfn $(type -P true) gio/tests/gdbus-testserver.py
		fi

		# Some tests need ipv6, upstream bug #667468
		if [[ -n "${IPV6_DISABLED}" ]]; then
			sed -i -e "/gdbus\/peer-to-peer/d" gio/tests/gdbus-peer.c || die
			sed -i -e "/gdbus\/delayed-message-processing/d" gio/tests/gdbus-peer.c || die
			sed -i -e "/gdbus\/nonce-tcp/d" gio/tests/gdbus-peer.c || die
		fi

		# thread test fails, upstream bug #679306
		# FIXME: we need to check if it's still failing as upstream thinks something
		# is wrong in our setups
		#epatch "${FILESDIR}/${PN}-2.34.0-testsuite-skip-thread4.patch"

		# This test is prone to fail, bug #504024, upstream bug #723719
		sed -i -e '/gdbus-close-pending/d' gio/tests/Makefile.am || die
	else
		# Don't build tests, also prevents extra deps, bug #512022
		sed -i -e 's/ tests//' {.,gio,glib}/Makefile.am || die
	fi

	# gdbus-codegen is a separate package
	epatch "${FILESDIR}/${PN}-2.40.0-external-gdbus-codegen.patch"

	# leave python shebang alone
	sed -e '/${PYTHON}/d' \
		-i glib/Makefile.{am,in} || die

	# Gentoo handles completions in a different directory
	sed -i "s|^completiondir =.*|completiondir = $(get_bashcompdir)|" \
		gio/Makefile.am || die

	epatch_user

	# Also needed to prevent cross-compile failures, see bug #267603
	eautoreconf

	gnome2_src_prepare

	epunt_cxx
}

multilib_src_configure() {
	# Avoid circular depend with dev-util/pkgconfig and
	# native builds (cross-compiles won't need pkg-config
	# in the target ROOT to work here)
	if ! tc-is-cross-compiler && ! $(tc-getPKG_CONFIG) --version >& /dev/null; then
		if has_version sys-apps/dbus; then
			export DBUS1_CFLAGS="-I/usr/include/dbus-1.0 -I/usr/$(get_libdir)/dbus-1.0/include"
			export DBUS1_LIBS="-ldbus-1"
		fi
		export LIBFFI_CFLAGS="-I$(echo /usr/$(get_libdir)/libffi-*/include)"
		export LIBFFI_LIBS="-lffi"
	fi

	local myconf

	case "${CHOST}" in
		*-mingw*) myconf="${myconf} --with-threads=win32" ;;
		*)        myconf="${myconf} --with-threads=posix" ;;
	esac

	# Only used by the gresource bin
	multilib_is_native_abi || myconf="${myconf} --disable-libelf"

	# FIXME: Always use internal libpcre, bug #254659
	# (maybe consider going back to system lib
	ECONF_SOURCE="${S}" gnome2_src_configure ${myconf} \
		$(use_enable xattr) \
		$(use_enable fam) \
		$(use_enable selinux) \
		$(use_enable static-libs static) \
		$(use_enable systemtap dtrace) \
		$(use_enable systemtap systemtap) \
		--disable-compile-warnings \
		--enable-man \
		--with-pcre=internal \
		--with-xml-catalog="${EPREFIX}/etc/xml/catalog"

	if multilib_is_native_abi; then
		local d
		for d in glib gio gobject; do
			ln -s "${S}"/docs/reference/${d}/html docs/reference/${d}/html || die
		done
	fi
}

multilib_src_test() {
	unset DBUS_SESSION_BUS_ADDRESS
	export XDG_CONFIG_DIRS=/etc/xdg
	export XDG_DATA_DIRS=/usr/local/share:/usr/share
	export G_DBUS_COOKIE_SHA1_KEYRING_DIR="${T}/temp"
	unset GSETTINGS_BACKEND # bug 352451
	export LC_TIME=C # bug #411967
	python_export_best

	# Related test is a bit nitpicking
	mkdir "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
	chmod 0700 "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"

	# Hardened: gdb needs this, bug #338891
	if host-is-pax ; then
		pax-mark -mr "${BUILD_DIR}"/tests/.libs/assert-msg-test \
			|| die "Hardened adjustment failed"
	fi

	# Need X for dbus-launch session X11 initialization
	Xemake check
}

multilib_src_install() {
	gnome2_src_install
}

multilib_src_install_all() {
	DOCS="AUTHORS ChangeLog* NEWS* README"
	einstalldocs

	if use utils ; then
		python_replicate_script "${ED}"/usr/bin/gtester-report
	else
		rm "${ED}usr/bin/gtester-report"
		rm "${ED}usr/share/man/man1/gtester-report.1"
	fi

	# Do not install charset.alias even if generated, leave it to libiconv
	rm -f "${ED}/usr/lib/charset.alias"

	# Don't install gdb python macros, bug 291328
	rm -rf "${ED}/usr/share/gdb/" "${ED}/usr/share/glib-2.0/gdb/"
}

pkg_postinst() {
	gnome2_pkg_postinst
	if has_version '<x11-libs/gtk+-3.0.12:3'; then
		# To have a clear upgrade path for gtk+-3.0.x users, have to resort to
		# a warning instead of a blocker
		ewarn
		ewarn "Using <gtk+-3.0.12:3 with ${P} results in frequent crashes."
		ewarn "You should upgrade to a newer version of gtk+:3 immediately."
	fi
}





^ permalink raw reply	[flat|nested] 6+ messages in thread
* [gentoo-commits] gentoo-x86 commit in dev-libs/glib: glib-2.42.2.ebuild ChangeLog
@ 2015-03-14 18:27 Pacho Ramos (pacho)
  0 siblings, 0 replies; 6+ messages in thread
From: Pacho Ramos (pacho) @ 2015-03-14 18:27 UTC (permalink / raw
  To: gentoo-commits

pacho       15/03/14 18:27:36

  Modified:             glib-2.42.2.ebuild ChangeLog
  Log:
  amd64 stable, bug 534012
  
  (Portage version: 2.2.17/cvs/Linux x86_64, RepoMan options: --include-arches="amd64", signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.2                  dev-libs/glib/glib-2.42.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?r1=1.1&r2=1.2

Index: glib-2.42.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- glib-2.42.2.ebuild	26 Feb 2015 19:24:49 -0000	1.1
+++ glib-2.42.2.ebuild	14 Mar 2015 18:27:36 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v 1.1 2015/02/26 19:24:49 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v 1.2 2015/03/14 18:27:36 pacho Exp $
 
 # Until bug #537330 glib is a reverse dependency of pkgconfig and, then
 # adding new dependencies end up making stage3 to grow. Every addition needs
@@ -32,7 +32,7 @@
 	test? ( ${PYTHON_REQUIRED_USE} )
 "
 
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
 
 RDEPEND="
 	!<dev-util/gdbus-codegen-${PV}



1.641                dev-libs/glib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.641&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.641&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.640&r2=1.641

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.640
retrieving revision 1.641
diff -u -r1.640 -r1.641
--- ChangeLog	26 Feb 2015 19:24:49 -0000	1.640
+++ ChangeLog	14 Mar 2015 18:27:36 -0000	1.641
@@ -1,6 +1,9 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.640 2015/02/26 19:24:49 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.641 2015/03/14 18:27:36 pacho Exp $
+
+  14 Mar 2015; Pacho Ramos <pacho@gentoo.org> glib-2.42.2.ebuild:
+  amd64 stable, bug 534012
 
 *glib-2.42.2 (26 Feb 2015)
 





^ permalink raw reply	[flat|nested] 6+ messages in thread
* [gentoo-commits] gentoo-x86 commit in dev-libs/glib: glib-2.42.2.ebuild ChangeLog
@ 2015-03-15 11:10 Pacho Ramos (pacho)
  0 siblings, 0 replies; 6+ messages in thread
From: Pacho Ramos (pacho) @ 2015-03-15 11:10 UTC (permalink / raw
  To: gentoo-commits

pacho       15/03/15 11:10:00

  Modified:             glib-2.42.2.ebuild ChangeLog
  Log:
  ppc stable, bug 534012
  
  (Portage version: 2.2.17/cvs/Linux x86_64, RepoMan options: --include-arches="ppc", signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.3                  dev-libs/glib/glib-2.42.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?r1=1.2&r2=1.3

Index: glib-2.42.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- glib-2.42.2.ebuild	14 Mar 2015 18:27:36 -0000	1.2
+++ glib-2.42.2.ebuild	15 Mar 2015 11:10:00 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v 1.2 2015/03/14 18:27:36 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v 1.3 2015/03/15 11:10:00 pacho Exp $
 
 # Until bug #537330 glib is a reverse dependency of pkgconfig and, then
 # adding new dependencies end up making stage3 to grow. Every addition needs
@@ -32,7 +32,7 @@
 	test? ( ${PYTHON_REQUIRED_USE} )
 "
 
-KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
 
 RDEPEND="
 	!<dev-util/gdbus-codegen-${PV}



1.642                dev-libs/glib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.642&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.642&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.641&r2=1.642

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.641
retrieving revision 1.642
diff -u -r1.641 -r1.642
--- ChangeLog	14 Mar 2015 18:27:36 -0000	1.641
+++ ChangeLog	15 Mar 2015 11:10:00 -0000	1.642
@@ -1,6 +1,9 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.641 2015/03/14 18:27:36 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.642 2015/03/15 11:10:00 pacho Exp $
+
+  15 Mar 2015; Pacho Ramos <pacho@gentoo.org> glib-2.42.2.ebuild:
+  ppc stable, bug 534012
 
   14 Mar 2015; Pacho Ramos <pacho@gentoo.org> glib-2.42.2.ebuild:
   amd64 stable, bug 534012





^ permalink raw reply	[flat|nested] 6+ messages in thread
* [gentoo-commits] gentoo-x86 commit in dev-libs/glib: glib-2.42.2.ebuild ChangeLog
@ 2015-03-15 11:47 Pacho Ramos (pacho)
  0 siblings, 0 replies; 6+ messages in thread
From: Pacho Ramos (pacho) @ 2015-03-15 11:47 UTC (permalink / raw
  To: gentoo-commits

pacho       15/03/15 11:47:43

  Modified:             glib-2.42.2.ebuild ChangeLog
  Log:
  ppc64 stable, bug 534012
  
  (Portage version: 2.2.17/cvs/Linux x86_64, RepoMan options: --include-arches="ppc64", signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.4                  dev-libs/glib/glib-2.42.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?r1=1.3&r2=1.4

Index: glib-2.42.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- glib-2.42.2.ebuild	15 Mar 2015 11:10:00 -0000	1.3
+++ glib-2.42.2.ebuild	15 Mar 2015 11:47:43 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v 1.3 2015/03/15 11:10:00 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v 1.4 2015/03/15 11:47:43 pacho Exp $
 
 # Until bug #537330 glib is a reverse dependency of pkgconfig and, then
 # adding new dependencies end up making stage3 to grow. Every addition needs
@@ -32,7 +32,7 @@
 	test? ( ${PYTHON_REQUIRED_USE} )
 "
 
-KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
 
 RDEPEND="
 	!<dev-util/gdbus-codegen-${PV}



1.643                dev-libs/glib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.643&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.643&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.642&r2=1.643

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.642
retrieving revision 1.643
diff -u -r1.642 -r1.643
--- ChangeLog	15 Mar 2015 11:10:00 -0000	1.642
+++ ChangeLog	15 Mar 2015 11:47:43 -0000	1.643
@@ -1,6 +1,9 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.642 2015/03/15 11:10:00 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.643 2015/03/15 11:47:43 pacho Exp $
+
+  15 Mar 2015; Pacho Ramos <pacho@gentoo.org> glib-2.42.2.ebuild:
+  ppc64 stable, bug 534012
 
   15 Mar 2015; Pacho Ramos <pacho@gentoo.org> glib-2.42.2.ebuild:
   ppc stable, bug 534012





^ permalink raw reply	[flat|nested] 6+ messages in thread
* [gentoo-commits] gentoo-x86 commit in dev-libs/glib: glib-2.42.2.ebuild ChangeLog
@ 2015-03-15 13:17 Pacho Ramos (pacho)
  0 siblings, 0 replies; 6+ messages in thread
From: Pacho Ramos (pacho) @ 2015-03-15 13:17 UTC (permalink / raw
  To: gentoo-commits

pacho       15/03/15 13:17:36

  Modified:             glib-2.42.2.ebuild ChangeLog
  Log:
  x86 stable, bug 534012
  
  (Portage version: 2.2.17/cvs/Linux x86_64, RepoMan options: --include-arches="x86", signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.5                  dev-libs/glib/glib-2.42.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?r1=1.4&r2=1.5

Index: glib-2.42.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- glib-2.42.2.ebuild	15 Mar 2015 11:47:43 -0000	1.4
+++ glib-2.42.2.ebuild	15 Mar 2015 13:17:36 -0000	1.5
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v 1.4 2015/03/15 11:47:43 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v 1.5 2015/03/15 13:17:36 pacho Exp $
 
 # Until bug #537330 glib is a reverse dependency of pkgconfig and, then
 # adding new dependencies end up making stage3 to grow. Every addition needs
@@ -32,7 +32,7 @@
 	test? ( ${PYTHON_REQUIRED_USE} )
 "
 
-KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh ~sparc x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
 
 RDEPEND="
 	!<dev-util/gdbus-codegen-${PV}



1.644                dev-libs/glib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.644&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.644&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.643&r2=1.644

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.643
retrieving revision 1.644
diff -u -r1.643 -r1.644
--- ChangeLog	15 Mar 2015 11:47:43 -0000	1.643
+++ ChangeLog	15 Mar 2015 13:17:36 -0000	1.644
@@ -1,6 +1,9 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.643 2015/03/15 11:47:43 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.644 2015/03/15 13:17:36 pacho Exp $
+
+  15 Mar 2015; Pacho Ramos <pacho@gentoo.org> glib-2.42.2.ebuild:
+  x86 stable, bug 534012
 
   15 Mar 2015; Pacho Ramos <pacho@gentoo.org> glib-2.42.2.ebuild:
   ppc64 stable, bug 534012





^ permalink raw reply	[flat|nested] 6+ messages in thread
* [gentoo-commits] gentoo-x86 commit in dev-libs/glib: glib-2.42.2.ebuild ChangeLog
@ 2015-06-07 10:16 Markus Meier (maekke)
  0 siblings, 0 replies; 6+ messages in thread
From: Markus Meier (maekke) @ 2015-06-07 10:16 UTC (permalink / raw
  To: gentoo-commits

maekke      15/06/07 10:16:37

  Modified:             glib-2.42.2.ebuild ChangeLog
  Log:
  arm stable, bug #534012
  
  (Portage version: 2.2.20/cvs/Linux x86_64, RepoMan options: --include-arches="arm", signed Manifest commit with key 072AD062)

Revision  Changes    Path
1.7                  dev-libs/glib/glib-2.42.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild?r1=1.6&r2=1.7

Index: glib-2.42.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- glib-2.42.2.ebuild	29 Mar 2015 10:14:34 -0000	1.6
+++ glib-2.42.2.ebuild	7 Jun 2015 10:16:37 -0000	1.7
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v 1.6 2015/03/29 10:14:34 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.42.2.ebuild,v 1.7 2015/06/07 10:16:37 maekke Exp $
 
 # Until bug #537330 glib is a reverse dependency of pkgconfig and, then
 # adding new dependencies end up making stage3 to grow. Every addition needs
@@ -32,7 +32,7 @@
 	test? ( ${PYTHON_REQUIRED_USE} )
 "
 
-KEYWORDS="~alpha amd64 ~arm ~arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh ~sparc x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
+KEYWORDS="~alpha amd64 arm ~arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh ~sparc x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
 
 RDEPEND="
 	!<dev-util/gdbus-codegen-${PV}



1.649                dev-libs/glib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.649&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.649&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.648&r2=1.649

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.648
retrieving revision 1.649
diff -u -r1.648 -r1.649
--- ChangeLog	5 Jun 2015 16:46:59 -0000	1.648
+++ ChangeLog	7 Jun 2015 10:16:37 -0000	1.649
@@ -1,6 +1,9 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.648 2015/06/05 16:46:59 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.649 2015/06/07 10:16:37 maekke Exp $
+
+  07 Jun 2015; Markus Meier <maekke@gentoo.org> glib-2.42.2.ebuild:
+  arm stable, bug #534012
 
   05 Jun 2015; Pacho Ramos <pacho@gentoo.org> -glib-2.42.1.ebuild,
   glib-1.2.10-r6.ebuild:





^ permalink raw reply	[flat|nested] 6+ messages in thread
end of thread, other threads:[~2015-06-07 10:16 UTC | newest]

Thread overview: 6+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-03-14 18:27 [gentoo-commits] gentoo-x86 commit in dev-libs/glib: glib-2.42.2.ebuild ChangeLog Pacho Ramos (pacho)
  -- strict thread matches above, loose matches on Subject: below --
2015-06-07 10:16 Markus Meier (maekke)
2015-03-15 13:17 Pacho Ramos (pacho)
2015-03-15 11:47 Pacho Ramos (pacho)
2015-03-15 11:10 Pacho Ramos (pacho)
2015-02-26 19:24 Pacho Ramos (pacho)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox