[gentoo-commits] gentoo-x86 commit in app-editors/scite: ChangeLog scite-3.5.4.ebuild scite-3.5.2.ebuild scite-3.5.3.ebuild scite-3.5.0.ebuild

[gentoo-commits] gentoo-x86 commit in app-editors/scite: ChangeLog scite-3.5.4.ebuild scite-3.5.2.ebuild scite-3.5.3.ebuild scite-3.5.0.ebuild

[Yixun Lan (dlan)]

dlan        15/03/10 15:57:24

  Modified:             ChangeLog scite-3.5.2.ebuild
  Added:                scite-3.5.4.ebuild
  Removed:              scite-3.5.3.ebuild scite-3.5.0.ebuild
  Log:
  version bump, drop old, also fix slot warning, bug 542760; thanks Ervin Peters
  
  (Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key 0xAABEFD55)

Revision  Changes    Path
1.180                app-editors/scite/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/scite/ChangeLog?rev=1.180&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/scite/ChangeLog?rev=1.180&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/scite/ChangeLog?r1=1.179&r2=1.180

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/scite/ChangeLog,v
retrieving revision 1.179
retrieving revision 1.180
diff -u -r1.179 -r1.180
--- ChangeLog	17 Feb 2015 10:38:48 -0000	1.179
+++ ChangeLog	10 Mar 2015 15:57:24 -0000	1.180
@@ -1,6 +1,13 @@
 # ChangeLog for app-editors/scite
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/ChangeLog,v 1.179 2015/02/17 10:38:48 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/ChangeLog,v 1.180 2015/03/10 15:57:24 dlan Exp $
+
+*scite-3.5.4 (10 Mar 2015)
+
+  10 Mar 2015; Yixun Lan <dlan@gentoo.org> -scite-3.5.0.ebuild,
+  scite-3.5.2.ebuild, -scite-3.5.3.ebuild, +scite-3.5.4.ebuild:
+  version bump, drop old, also fix slot warning, bug 542760; thanks Ervin
+  Peters
 
   17 Feb 2015; Agostino Sarubbo <ago@gentoo.org> scite-3.5.2.ebuild:
   Stable for amd64/ppc/x86, wrt bug #540346



1.3                  app-editors/scite/scite-3.5.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/scite/scite-3.5.2.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/scite/scite-3.5.2.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/scite/scite-3.5.2.ebuild?r1=1.2&r2=1.3

Index: scite-3.5.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/scite/scite-3.5.2.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- scite-3.5.2.ebuild	17 Feb 2015 10:38:48 -0000	1.2
+++ scite-3.5.2.ebuild	10 Mar 2015 15:57:24 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/scite-3.5.2.ebuild,v 1.2 2015/02/17 10:38:48 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/scite-3.5.2.ebuild,v 1.3 2015/03/10 15:57:24 dlan Exp $
 
 EAPI="5"
 
@@ -16,12 +16,12 @@
 KEYWORDS="amd64 ppc x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux"
 IUSE="lua"
 
-RDEPEND="dev-libs/glib
+RDEPEND="dev-libs/glib:2
 	x11-libs/cairo
 	x11-libs/gtk+:2
 	x11-libs/gdk-pixbuf
 	x11-libs/pango
-	lua? ( >=dev-lang/lua-5 )"
+	lua? ( >=dev-lang/lua-5:0= )"
 DEPEND="${RDEPEND}
 	virtual/pkgconfig
 	>=sys-apps/sed-4"



1.1                  app-editors/scite/scite-3.5.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/scite/scite-3.5.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/scite/scite-3.5.4.ebuild?rev=1.1&content-type=text/plain

Index: scite-3.5.4.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/scite-3.5.4.ebuild,v 1.1 2015/03/10 15:57:24 dlan Exp $

EAPI="5"

inherit toolchain-funcs eutils

MY_PV=${PV//./}
DESCRIPTION="A very powerful editor for programmers"
HOMEPAGE="http://www.scintilla.org/SciTE.html"
SRC_URI="mirror://sourceforge/scintilla/${PN}${MY_PV}.tgz"

LICENSE="HPND lua? ( MIT )"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux"
IUSE="lua"

RDEPEND="dev-libs/glib:2
	x11-libs/cairo
	x11-libs/gtk+:2
	x11-libs/gdk-pixbuf
	x11-libs/pango
	lua? ( >=dev-lang/lua-5:0= )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	>=sys-apps/sed-4"

S="${WORKDIR}/${PN}/gtk"

src_prepare() {
	cd "${WORKDIR}/scintilla/gtk"
	sed -i makefile \
		-e "s#^CXXFLAGS=#CXXFLAGS=${CXXFLAGS} #" \
		-e "s#^\(CXXFLAGS=.*\)-Os#\1#" \
		-e "s#^CC =\(.*\)#CC = $(tc-getCXX)#" \
		-e "s#^CCOMP =\(.*\)#CCOMP = $(tc-getCC)#" \
		-e "s#-Os##" \
		|| die "error patching makefile"

	cd "${WORKDIR}/scite/gtk"
	sed -i makefile \
		-e "s#-rdynamic#-rdynamic ${LDFLAGS}#" \
		|| die "error patching makefile"

	cd "${S}"
	sed -i makefile \
		-e 's#usr/local#usr#g' \
		-e 's#/gnome/apps/Applications#/applications#' \
		-e "s#^CXXFLAGS=#CXXFLAGS=${CXXFLAGS} #" \
		-e "s#^\(CXXFLAGS=.*\)-Os#\1#" \
		-e "s#^CC =\(.*\)#CC = $(tc-getCXX)#" \
		-e "s#^CCOMP =\(.*\)#CCOMP = $(tc-getCC)#" \
		-e 's#${D}##' \
		-e 's#-g root#-g 0#' \
		-e "s#-Os##" \
		|| die "error patching makefile"
}

src_compile() {
	emake -C ../../scintilla/gtk AR="$(tc-getAR)"
	if use lua; then
		emake
	else
		emake NO_LUA=1
	fi
}

src_install() {
	dodir /usr/bin
	dodir /usr/share/{pixmaps,applications}

	emake prefix="${ED}/usr" install

	# we have to keep this because otherwise it'll break upgrading
	mv "${ED}/usr/bin/SciTE" "${ED}/usr/bin/scite" || die
	dosym /usr/bin/scite /usr/bin/SciTE

	# replace .desktop file with our own working version
	rm -f "${ED}/usr/share/applications/SciTE.desktop" || die
	domenu "${FILESDIR}/scite.desktop"

	doman ../doc/scite.1
	dodoc ../README
}