* [gentoo-commits] gentoo-x86 commit in app-emulation/playonlinux: playonlinux-4.2.6.ebuild metadata.xml ChangeLog playonlinux-4.1.1.ebuild playonlinux-4.1.1-r1.ebuild
@ 2015-03-10 3:12 Ian Delaney (idella4)
0 siblings, 0 replies; only message in thread
From: Ian Delaney (idella4) @ 2015-03-10 3:12 UTC (permalink / raw
To: gentoo-commits
idella4 15/03/10 03:12:02
Modified: metadata.xml ChangeLog
Added: playonlinux-4.2.6.ebuild
Removed: playonlinux-4.1.1.ebuild
playonlinux-4.1.1-r1.ebuild
Log:
bump, fix nagging update notification, ack to Adam Mills for new patch, ack to Kent Fredric wrt bug #522356, fixes Bugs 480550 & 524522. proxy maintainership change to NP-Hardass with consent of prior maintainer wrt bug #542630
(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)
Revision Changes Path
1.6 app-emulation/playonlinux/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/playonlinux/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/playonlinux/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/playonlinux/metadata.xml?r1=1.5&r2=1.6
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/playonlinux/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml 14 Jul 2012 18:22:55 -0000 1.5
+++ metadata.xml 10 Mar 2015 03:12:02 -0000 1.6
@@ -3,8 +3,13 @@
<pkgmetadata>
<herd>proxy-maintainers</herd>
<maintainer>
- <email>mikemol@gmail.com</email>
- <name>Michael Mol</name>
+ <email>idella4@gentoo.org</email>
+ <name>Ian Delaney</name>
+ </maintainer>
+ <maintainer>
+ <email>np.hardass@gmail.com</email>
+ <name>NP-Hardass</name>
+ <description>proxy maintainer and recipient of bugs</description>
</maintainer>
<use>
<flag name="winbind">Enables support for the winbind auth daemon</flag>
1.22 app-emulation/playonlinux/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/playonlinux/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/playonlinux/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/playonlinux/ChangeLog?r1=1.21&r2=1.22
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/playonlinux/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog 5 Aug 2014 00:54:27 -0000 1.21
+++ ChangeLog 10 Mar 2015 03:12:02 -0000 1.22
@@ -1,6 +1,16 @@
# ChangeLog for app-emulation/playonlinux
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/playonlinux/ChangeLog,v 1.21 2014/08/05 00:54:27 zx2c4 Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/playonlinux/ChangeLog,v 1.22 2015/03/10 03:12:02 idella4 Exp $
+
+*playonlinux-4.2.6 (10 Mar 2015)
+
+ 10 Mar 2015; Ian Delaney <idella4@gentoo.org>
+ +files/playonlinux-4.2.6-stop-update-warning.patch, +playonlinux-4.2.6.ebuild,
+ -files/playonlinux-4.1.1-not-exclude-ipv6.patch, -playonlinux-4.1.1-r1.ebuild,
+ -playonlinux-4.1.1.ebuild, metadata.xml:
+ bump, fix nagging update notification, ack to Adam Mills for new patch, ack to
+ Kent Fredric wrt bug #522356, fixes Bugs 480550 & 524522. proxy maintainership
+ change to NP-Hardass with consent of prior maintainer wrt bug #542630
*playonlinux-4.2.4 (05 Aug 2014)
1.1 app-emulation/playonlinux/playonlinux-4.2.6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/playonlinux/playonlinux-4.2.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/playonlinux/playonlinux-4.2.6.ebuild?rev=1.1&content-type=text/plain
Index: playonlinux-4.2.6.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/playonlinux/playonlinux-4.2.6.ebuild,v 1.1 2015/03/10 03:12:02 idella4 Exp $
EAPI="5"
PYTHON_COMPAT=( python2_7 )
inherit gnome2-utils python-single-r1 games
MY_PN="PlayOnLinux"
DESCRIPTION="Set of scripts to easily install and use Windows games and software"
HOMEPAGE="http://playonlinux.com/"
SRC_URI="http://www.playonlinux.com/script_files/${MY_PN}/${PV}/${MY_PN}_${PV}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="winbind"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
DEPEND=""
RDEPEND="app-emulation/wine
app-arch/cabextract
app-arch/p7zip
app-arch/unzip
app-crypt/gnupg
dev-python/wxpython:2.8[${PYTHON_USEDEP}]
|| ( media-gfx/imagemagick media-gfx/graphicsmagick[imagemagick] )
net-misc/wget
x11-apps/mesa-progs
x11-terms/xterm
media-gfx/icoutils
|| ( net-analyzer/netcat net-analyzer/netcat6 )
winbind? ( net-fs/samba[winbind] ) "
S=${WORKDIR}/${PN}
# TODO:
# Having a real install script and let playonlinux use standard filesystem
# architecture to prevent having everything installed into GAMES_DATADIR
# It will let using LANGUAGES easily
# How to deal with Microsoft Fonts installation asked every time ?
# How to deal with wine version installed ? (have a better mgmt of system one)
# Look at debian pkg: http://packages.debian.org/sid/playonlinux
pkg_setup() {
python-single-r1_pkg_setup
games_pkg_setup
}
src_prepare() {
epatch "${FILESDIR}/${PN}-4.2.4-pol-bash.patch"
epatch "${FILESDIR}/${PN}-4.2.4-binary-plugin.patch"
epatch "${FILESDIR}/${PN}-4.2.6-stop-update-warning.patch"
python_fix_shebang .
# remove playonmac
rm etc/{playonmac.icns,terminal.applescript} || die
# remove desktop integration
rm etc/{PlayOnLinux.desktop,PlayOnLinux.directory,playonlinux-Programmes.menu} || die
}
src_install() {
# all things without exec permissions
insinto "${GAMES_DATADIR}/${PN}"
doins -r resources lang lib etc plugins
# bash/ install
exeinto "${GAMES_DATADIR}/${PN}/bash"
find "${S}/bash" -type f -exec doexe '{}' +
exeinto "${GAMES_DATADIR}/${PN}/bash/expert"
find "${S}/bash/expert" -type f -exec doexe '{}' +
# python/ install
python_moduleinto "${GAMES_DATADIR}/${PN}"
python_domodule python
# main executable files
exeinto "${GAMES_DATADIR}/${PN}"
doexe ${PN}{,-pkg,-bash,-shell,-url_handler}
# icons
doicon -s 128 etc/${PN}.png
for size in 16 22 32; do
newicon -s $size etc/${PN}$size.png ${PN}.png
done
doman "${FILESDIR}"/playonlinux{,-pkg}.1
dodoc CHANGELOG.md
games_make_wrapper ${PN} "./${PN}" "${GAMES_DATADIR}/${PN}"
games_make_wrapper ${PN}-pkg "./${PN}-pkg" "${GAMES_DATADIR}/${PN}"
make_desktop_entry ${PN} ${MY_PN} ${PN} Game
prepgamesdirs
}
pkg_preinst() {
gnome2_icon_savelist
}
pkg_postinst() {
games_pkg_postinst
gnome2_icon_cache_update
}
pkg_prerm() {
if [[ -z ${REPLACING_VERSIONS} ]]; then
elog "Installed softwares and games with playonlinux have not been removed."
elog "To remove them, you can re-install playonlinux and remove them using it"
elog "or do it manually by removing .PlayOnLinux/ in your home directory."
fi
}
pkg_postrm() {
gnome2_icon_cache_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-03-10 3:12 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-03-10 3:12 [gentoo-commits] gentoo-x86 commit in app-emulation/playonlinux: playonlinux-4.2.6.ebuild metadata.xml ChangeLog playonlinux-4.1.1.ebuild playonlinux-4.1.1-r1.ebuild Ian Delaney (idella4)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox