* [gentoo-commits] gentoo-x86 commit in sys-fs/aufs3: aufs3-3_p20150309.ebuild ChangeLog
@ 2015-03-09 8:02 Justin Lecher (jlec)
0 siblings, 0 replies; only message in thread
From: Justin Lecher (jlec) @ 2015-03-09 8:02 UTC (permalink / raw
To: gentoo-commits
jlec 15/03/09 08:02:17
Modified: ChangeLog
Added: aufs3-3_p20150309.ebuild
Log:
Bump to latest aufs3 release
(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)
Revision Changes Path
1.122 sys-fs/aufs3/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/aufs3/ChangeLog?rev=1.122&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/aufs3/ChangeLog?rev=1.122&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/aufs3/ChangeLog?r1=1.121&r2=1.122
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/aufs3/ChangeLog,v
retrieving revision 1.121
retrieving revision 1.122
diff -u -r1.121 -r1.122
--- ChangeLog 23 Feb 2015 08:12:03 -0000 1.121
+++ ChangeLog 9 Mar 2015 08:02:17 -0000 1.122
@@ -1,6 +1,11 @@
# ChangeLog for sys-fs/aufs3
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/aufs3/ChangeLog,v 1.121 2015/02/23 08:12:03 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/aufs3/ChangeLog,v 1.122 2015/03/09 08:02:17 jlec Exp $
+
+*aufs3-3_p20150309 (09 Mar 2015)
+
+ 09 Mar 2015; Justin Lecher <jlec@gentoo.org> +aufs3-3_p20150309.ebuild:
+ Bump to latest aufs3 release
*aufs3-3_p20150223 (23 Feb 2015)
1.1 sys-fs/aufs3/aufs3-3_p20150309.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/aufs3/aufs3-3_p20150309.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/aufs3/aufs3-3_p20150309.ebuild?rev=1.1&content-type=text/plain
Index: aufs3-3_p20150309.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/aufs3/aufs3-3_p20150309.ebuild,v 1.1 2015/03/09 08:02:17 jlec Exp $
EAPI=5
inherit eutils flag-o-matic linux-info linux-mod multilib readme.gentoo toolchain-funcs
AUFS_VERSION="${PV%%_p*}"
# highest branch version
PATCH_MAX_VER=18
# highest supported version
KERN_MAX_VER=19
# lowest supported version
KERN_MIN_VER=14
DESCRIPTION="An entirely re-designed and re-implemented Unionfs"
HOMEPAGE="http://aufs.sourceforge.net/"
SRC_URI="http://dev.gentoo.org/~jlec/distfiles/aufs3-standalone-${PV}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc fuse hfs inotify kernel-patch nfs pax_kernel ramfs"
DEPEND="
dev-util/patchutils
dev-vcs/git"
RDEPEND="
sys-fs/aufs-util
!sys-fs/aufs
!sys-fs/aufs2"
S="${WORKDIR}"/${PN}-standalone
MODULE_NAMES="aufs(misc:${S})"
README_GENTOO_SUFFIX="-r1"
pkg_setup() {
CONFIG_CHECK+=" !AUFS_FS"
use inotify && CONFIG_CHECK+=" ~FSNOTIFY"
use nfs && CONFIG_CHECK+=" EXPORTFS"
use fuse && CONFIG_CHECK+=" ~FUSE_FS"
use hfs && CONFIG_CHECK+=" ~HFSPLUS_FS"
use pax_kernel && CONFIG_CHECK+=" PAX" && ERROR_PAX="Please use hardened sources"
# this is needed so merging a binpkg ${PN} is possible w/out a kernel unpacked on the system
[ -n "$PKG_SETUP_HAS_BEEN_RAN" ] && return
get_version
kernel_is lt 3 ${KERN_MIN_VER} 0 && die "the kernel version isn't supported by upstream anymore. Please upgrade."
kernel_is gt 3 ${KERN_MAX_VER} 99 && die "kernel too new"
linux-mod_pkg_setup
if [[ "${KV_MINOR}" -gt "${PATCH_MAX_VER}" ]]; then
PATCH_BRANCH="x-rcN"
elif [[ "${KV_MINOR}" == "14" ]] && [[ "${KV_PATCH}" -ge "21" ]]; then
PATCH_BRANCH="${KV_MINOR}".12+
elif [[ "${KV_MINOR}" == "18" ]] && [[ "${KV_PATCH}" -ge "1" ]]; then
PATCH_BRANCH="${KV_MINOR}".1+
else
PATCH_BRANCH="${KV_MINOR}"
fi
case ${KV_EXTRA} in
"")
elog "It seems you are using vanilla-sources with aufs3"
elog "Please use sys-kernel/aufs-sources with USE=vanilla"
elog "This will save you the nasty reemerge of sys-fs/aufs3 on every kernel upgrade"
;;
"-gentoo")
elog "It seems you are using gentoo-sources with aufs3"
elog "Please use sys-kernel/aufs-sources"
elog "This will save you the nasty reemerge of sys-fs/aufs3 on every kernel upgrade"
;;
esac
pushd "${T}" &> /dev/null
unpack ${A}
cd ${PN}-standalone || die
local module_branch=origin/${PN}.${PATCH_BRANCH}
einfo "Using ${module_branch} as patch source"
git checkout -q -b local-${PN}.${PATCH_BRANCH} ${module_branch} || die
combinediff ${PN}-base.patch ${PN}-standalone.patch > "${T}"/combined-1.patch
combinediff "${T}"/combined-1.patch ${PN}-mmap.patch > ${PN}-standalone-base-mmap-combined.patch
if ! ( patch -p1 --dry-run --force -R -d ${KV_DIR} < ${PN}-standalone-base-mmap-combined.patch > /dev/null ); then
if use kernel-patch; then
cd ${KV_DIR}
ewarn "Patching your kernel..."
patch --no-backup-if-mismatch --force -p1 -R -d ${KV_DIR} < "${T}"/${PN}-standalone/${PN}-standalone-base-mmap-combined.patch >/dev/null
epatch "${T}"/${PN}-standalone/${PN}-standalone-base-mmap-combined.patch
ewarn "You need to compile your kernel with the applied patch"
ewarn "to be able to load and use the aufs kernel module"
else
eerror "You need to apply a patch to your kernel to compile and run the ${PN} module"
eerror "Either enable the kernel-patch useflag to do it with this ebuild"
eerror "or apply "${T}"/${PN}-standalone/${PN}-standalone-base-mmap-combined.patch by hand"
die "missing kernel patch, please apply it first"
fi
fi
popd &> /dev/null
export PKG_SETUP_HAS_BEEN_RAN=1
}
set_config() {
for option in $*; do
grep -q "^CONFIG_AUFS_${option} =" config.mk || die "${option} is not a valid config option"
sed "/^CONFIG_AUFS_${option}/s:=:= y:g" -i config.mk || die
done
}
src_prepare() {
local module_branch=origin/${PN}.${PATCH_BRANCH}
einfo "Using for module creation branch ${module_branch}"
git checkout -q -b local-gentoo ${module_branch} || die
# All config options to off
sed "s:= y:=:g" -i config.mk || die
set_config RDU BRANCH_MAX_127 SBILIST
use debug && set_config DEBUG
use fuse && set_config BR_FUSE POLL
use hfs && set_config BR_HFSPLUS
use inotify && set_config HNOTIFY HFSNOTIFY
use nfs && set_config EXPORT
use nfs && ( use amd64 || use ppc64 ) && set_config INO_T_64
use ramfs && set_config BR_RAMFS
if use pax_kernel; then
if kernel_is ge 3 11; then
epatch "${FILESDIR}"/pax-3.11.patch
else
epatch "${FILESDIR}"/pax-3.patch
fi
fi
sed -i "s:aufs.ko usr/include/linux/aufs_type.h:aufs.ko:g" Makefile || die
}
src_compile() {
local ARCH=x86
emake \
CC=$(tc-getCC) \
LD=$(tc-getLD) \
LDFLAGS="$(raw-ldflags)" \
ARCH=$(tc-arch-kernel) \
CONFIG_AUFS_FS=m \
KDIR="${KV_OUT_DIR}"
}
src_install() {
linux-mod_src_install
insinto /usr/share/doc/${PF}
use doc && doins -r Documentation
use kernel-patch || doins "${T}"/${PN}-standalone/${PN}-standalone-base-mmap-combined.patch
dodoc Documentation/filesystems/aufs/README "${T}"/${PN}-standalone/{aufs3-loopback,vfs-ino,tmpfs-idr}.patch
readme.gentoo_create_doc
}
pkg_postinst() {
readme.gentoo_pkg_postinst
linux-mod_pkg_postinst
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-03-09 8:02 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-03-09 8:02 [gentoo-commits] gentoo-x86 commit in sys-fs/aufs3: aufs3-3_p20150309.ebuild ChangeLog Justin Lecher (jlec)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox