[gentoo-commits] gentoo-x86 commit in net-misc/tor: tor-0.2.6.3_alpha.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-misc/tor: tor-0.2.6.3_alpha.ebuild ChangeLog

[Anthony G. Basile (blueness)]

blueness    15/03/08 00:04:44

  Modified:             ChangeLog
  Added:                tor-0.2.6.3_alpha.ebuild
  Log:
  Version bump alpha.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

Revision  Changes    Path
1.465                net-misc/tor/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?rev=1.465&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?rev=1.465&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?r1=1.464&r2=1.465

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v
retrieving revision 1.464
retrieving revision 1.465
diff -u -r1.464 -r1.465
--- ChangeLog	28 Feb 2015 22:04:37 -0000	1.464
+++ ChangeLog	8 Mar 2015 00:04:44 -0000	1.465
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/tor
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v 1.464 2015/02/28 22:04:37 bircoph Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v 1.465 2015/03/08 00:04:44 blueness Exp $
+
+*tor-0.2.6.3_alpha (08 Mar 2015)
+
+  08 Mar 2015; Anthony G. Basile <blueness@gentoo.org>
+  +tor-0.2.6.3_alpha.ebuild:
+  Version bump alpha.
 
   28 Feb 2015; Andrew Savchenko <bircoph@gentoo.org> metadata.xml:
   seccomp USE flag is now global, removing from metadata



1.1                  net-misc/tor/tor-0.2.6.3_alpha.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/tor-0.2.6.3_alpha.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/tor-0.2.6.3_alpha.ebuild?rev=1.1&content-type=text/plain

Index: tor-0.2.6.3_alpha.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/tor-0.2.6.3_alpha.ebuild,v 1.1 2015/03/08 00:04:44 blueness Exp $

EAPI="5"

inherit eutils flag-o-matic readme.gentoo systemd toolchain-funcs versionator user

MY_PV="$(replace_version_separator 4 -)"
MY_PF="${PN}-${MY_PV}"
DESCRIPTION="Anonymizing overlay network for TCP"
HOMEPAGE="http://www.torproject.org/"
SRC_URI="https://www.torproject.org/dist/${MY_PF}.tar.gz
	https://archive.torproject.org/tor-package-archive/${MY_PF}.tar.gz"
S="${WORKDIR}/${MY_PF}"

LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~x86"
IUSE="-bufferevents nat-pmp scrypt seccomp selinux stats systemd tor-hardening transparent-proxy test upnp web"

DEPEND="dev-libs/openssl
	sys-libs/zlib
	dev-libs/libevent
	bufferevents? ( dev-libs/libevent[ssl] )
	nat-pmp? ( net-libs/libnatpmp )
	scrypt? ( app-crypt/libscrypt )
	seccomp? ( sys-libs/libseccomp )
	upnp? ( net-libs/miniupnpc )"
RDEPEND="${DEPEND}
	selinux? ( sec-policy/selinux-tor )"

pkg_setup() {
	enewgroup tor
	enewuser tor -1 -1 /var/lib/tor tor
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.2.3.14_alpha-torrc.sample.patch
	epatch_user
}

src_configure() {
	# Upstream isn't sure of all the user provided CFLAGS that
	# will break tor, but does recommend against -fstrict-aliasing.
	# We'll filter-flags them here as we encounter them.
	filter-flags -fstrict-aliasing

	econf \
		--enable-asciidoc \
		--docdir=/usr/share/doc/${PF} \
		$(use_enable stats instrument-downloads) \
		$(use_enable bufferevents) \
		$(use_enable nat-pmp) \
		$(use_enable scrypt libscrypt) \
		$(use_enable seccomp) \
		$(use_enable systemd) \
		$(use_enable tor-hardening gcc-hardening) \
		$(use_enable tor-hardening linker-hardening) \
		$(use_enable transparent-proxy transparent) \
		$(use_enable upnp) \
		$(use_enable web tor2web-mode) \
		$(use_enable test unittests) \
		$(use_enable test coverage)
}

src_install() {
	readme.gentoo_create_doc

	newconfd "${FILESDIR}"/tor.confd tor
	newinitd "${FILESDIR}"/tor.initd-r7 tor
	systemd_dounit "${FILESDIR}/${PN}.service"
	systemd_dotmpfilesd "${FILESDIR}/${PN}.conf"

	emake DESTDIR="${D}" install

	keepdir /var/lib/tor

	dodoc README ChangeLog ReleaseNotes doc/HACKING

	fperms 750 /var/lib/tor
	fowners tor:tor /var/lib/tor

	insinto /etc/tor/
	newins "${FILESDIR}"/torrc-r1 torrc
}

pkg_postinst() {
	readme.gentoo_pkg_postinst

	if [[ $(gcc-major-version) -eq 4 && $(gcc-minor-version) -eq 8 && $(gcc-micro-version) -ge 1 ]] ; then
		ewarn "Due to a bug in  >=gcc-4.8.1, compiling ${P} with -Os leads to an infinite"
		ewarn "loop.  See:"
		ewarn
		ewarn "    https://trac.torproject.org/projects/tor/ticket/10259"
		ewarn "    http://gcc.gnu.org/bugzilla/show_bug.cgi?id=59358"
		ewarn
	fi
}