[gentoo-commits] gentoo-x86 commit in dev-python/dnspython: dnspython-1.12.0-r1.ebuild ChangeLog

["Ian Delaney (idella4)" <idella4@gentoo.org>]

idella4     15/03/06 11:37:48

  Modified:             ChangeLog
  Added:                dnspython-1.12.0-r1.ebuild
  Log:
  revbump; add py3 support by addition of dnspython3 tarball, SRC_URI updated, virtual re-write, assistance from NP-Hardass in achieving final form of the ebuild
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.94                 dev-python/dnspython/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/dnspython/ChangeLog?rev=1.94&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/dnspython/ChangeLog?rev=1.94&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/dnspython/ChangeLog?r1=1.93&r2=1.94

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/dnspython/ChangeLog,v
retrieving revision 1.93
retrieving revision 1.94
diff -u -r1.93 -r1.94
--- ChangeLog	26 Jan 2015 14:27:05 -0000	1.93
+++ ChangeLog	6 Mar 2015 11:37:48 -0000	1.94
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/dnspython
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/dnspython/ChangeLog,v 1.93 2015/01/26 14:27:05 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/dnspython/ChangeLog,v 1.94 2015/03/06 11:37:48 idella4 Exp $
+
+*dnspython-1.12.0-r1 (06 Mar 2015)
+
+  06 Mar 2015; Ian Delaney <idella4@gentoo.org> +dnspython-1.12.0-r1.ebuild:
+  revbump; add py3 support by addition of dnspython3 tarball, SRC_URI updated,
+  virtual re-write, assistance from NP-Hardass in achieving final form of the
+  ebuild
 
   26 Jan 2015; Manuel Rüger <mrueg@gentoo.org> -dnspython-1.10.0-r1.ebuild,
   -dnspython-1.10.0.ebuild, -dnspython-1.9.4.ebuild:



1.1                  dev-python/dnspython/dnspython-1.12.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/dnspython/dnspython-1.12.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/dnspython/dnspython-1.12.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: dnspython-1.12.0-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/dnspython/dnspython-1.12.0-r1.ebuild,v 1.1 2015/03/06 11:37:48 idella4 Exp $

EAPI=5
PYTHON_COMPAT=( python{2_7,3_3,3_4} )

inherit distutils-r1

PN3="${PN}3"
P3="${PN3}-${PV}"

DESCRIPTION="DNS toolkit for Python"
HOMEPAGE="http://www.dnspython.org/ http://pypi.python.org/pypi/dnspython"
SRC_URI="http://www.dnspython.org/kits/${PV}/${P}.tar.gz
	http://www.dnspython.org/kits3/${PV}/${P3}.zip"

LICENSE="ISC"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
IUSE="examples test"

DEPEND="dev-python/pycrypto[${PYTHON_USEDEP}]
	app-arch/unzip"
RDEPEND="${DEPEND}"

S2="${S}"
S3="${WORKDIR}/${P3}"

# For testsuite
DISTUTILS_IN_SOURCE_BUILD=1

python_prepare() {
	if python_is_python3; then
		cp -r "${WORKDIR}/${P3}" "${BUILD_DIR}" || die
	else
		distutils-r1_python_prepare
	fi
}

python_compile() {
	if python_is_python3; then
		run_in_build_dir distutils-r1_python_compile
	else
		distutils-r1_python_compile
	fi
}

python_install(){
	if python_is_python3; then
		run_in_build_dir distutils-r1_python_install
	else
		distutils-r1_python_install
	fi
}

python_test() {
	if python_is_python3; then
		pushd "${S3}/tests" &> /dev/null
	else
		pushd "${S2}/tests" &> /dev/null
	fi
	"${PYTHON}" utest.py || die "tests failed under ${EPYTHON}"
	einfo "Testsuite passed under ${EPYTHON}"
	popd &> /dev/null
}

python_install_all() {
	use examples && local EXAMPLES=( examples/. )
	distutils-r1_python_install_all
}