[gentoo-commits] gentoo-x86 commit in net-analyzer/openvas-manager: openvas-manager-5.0.9.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-analyzer/openvas-manager: openvas-manager-5.0.9.ebuild ChangeLog

[Justin Lecher (jlec)]

jlec        15/03/06 10:13:49

  Modified:             ChangeLog
  Added:                openvas-manager-5.0.9.ebuild
  Log:
  Version Bump
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.20                 net-analyzer/openvas-manager/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-manager/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-manager/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-manager/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/openvas-manager/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	14 Feb 2015 14:28:55 -0000	1.19
+++ ChangeLog	6 Mar 2015 10:13:49 -0000	1.20
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/openvas-manager
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-manager/ChangeLog,v 1.19 2015/02/14 14:28:55 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-manager/ChangeLog,v 1.20 2015/03/06 10:13:49 jlec Exp $
+
+*openvas-manager-5.0.9 (06 Mar 2015)
+
+  06 Mar 2015; Justin Lecher <jlec@gentoo.org> +openvas-manager-5.0.9.ebuild:
+  Version Bump
 
   14 Feb 2015; Justin Lecher <jlec@gentoo.org> -openvas-manager-5.0.7.ebuild,
   -openvas-manager-6.0_beta3.ebuild, -openvas-manager-6.0_beta4.ebuild,



1.1                  net-analyzer/openvas-manager/openvas-manager-5.0.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-manager/openvas-manager-5.0.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-manager/openvas-manager-5.0.9.ebuild?rev=1.1&content-type=text/plain

Index: openvas-manager-5.0.9.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-manager/openvas-manager-5.0.9.ebuild,v 1.1 2015/03/06 10:13:49 jlec Exp $

EAPI=5

inherit cmake-utils systemd

MY_PN=openvasmd

DL_ID=1963

DESCRIPTION="A remote security scanner for Linux (openvas-manager)"
HOMEPAGE="http://www.openvas.org/"
SRC_URI="http://wald.intevation.org/frs/download.php/${DL_ID}/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~arm ~ppc ~x86"
IUSE=""

RDEPEND="
	>=net-analyzer/openvas-libraries-7.0.9
	>=dev-db/sqlite-3
	!net-analyzer/openvas-administrator"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

PATCHES=(
	"${FILESDIR}"/${PN}-5.0.4-gpgerror.patch
	"${FILESDIR}"/${PN}-5.0.4-bsdsource.patch
	"${FILESDIR}"/${PN}-5.0.4-run.patch
	)

src_prepare() {
	sed \
		-e '/^install.*OPENVAS_CACHE_DIR.*/d' \
		-i CMakeLists.txt || die
	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DLOCALSTATEDIR="${EPREFIX}/var"
		-DSYSCONFDIR="${EPREFIX}/etc"
		)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	insinto /etc/openvas/
	doins "${FILESDIR}"/${MY_PN}-daemon.conf
	dosym ../openvas/${MY_PN}-daemon.conf /etc/conf.d/${PN}

	insinto /etc/logrotate.d
	newins "${FILESDIR}"/${MY_PN}.logrotate ${MY_PN}

	newinitd "${FILESDIR}"/${MY_PN}.init ${MY_PN}
	systemd_dounit "${FILESDIR}"/${MY_PN}.service
}