[gentoo-commits] gentoo-x86 commit in net-misc/wget: wget-1.16.2.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-misc/wget: wget-1.16.2.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      15/02/28 18:04:47

  Modified:             ChangeLog
  Added:                wget-1.16.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.201                net-misc/wget/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wget/ChangeLog?rev=1.201&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wget/ChangeLog?rev=1.201&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wget/ChangeLog?r1=1.200&r2=1.201

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/wget/ChangeLog,v
retrieving revision 1.200
retrieving revision 1.201
diff -u -r1.200 -r1.201
--- ChangeLog	8 Dec 2014 17:55:39 -0000	1.200
+++ ChangeLog	28 Feb 2015 18:04:47 -0000	1.201
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/wget
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/wget/ChangeLog,v 1.200 2014/12/08 17:55:39 polynomial-c Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/wget/ChangeLog,v 1.201 2015/02/28 18:04:47 vapier Exp $
+
+*wget-1.16.2 (28 Feb 2015)
+
+  28 Feb 2015; Mike Frysinger <vapier@gentoo.org> +wget-1.16.2.ebuild:
+  Version bump.
 
   08 Dec 2014; Lars Wendler <polynomial-c@gentoo.org> wget-1.16.1.ebuild:
   Disable progress bar assertion as recommended by upstream.



1.1                  net-misc/wget/wget-1.16.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wget/wget-1.16.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/wget/wget-1.16.2.ebuild?rev=1.1&content-type=text/plain

Index: wget-1.16.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/wget/wget-1.16.2.ebuild,v 1.1 2015/02/28 18:04:47 vapier Exp $

EAPI="4"
PYTHON_COMPAT=( python{3_3,3_4} )

inherit flag-o-matic python-any-r1 toolchain-funcs autotools

DESCRIPTION="Network utility to retrieve files from the WWW"
HOMEPAGE="http://www.gnu.org/software/wget/"
SRC_URI="mirror://gnu/wget/${P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="debug gnutls idn ipv6 nls ntlm pcre +ssl static test uuid zlib"

LIB_DEPEND="idn? ( net-dns/libidn[static-libs(+)] )
	pcre? ( dev-libs/libpcre[static-libs(+)] )
	ssl? (
		gnutls? ( net-libs/gnutls[static-libs(+)] )
		!gnutls? ( dev-libs/openssl:0[static-libs(+)] )
	)
	uuid? ( sys-apps/util-linux[static-libs(+)] )
	zlib? ( sys-libs/zlib[static-libs(+)] )"
RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	virtual/pkgconfig
	static? ( ${LIB_DEPEND} )
	test? (
		${PYTHON_DEPS}
		dev-lang/perl
		dev-perl/HTTP-Daemon
		dev-perl/HTTP-Message
		dev-perl/IO-Socket-SSL
	)
	nls? ( sys-devel/gettext )"

REQUIRED_USE="ntlm? ( !gnutls ssl ) gnutls? ( ssl )"

DOCS=( AUTHORS MAILING-LIST NEWS README doc/sample.wgetrc )

pkg_setup() {
	use test && python-any-r1_pkg_setup
}

src_configure() {
	# fix compilation on Solaris, we need filio.h for FIONBIO as used in
	# the included gnutls -- force ioctl.h to include this header
	[[ ${CHOST} == *-solaris* ]] && append-cppflags -DBSD_COMP=1

	if use static ; then
		append-ldflags -static
		tc-export PKG_CONFIG
		PKG_CONFIG+=" --static"
	fi
	econf \
		--disable-assert \
		--disable-rpath \
		$(use_with ssl ssl $(usex gnutls gnutls openssl)) \
		$(use_enable ssl opie) \
		$(use_enable ssl digest) \
		$(use_enable idn iri) \
		$(use_enable ipv6) \
		$(use_enable nls) \
		$(use_enable ntlm) \
		$(use_enable pcre) \
		$(use_enable debug) \
		$(use_with uuid libuuid) \
		$(use_with zlib)
}

src_test() {
	emake check
}

src_install() {
	default

	sed -i \
		-e "s:/usr/local/etc:${EPREFIX}/etc:g" \
		"${ED}"/etc/wgetrc \
		"${ED}"/usr/share/man/man1/wget.1 \
		"${ED}"/usr/share/info/wget.info
}