[gentoo-commits] gentoo-x86 commit in dev-python/rdflib: rdflib-4.2.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-python/rdflib: rdflib-4.2.0.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     15/02/28 07:35:47

  Modified:             ChangeLog
  Added:                rdflib-4.2.0.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.17/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.52                 dev-python/rdflib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/rdflib/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/rdflib/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/rdflib/ChangeLog?r1=1.51&r2=1.52

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/rdflib/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog	2 Feb 2015 14:42:20 -0000	1.51
+++ ChangeLog	28 Feb 2015 07:35:47 -0000	1.52
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/rdflib
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/rdflib/ChangeLog,v 1.51 2015/02/02 14:42:20 mrueg Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/rdflib/ChangeLog,v 1.52 2015/02/28 07:35:47 patrick Exp $
+
+*rdflib-4.2.0 (28 Feb 2015)
+
+  28 Feb 2015; Patrick Lauer <patrick@gentoo.org> +rdflib-4.2.0.ebuild:
+  Bump
 
   02 Feb 2015; Manuel Rüger <mrueg@gentoo.org> -rdflib-3.2.3.ebuild:
   Remove old.



1.1                  dev-python/rdflib/rdflib-4.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/rdflib/rdflib-4.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/rdflib/rdflib-4.2.0.ebuild?rev=1.1&content-type=text/plain

Index: rdflib-4.2.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/rdflib/rdflib-4.2.0.ebuild,v 1.1 2015/02/28 07:35:47 patrick Exp $

EAPI=5

PYTHON_COMPAT=( python{2_7,3_3,3_4} )
PYTHON_REQ_USE="sqlite?"
DISTUTILS_NO_PARALLEL_BUILD=true
# The usual required for tests
DISTUTILS_IN_SOURCE_BUILD=1

inherit distutils-r1

DESCRIPTION="RDF library containing a triple store and parser/serializer"
HOMEPAGE="https://github.com/RDFLib/rdflib http://pypi.python.org/pypi/rdflib"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="berkdb examples mysql redland sqlite test"

RDEPEND="
	dev-python/isodate[${PYTHON_USEDEP}]
	dev-python/html5lib[$(python_gen_usedep 'python2*')]
	dev-python/pyparsing[${PYTHON_USEDEP}]
	berkdb? ( dev-python/bsddb3[${PYTHON_USEDEP}] )
	mysql? ( dev-python/mysql-python[$(python_gen_usedep 'python2*')] )
	redland? ( dev-libs/redland-bindings[python,$(python_gen_usedep 'python2*')] )"
DEPEND="${RDEPEND}
	dev-python/setuptools[${PYTHON_USEDEP}]
	test? ( dev-python/sparql-wrapper[${PYTHON_USEDEP}]
		>=dev-python/nose-1.3.1-r1[${PYTHON_USEDEP}] )"

python_prepare_all() {
	# Upstream manufactured .pyc files which promptly break distutils' src_test
	find -name "*.py[oc~]" -delete || die
	distutils-r1_python_prepare_all
}

python_test() {
	if python_is_python3; then
		pushd "${BUILD_DIR}/src/" > /dev/null
		if [[ "${EPYTHON}" == 'python3.4' ]]; then
			sed -e 's:test_rdfpipe_bytes_vs_str:_&:' \
				-e 's:test_rdfpipe_mdata_open:_&:' \
				-i test/test_issue375.py || die
			sed -e 's:testHTML:_&:' \
				-i test/test_xmlliterals.py || die
		fi
		"${PYTHON}" ./run_tests.py || die "Tests failed under ${EPYTHON}"
		popd > /dev/null
	else
		"${PYTHON}" ./run_tests.py || die "Tests failed under ${EPYTHON}"
	fi
}

python_install_all() {
	use examples && local EXAMPLES=( examples/. )
	distutils-r1_python_install_all
}