[gentoo-commits] gentoo-x86 commit in net-misc/minidlna: minidlna-1.1.4.ebuild ChangeLog minidlna-1.1.0-r3.ebuild minidlna-1.1.0-r2.ebuild minidlna-1.1.1.ebuild minidlna-1.1.2.ebuild

["Michael Weber (xmw)" <xmw@gentoo.org>]

xmw         15/02/27 11:50:34

  Modified:             ChangeLog
  Added:                minidlna-1.1.4.ebuild
  Removed:              minidlna-1.1.0-r3.ebuild minidlna-1.1.0-r2.ebuild
                        minidlna-1.1.1.ebuild minidlna-1.1.2.ebuild
  Log:
  Version bump with gentoo logo (bug 522112, thanks BT, Steve Dibb, Perfect Gentleman and baru reddy).
  
  (Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

Revision  Changes    Path
1.44                 net-misc/minidlna/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/minidlna/ChangeLog?rev=1.44&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/minidlna/ChangeLog?rev=1.44&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/minidlna/ChangeLog?r1=1.43&r2=1.44

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/minidlna/ChangeLog,v
retrieving revision 1.43
retrieving revision 1.44
diff -u -r1.43 -r1.44
--- ChangeLog	30 Oct 2014 10:01:45 -0000	1.43
+++ ChangeLog	27 Feb 2015 11:50:34 -0000	1.44
@@ -1,6 +1,14 @@
 # ChangeLog for net-misc/minidlna
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/minidlna/ChangeLog,v 1.43 2014/10/30 10:01:45 ago Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/minidlna/ChangeLog,v 1.44 2015/02/27 11:50:34 xmw Exp $
+
+*minidlna-1.1.4 (27 Feb 2015)
+
+  27 Feb 2015; Michael Weber <xmw@gentoo.org> +minidlna-1.1.4.ebuild,
+  -minidlna-1.1.0-r2.ebuild, -minidlna-1.1.0-r3.ebuild, -minidlna-1.1.1.ebuild,
+  -minidlna-1.1.2.ebuild:
+  Version bump with gentoo logo (bug 522112, thanks BT, Steve Dibb, Perfect
+  Gentleman and baru reddy).
 
   30 Oct 2014; Agostino Sarubbo <ago@gentoo.org> minidlna-1.1.3.ebuild:
   Stable for x86, wrt bug #524644



1.1                  net-misc/minidlna/minidlna-1.1.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/minidlna/minidlna-1.1.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/minidlna/minidlna-1.1.4.ebuild?rev=1.1&content-type=text/plain

Index: minidlna-1.1.4.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/minidlna/minidlna-1.1.4.ebuild,v 1.1 2015/02/27 11:50:34 xmw Exp $

EAPI=5

inherit eutils linux-info systemd toolchain-funcs user

DESCRIPTION="DLNA/UPnP-AV compliant media server"
HOMEPAGE="http://minidlna.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PV}/${P}.tar.gz
	http://dev.gentoo.org/~xmw/${PN}-gentoo-artwork.patch.xz"

LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="netgear readynas"

RDEPEND="dev-db/sqlite:3
	media-libs/flac
	media-libs/libexif
	media-libs/libid3tag
	media-libs/libogg
	media-libs/libvorbis
	virtual/ffmpeg
	virtual/jpeg:0"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

CONFIG_CHECK="~INOTIFY_USER"

pkg_setup() {
	local my_is_new="yes"
	[ -d "${EPREFIX}"/var/lib/${PN} ] && my_is_new="no"
	enewgroup ${PN}
	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
	if [ -d "${EPREFIX}"/var/lib/${PN} ] && [ "${my_is_new}" == "yes" ] ; then
		# created by above enewuser command w/ wrong group and permissions
		chown ${PN}:${PN} "${EPREFIX}"/var/lib/${PN} || die
		chmod 0750 "${EPREFIX}"/var/lib/${PN} || die
		# if user already exists, but /var/lib/minidlna is missing
		# rely on ${D}/var/lib/minidlna created in src_install
	fi

	linux-info_pkg_setup
}

src_prepare() {
	sed -e "/log_dir/s:/var/log:/var/log/${PN}:" \
		-e "/db_dir/s:/var/cache/:/var/lib/:" \
		-i ${PN}.conf || die

	epatch "${WORKDIR}"/${PN}-gentoo-artwork.patch

	epatch_user
}

src_configure() {
	econf \
		--disable-silent-rules \
		--with-db-path=/var/lib/${PN} \
		--with-log-path=/var/log/${PN} \
		--enable-tivo \
		$(use_enable netgear) \
		$(use_enable readynas)
}

src_install() {
	default

	insinto /etc
	doins ${PN}.conf

	newconfd "${FILESDIR}"/${PN}-1.0.25.confd ${PN}
	newinitd "${FILESDIR}"/${PN}-1.1.2.initd ${PN}
	systemd_newunit "${FILESDIR}"/${PN}-1.1.2.service ${PN}.service
	echo "d /run/${PN} 0755 ${PN} ${PN} -" > "${T}"/${PN}.conf
	systemd_dotmpfilesd "${T}"/${PN}.conf

	dodir /var/{lib,log}/${PN}
	fowners ${PN}:${PN} /var/{lib,log}/${PN}
	fperms 0750 /var/{lib,log}/${PN}

	dodoc AUTHORS NEWS README TODO
	doman ${PN}d.8 ${PN}.conf.5
}

pkg_postinst() {
	elog "minidlna now runs as minidlna:minidlna (bug 426726),"
	elog "logfile is moved to /var/log/minidlna/minidlna.log,"
	elog "cache is moved to /var/lib/minidlna."
	elog "Please edit /etc/conf.d/${PN} and file ownerships to suit your needs."
}