[gentoo-commits] gentoo-x86 commit in app-backup/backintime: backintime-1.0.36-r2.ebuild ChangeLog backintime-1.0.36-r1.ebuild

[gentoo-commits] gentoo-x86 commit in app-backup/backintime: backintime-1.0.36-r2.ebuild ChangeLog backintime-1.0.36-r1.ebuild

[Michael Weber (xmw)]

xmw         15/02/27 10:08:43

  Modified:             ChangeLog
  Added:                backintime-1.0.36-r2.ebuild
  Removed:              backintime-1.0.36-r1.ebuild
  Log:
  Revbump for previous RDEPEND change
  
  (Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

Revision  Changes    Path
1.25                 app-backup/backintime/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backintime/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backintime/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backintime/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/backintime/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	27 Feb 2015 10:06:49 -0000	1.24
+++ ChangeLog	27 Feb 2015 10:08:43 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for app-backup/backintime
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/backintime/ChangeLog,v 1.24 2015/02/27 10:06:49 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/backintime/ChangeLog,v 1.25 2015/02/27 10:08:43 xmw Exp $
+
+*backintime-1.0.36-r2 (27 Feb 2015)
+
+  27 Feb 2015; Michael Weber <xmw@gentoo.org> +backintime-1.0.36-r2.ebuild,
+  -backintime-1.0.36-r1.ebuild:
+  Revbump for previous RDEPEND change
 
   27 Feb 2015; Michael Weber <xmw@gentoo.org> backintime-1.0.36-r1.ebuild:
   Add DEPEND on dbus-python (bug 522734, thanks Martin LORANG).



1.1                  app-backup/backintime/backintime-1.0.36-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backintime/backintime-1.0.36-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/backintime/backintime-1.0.36-r2.ebuild?rev=1.1&content-type=text/plain

Index: backintime-1.0.36-r2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-backup/backintime/backintime-1.0.36-r2.ebuild,v 1.1 2015/02/27 10:08:43 xmw Exp $

EAPI=5

PYTHON_COMPAT=( python{2_6,2_7} )

inherit eutils python-single-r1

DESCRIPTION="A simple backup system inspired by TimeVault and FlyBack, with a GUI for GNOME and KDE4"
HOMEPAGE="http://backintime.le-web.org/"
SRC_URI="http://${PN}.le-web.org/download/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="kde gnome"

RDEPEND="${PYTHON_DEPS}
	dev-python/dbus-python[${PYTHON_USEDEP}]
	dev-python/keyring[${PYTHON_USEDEP}]
	dev-python/notify-python[${PYTHON_USEDEP}]
	net-misc/openssh
	net-misc/rsync[xattr,acl]
	kde? (
		>=kde-base/kdelibs-4
		kde-base/pykde4[${PYTHON_USEDEP}]
		kde-base/kompare
		kde-base/kdesu
	)
	gnome? (
		gnome-base/libglade
		dev-util/meld
		gnome-base/gnome-session
		dev-python/gnome-vfs-python
		dev-python/libgnome-python
		dev-python/pygobject:2[${PYTHON_USEDEP}]
		dev-python/pygtk[${PYTHON_USEDEP}]
		x11-libs/gksu
	)"

DEPEND="${RDEPEND}"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

S=${WORKDIR}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.0.24-dont-install-license.patch

	#fix doc install location
	sed -i "s:/doc/kde4/HTML/:/doc/HTML/:g" kde4/Makefile.template || die
	sed -i "s:/doc/backintime:/doc/${PF}:g" common/Makefile.template || die

	cp "${FILESDIR}"/backintime-1.0.4-kde4-root.desktop \
		kde4/backintime-kde4-root.desktop || die

	#bug 482106
	epatch "${FILESDIR}"/${P}-wrapper.patch
	sed -e "s:^python2 :${PYTHON} :" \
		-e "s:APP_PATH=\"/usr:APP_PATH=\"${EPREFIX}/usr:" \
		-i kde4/backintime-kde4 gnome/backintime-gnome \
			common/backintime || die

	backintime_variants="common $(usex gnome gnome '') $(usex kde kde4 '')"
	backintime_run() {
		local variant
		for variant in ${backintime_variants} ; do
			einfo "$variant: run \"$@\""
			pushd "${S}"/${variant} || die
			"${@}" || die
			popd
		done
	}

	if [ -n ${LINGUAS+x} ] ; then
		cd common/po || die
		for po in *.po ; do
			if ! has ${po/.po} ${LINGUAS} ; then
				rm ${po} || die
			fi
		done
	fi
}

src_configure() {
	backintime_run econf
}

src_compile() {
	backintime_run emake
}

src_install() {
	backintime_run emake DESTDIR="${D}" install
	python_optimize "${D}"
}