* [gentoo-commits] gentoo-x86 commit in net-libs/gtk-vnc: gtk-vnc-0.5.4.ebuild metadata.xml ChangeLog
@ 2015-02-12 13:16 Pacho Ramos (pacho)
0 siblings, 0 replies; only message in thread
From: Pacho Ramos (pacho) @ 2015-02-12 13:16 UTC (permalink / raw
To: gentoo-commits
pacho 15/02/12 13:16:54
Modified: metadata.xml ChangeLog
Added: gtk-vnc-0.5.4.ebuild
Log:
Version bump
(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.9 net-libs/gtk-vnc/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gtk-vnc/metadata.xml?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gtk-vnc/metadata.xml?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gtk-vnc/metadata.xml?r1=1.8&r2=1.9
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gtk-vnc/metadata.xml,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- metadata.xml 10 Aug 2013 20:23:22 -0000 1.8
+++ metadata.xml 12 Feb 2015 13:16:54 -0000 1.9
@@ -5,8 +5,5 @@
<herd>virtualization</herd>
<use>
<flag name="gtk3">Build the gtk3 gtk-vnc library and other gtk3 assets</flag>
- <flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg>
- for introspection</flag>
- <flag name="vala">Enable bindings for <pkg>dev-lang/vala</pkg></flag>
</use>
</pkgmetadata>
1.124 net-libs/gtk-vnc/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gtk-vnc/ChangeLog?rev=1.124&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gtk-vnc/ChangeLog?rev=1.124&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gtk-vnc/ChangeLog?r1=1.123&r2=1.124
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/gtk-vnc/ChangeLog,v
retrieving revision 1.123
retrieving revision 1.124
diff -u -r1.123 -r1.124
--- ChangeLog 13 Nov 2014 12:30:40 -0000 1.123
+++ ChangeLog 12 Feb 2015 13:16:54 -0000 1.124
@@ -1,6 +1,12 @@
# ChangeLog for net-libs/gtk-vnc
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gtk-vnc/ChangeLog,v 1.123 2014/11/13 12:30:40 pacho Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gtk-vnc/ChangeLog,v 1.124 2015/02/12 13:16:54 pacho Exp $
+
+*gtk-vnc-0.5.4 (12 Feb 2015)
+
+ 12 Feb 2015; Pacho Ramos <pacho@gentoo.org> +gtk-vnc-0.5.4.ebuild,
+ metadata.xml:
+ Version bump
13 Nov 2014; Pacho Ramos <pacho@gentoo.org> -files/gtk-vnc-0.5.0-pod.patch,
-files/gtk-vnc-0.5.0-pulseaudio-automagic.patch, -gtk-vnc-0.5.2.ebuild:
1.1 net-libs/gtk-vnc/gtk-vnc-0.5.4.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gtk-vnc/gtk-vnc-0.5.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/gtk-vnc/gtk-vnc-0.5.4.ebuild?rev=1.1&content-type=text/plain
Index: gtk-vnc-0.5.4.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/gtk-vnc/gtk-vnc-0.5.4.ebuild,v 1.1 2015/02/12 13:16:54 pacho Exp $
EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python2_7 )
VALA_MIN_API_VERSION="0.16"
VALA_USE_DEPEND="vapigen"
inherit gnome2 python-r1 vala
DESCRIPTION="VNC viewer widget for GTK"
HOMEPAGE="https://wiki.gnome.org/Projects/gtk-vnc"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="examples +gtk3 +introspection pulseaudio python sasl vala"
REQUIRED_USE="
python? ( ${PYTHON_REQUIRED_USE} )
vala? ( gtk3 introspection )
"
# libview is used in examples/gvncviewer -- no need
# glib-2.30.1 needed to avoid linking failure due to .la files (bug #399129)
COMMON_DEPEND="
>=dev-libs/glib-2.30.1:2
>=dev-libs/libgcrypt-1.4.2:0
dev-libs/libgpg-error
>=net-libs/gnutls-2.12
>=x11-libs/cairo-1.2
>=x11-libs/gtk+-2.18:2
x11-libs/libX11
gtk3? ( >=x11-libs/gtk+-2.91.3:3 )
introspection? ( >=dev-libs/gobject-introspection-0.9.4 )
pulseaudio? ( media-sound/pulseaudio )
python? (
${PYTHON_DEPS}
>=dev-python/pygtk-2:2[${PYTHON_USEDEP}] )
sasl? ( dev-libs/cyrus-sasl )
"
RDEPEND="${COMMON_DEPEND}"
DEPEND="${COMMON_DEPEND}
>=dev-lang/perl-5
>=dev-util/intltool-0.40
sys-devel/gettext
virtual/pkgconfig
vala? (
$(vala_depend)
>=dev-libs/gobject-introspection-0.9.4 )
"
# eautoreconf requires gnome-common
GTK2_BUILDDIR="${WORKDIR}/${P}_gtk2"
GTK3_BUILDDIR="${WORKDIR}/${P}_gtk3"
src_prepare() {
mkdir -p "${GTK2_BUILDDIR}" || die
mkdir -p "${GTK3_BUILDDIR}" || die
prepare_python() {
mkdir -p "${BUILD_DIR}" || die
}
if use python; then
python_foreach_impl prepare_python
fi
# Fix incorrect codegendir check: h2def.py is in pygobject, not pygtk, upstream bug#744393
sed -e 's/codegendir pygtk-2.0/codegendir pygobject-2.0/g' \
-i src/Makefile.* || die
# libtool seems unable to find this via VPATH so help it
sed -r "s:(gtkvnc_la_LIBADD =) libgtk-vnc-.*\.la:\1 ${GTK2_BUILDDIR}/src/libgtk-vnc-1.0.la:" \
-i src/Makefile.{am,in} || die
vala_src_prepare
gnome2_src_prepare
}
src_configure() {
local myconf
myconf="
$(use_with examples) \
$(use_enable introspection) \
$(use_with pulseaudio) \
$(use_with sasl) \
--with-coroutine=gthread \
--without-libview \
--disable-static \
--disable-vala"
cd "${GTK2_BUILDDIR}" || die
einfo "Running configure in ${GTK2_BUILDDIR}"
ECONF_SOURCE="${S}" gnome2_src_configure ${myconf} \
--with-python=no \
--with-gtk=2.0
configure_python() {
ECONF_SOURCE="${S}" gnome2_src_configure ${myconf} \
$(use_with python) \
--with-gtk=2.0
}
if use python; then
python_foreach_impl run_in_build_dir configure_python
fi
if use gtk3; then
cd "${GTK3_BUILDDIR}" || die
einfo "Running configure in ${GTK3_BUILDDIR}"
# Python support is via gobject-introspection
# Ex: from gi.repository import GtkVnc
ECONF_SOURCE="${S}" gnome2_src_configure ${myconf} \
$(use_enable vala) \
--with-python=no \
--with-gtk=3.0
fi
}
src_compile() {
cd "${GTK2_BUILDDIR}" || die
einfo "Running make in ${GTK2_BUILDDIR}"
gnome2_src_compile
compile_python() {
cd "${BUILD_DIR}"/src || die
# CPPFLAGS set to help find includes for gvnc.override
emake gtkvnc.la \
VPATH="${S}/src:${GTK2_BUILDDIR}/src:${BUILD_DIR}/src" \
CPPFLAGS="${CPPFLAGS} -I${GTK2_BUILDDIR}/src"
}
if use python; then
python_foreach_impl run_in_build_dir compile_python
fi
if use gtk3; then
cd "${GTK3_BUILDDIR}" || die
einfo "Running make in ${GTK3_BUILDDIR}"
gnome2_src_compile
fi
}
src_test() {
cd "${GTK2_BUILDDIR}" || die
einfo "Running make check in ${GTK2_BUILDDIR}"
default
if use gtk3; then
cd "${GTK3_BUILDDIR}" || die
einfo "Running make check in ${GTK3_BUILDDIR}"
default
fi
}
src_install() {
cd "${GTK2_BUILDDIR}" || die
einfo "Running make install in ${GTK2_BUILDDIR}"
gnome2_src_install
install_python() {
cd "${BUILD_DIR}"/src || die
emake install-pyexecLTLIBRARIES DESTDIR="${D}" \
VPATH="${S}/src:${GTK2_BUILDDIR}/src:${BUILD_DIR}/src" \
CPPFLAGS="${CPPFLAGS} -I${GTK2_BUILDDIR}/src"
}
if use python; then
python_foreach_impl run_in_build_dir install_python
fi
if use gtk3; then
cd "${GTK3_BUILDDIR}" || die
einfo "Running make install in ${GTK3_BUILDDIR}"
gnome2_src_install
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-02-12 13:16 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-02-12 13:16 [gentoo-commits] gentoo-x86 commit in net-libs/gtk-vnc: gtk-vnc-0.5.4.ebuild metadata.xml ChangeLog Pacho Ramos (pacho)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox