* [gentoo-commits] gentoo-x86 commit in media-plugins/vdr-xineliboutput: vdr-xineliboutput-9999.ebuild vdr-xineliboutput-2.0.0_p20130821.ebuild ChangeLog
@ 2015-02-12 10:11 Joerg Bornkessel (hd_brummy)
0 siblings, 0 replies; only message in thread
From: Joerg Bornkessel (hd_brummy) @ 2015-02-12 10:11 UTC (permalink / raw
To: gentoo-commits
hd_brummy 15/02/12 10:11:33
Modified: vdr-xineliboutput-9999.ebuild ChangeLog
Added: vdr-xineliboutput-2.0.0_p20130821.ebuild
Log:
new snapshot 20130821; compile fix vdr-2.1.10; cleanup; initsciptvdr-fronted to start sxfb
(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 34C2808A)
Revision Changes Path
1.19 media-plugins/vdr-xineliboutput/vdr-xineliboutput-9999.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-xineliboutput/vdr-xineliboutput-9999.ebuild?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-xineliboutput/vdr-xineliboutput-9999.ebuild?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-xineliboutput/vdr-xineliboutput-9999.ebuild?r1=1.18&r2=1.19
Index: vdr-xineliboutput-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/vdr-xineliboutput/vdr-xineliboutput-9999.ebuild,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- vdr-xineliboutput-9999.ebuild 15 Jan 2015 18:52:25 -0000 1.18
+++ vdr-xineliboutput-9999.ebuild 12 Feb 2015 10:11:33 -0000 1.19
@@ -1,6 +1,6 @@
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-xineliboutput/vdr-xineliboutput-9999.ebuild,v 1.18 2015/01/15 18:52:25 hd_brummy Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-xineliboutput/vdr-xineliboutput-9999.ebuild,v 1.19 2015/02/12 10:11:33 hd_brummy Exp $
EAPI=5
GENTOO_VDR_CONDITIONAL=yes
@@ -57,7 +57,7 @@
RDEPEND="${COMMON_DEPEND}"
S=${WORKDIR}/${PN}
-VDR_CONFD_FILE="${FILESDIR}/confd-1.0.0_pre6"
+VDR_CONFD_FILE="${FILESDIR}/confd-2.0.0"
pkg_setup() {
if ! use vdr && ! use xine; then
@@ -131,6 +131,8 @@
fi
if use xine; then
+ doinit "${FILESDIR}"/vdr-frontend
+
insinto $XINE_PLUGIN_DIR
doins xineplug_inp_xvdr.so
1.80 media-plugins/vdr-xineliboutput/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-xineliboutput/ChangeLog?rev=1.80&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-xineliboutput/ChangeLog?rev=1.80&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-xineliboutput/ChangeLog?r1=1.79&r2=1.80
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/vdr-xineliboutput/ChangeLog,v
retrieving revision 1.79
retrieving revision 1.80
diff -u -r1.79 -r1.80
--- ChangeLog 15 Jan 2015 18:52:25 -0000 1.79
+++ ChangeLog 12 Feb 2015 10:11:33 -0000 1.80
@@ -1,6 +1,16 @@
# ChangeLog for media-plugins/vdr-xineliboutput
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-xineliboutput/ChangeLog,v 1.79 2015/01/15 18:52:25 hd_brummy Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-xineliboutput/ChangeLog,v 1.80 2015/02/12 10:11:33 hd_brummy Exp $
+
+*vdr-xineliboutput-2.0.0_p20130821 (12 Feb 2015)
+
+ 12 Feb 2015; Joerg Bornkessel <hd_brummy@gentoo.org>
+ +vdr-xineliboutput-2.0.0_p20130821.ebuild, vdr-xineliboutput-9999.ebuild,
+ -files/vdr-xineliboutput-1.0.4_p20090810-compile-fix.diff,
+ -files/vdr-xineliboutput-1.0.5-ldflags.patch, +files/confd-2.0.0,
+ -files/vdr-xineliboutput-9999-build-system.patch, +files/vdr-frontend:
+ new snapshot 20130821; compile fix vdr-2.1.10; cleanup; initsciptvdr-fronted
+ to start sxfb
15 Jan 2015; Joerg Bornkessel <hd_brummy@gentoo.org>
vdr-xineliboutput-1.1.0.ebuild, vdr-xineliboutput-9999.ebuild:
1.1 media-plugins/vdr-xineliboutput/vdr-xineliboutput-2.0.0_p20130821.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-xineliboutput/vdr-xineliboutput-2.0.0_p20130821.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-plugins/vdr-xineliboutput/vdr-xineliboutput-2.0.0_p20130821.ebuild?rev=1.1&content-type=text/plain
Index: vdr-xineliboutput-2.0.0_p20130821.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-xineliboutput/vdr-xineliboutput-2.0.0_p20130821.ebuild,v 1.1 2015/02/12 10:11:33 hd_brummy Exp $
EAPI=5
inherit vdr-plugin-2
GENTOO_VDR_CONDITIONAL=yes
DESCRIPTION="VDR Plugin: Xinelib PlugIn"
HOMEPAGE="http://sourceforge.net/projects/xineliboutput/"
SRC_URI="http://vdr.websitec.de/download/${PN}/xineliboutput-2.0.0_p20130821.tar.bz2"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
IUSE="bluray caps dbus fbcon jpeg libextractor nls opengl +vdr vdpau +X +xine xinerama"
COMMON_DEPEND="
vdr? (
>=media-video/vdr-1.6.0
libextractor? ( >=media-libs/libextractor-0.5.20 )
caps? ( sys-libs/libcap )
)
xine? (
( >=media-libs/xine-lib-1.2
virtual/ffmpeg )
fbcon? ( jpeg? ( virtual/jpeg ) )
X? (
x11-libs/libX11
x11-libs/libXext
x11-libs/libXrender
xinerama? ( x11-libs/libXinerama )
dbus? ( dev-libs/dbus-glib dev-libs/glib:2 )
vdpau? ( x11-libs/libvdpau >=media-libs/xine-lib-1.2 )
jpeg? ( virtual/jpeg )
bluray? ( media-libs/libbluray )
opengl? ( virtual/opengl )
)
)"
DEPEND="${COMMON_DEPEND}
virtual/pkgconfig
sys-kernel/linux-headers
nls? ( sys-devel/gettext )
xine? (
X? (
x11-proto/xproto
x11-libs/libXxf86vm
)
)"
RDEPEND="${COMMON_DEPEND}"
REQUIRED_USE=" || ( vdr xine )"
VDR_CONFD_FILE="${FILESDIR}/confd-2.0.0"
pkg_setup() {
vdr-plugin-2_pkg_setup
if use xine; then
XINE_PLUGIN_DIR=$(pkg-config --variable=plugindir libxine)
[ -z "${XINE_PLUGIN_DIR}" ] && die "Could not find xine plugin dir"
fi
}
src_prepare() {
vdr-plugin-2_src_prepare
if has_version ">=media-video/vdr-2.1.10"; then
sed -e "s:pm = RenderPixmaps():pm = dynamic_cast<cPixmapMemory *>(RenderPixmaps()):"\
-e "s:delete pm;:DestroyPixmap(pm);:"\
-i osd.c
fi
}
src_configure() {
local myconf
if has_version ">=media-libs/xine-lib-1.2"; then
myconf="${myconf} --enable-libavutil"
else
myconf="${myconf} --disable-libavutil"
fi
# No autotools based configure script
./configure \
--cc=$(tc-getCC) \
--cxx=$(tc-getCXX) \
$(use_enable X x11) \
$(use_enable X xshm) \
$(use_enable X xdpms) \
$(use_enable X xshape) \
$(use_enable X xrender) \
$(use_enable fbcon fb) \
$(use_enable vdr) \
$(use_enable xine libxine) \
$(use_enable libextractor) \
$(use_enable caps libcap) \
$(use_enable jpeg libjpeg) \
$(use_enable xinerama) \
$(use_enable vdpau) \
$(use_enable dbus dbus-glib-1) \
$(use_enable nls i18n) \
$(use_enable bluray libbluray) \
$(use_enable opengl) \
${myconf} \
|| die
# UINT64_C is needed by ffmpeg headers
append-cxxflags -D__STDC_CONSTANT_MACROS
}
src_install() {
if use vdr; then
vdr-plugin-2_src_install
# bug 346989
insinto /etc/vdr/plugins/xineliboutput/
doins examples/allowed_hosts.conf
fowners -R vdr:vdr /etc/vdr/
if use nls; then
emake DESTDIR="${D}" i18n
fi
if use xine; then
doinit "${FILESDIR}"/vdr-frontend
insinto $XINE_PLUGIN_DIR
doins xineplug_inp_xvdr.so
insinto $XINE_PLUGIN_DIR/post
doins xineplug_post_*.so
if use fbcon; then
dobin vdr-fbfe
insinto $VDR_PLUGIN_DIR
doins libxineliboutput-fbfe.so.*
fi
if use X; then
dobin vdr-sxfe
insinto $VDR_PLUGIN_DIR
doins libxineliboutput-sxfe.so.*
fi
fi
else
emake DESTDIR="${D}" install
dodoc HISTORY README
fi
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-02-12 10:11 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-02-12 10:11 [gentoo-commits] gentoo-x86 commit in media-plugins/vdr-xineliboutput: vdr-xineliboutput-9999.ebuild vdr-xineliboutput-2.0.0_p20130821.ebuild ChangeLog Joerg Bornkessel (hd_brummy)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox