* [gentoo-commits] gentoo-x86 commit in gnome-extra/evolution-data-server: evolution-data-server-3.12.11.ebuild metadata.xml ChangeLog evolution-data-server-3.12.9.ebuild
@ 2015-02-09 12:57 Pacho Ramos (pacho)
0 siblings, 0 replies; only message in thread
From: Pacho Ramos (pacho) @ 2015-02-09 12:57 UTC (permalink / raw
To: gentoo-commits
pacho 15/02/09 12:57:44
Modified: metadata.xml ChangeLog
Added: evolution-data-server-3.12.11.ebuild
Removed: evolution-data-server-3.12.9.ebuild
Log:
Version bump, drop old
(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.8 gnome-extra/evolution-data-server/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/metadata.xml?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/metadata.xml?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/metadata.xml?r1=1.7&r2=1.8
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/metadata.xml,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- metadata.xml 9 Jun 2013 18:31:25 -0000 1.7
+++ metadata.xml 9 Feb 2015 12:57:44 -0000 1.8
@@ -6,7 +6,6 @@
<flag name="api-doc-extras">Build documentation for private APIs</flag>
<flag name="gnome-online-accounts">Enable using
<pkg>net-libs/gnome-online-accounts</pkg> for authorization</flag>
- <flag name="vala">Build <pkg>dev-lang/vala</pkg> bindings</flag>
<flag name="weather">Enable optional weather calendar support</flag>
</use>
</pkgmetadata>
1.410 gnome-extra/evolution-data-server/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?rev=1.410&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?rev=1.410&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog?r1=1.409&r2=1.410
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v
retrieving revision 1.409
retrieving revision 1.410
diff -u -r1.409 -r1.410
--- ChangeLog 14 Jan 2015 10:11:03 -0000 1.409
+++ ChangeLog 9 Feb 2015 12:57:44 -0000 1.410
@@ -1,6 +1,13 @@
# ChangeLog for gnome-extra/evolution-data-server
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v 1.409 2015/01/14 10:11:03 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/ChangeLog,v 1.410 2015/02/09 12:57:44 pacho Exp $
+
+*evolution-data-server-3.12.11 (09 Feb 2015)
+
+ 09 Feb 2015; Pacho Ramos <pacho@gentoo.org>
+ +evolution-data-server-3.12.11.ebuild, -evolution-data-server-3.12.9.ebuild,
+ metadata.xml:
+ Version bump, drop old
*evolution-data-server-3.12.10 (14 Jan 2015)
1.1 gnome-extra/evolution-data-server/evolution-data-server-3.12.11.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-3.12.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-3.12.11.ebuild?rev=1.1&content-type=text/plain
Index: evolution-data-server-3.12.11.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-3.12.11.ebuild,v 1.1 2015/02/09 12:57:44 pacho Exp $
EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python2_7 python3_4 pypy pypy2_0 )
VALA_MIN_API_VERSION="0.22"
VALA_USE_DEPEND="vapigen"
inherit db-use flag-o-matic gnome2 python-any-r1 vala virtualx
DESCRIPTION="Evolution groupware backend"
HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
SLOT="0/49" # subslot = libcamel-1.2 soname version
IUSE="api-doc-extras +gnome-online-accounts +gtk +introspection ipv6 ldap kerberos vala +weather"
REQUIRED_USE="vala? ( introspection )"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~x86-solaris"
RDEPEND="
>=app-crypt/gcr-3.4
>=app-crypt/libsecret-0.5[crypt]
>=dev-db/sqlite-3.5:=
>=dev-libs/glib-2.36:2
>=dev-libs/libgdata-0.10:=
>=dev-libs/libical-0.43:=
>=net-libs/libsoup-2.42:2.4
>=dev-libs/libxml2-2
>=dev-libs/nspr-4.4:=
>=dev-libs/nss-3.9:=
>=sys-libs/db-4:=
dev-libs/icu:=
sys-libs/zlib:=
virtual/libiconv
gtk? (
>=app-crypt/gcr-3.4[gtk]
>=x11-libs/gtk+-3.2:3
)
gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.8 )
introspection? ( >=dev-libs/gobject-introspection-0.9.12 )
kerberos? ( virtual/krb5:= )
ldap? ( >=net-nds/openldap-2:= )
weather? ( >=dev-libs/libgweather-3.8:2= )
"
DEPEND="${RDEPEND}
${PYTHON_DEPS}
dev-util/gdbus-codegen
dev-util/gperf
>=dev-util/gtk-doc-am-1.14
>=dev-util/intltool-0.35.5
>=gnome-base/gnome-common-3.5.5
>=sys-devel/gettext-0.17
virtual/pkgconfig
vala? ( $(vala_depend) )
"
# eautoreconf needs:
# >=gnome-base/gnome-common-2
# Some tests fail due to missings locales.
# Also, dbus tests are flacky, bugs #397975 #501834
# It looks like a nightmare to disable those for now.
RESTRICT="test"
pkg_setup() {
python-any-r1_pkg_setup
}
src_prepare() {
use vala && vala_src_prepare
# Fix relink issues in src_install
ELTCONF="--reverse-deps"
gnome2_src_prepare
# Fix compilation flags crazyness, upstream bug #653157
sed 's/^\(AM_CFLAGS="\)$WARNING_FLAGS/\1/' \
-i configure || die "sed failed"
}
src_configure() {
# /usr/include/db.h is always db-1 on FreeBSD
# so include the right dir in CPPFLAGS
append-cppflags "-I$(db_includedir)"
# phonenumber does not exist in tree
gnome2_src_configure \
$(use_enable api-doc-extras gtk-doc) \
$(use_with api-doc-extras private-docs) \
$(use_enable gnome-online-accounts goa) \
$(use_enable gtk) \
$(use_enable introspection) \
$(use_enable ipv6) \
$(use_with kerberos krb5 "${EPREFIX}"/usr) \
$(use_with ldap openldap) \
$(use_enable vala vala-bindings) \
$(use_enable weather) \
--enable-google \
--enable-largefile \
--enable-smime \
--with-libdb="${EPREFIX}"/usr \
--without-phonenumber \
--disable-examples \
--disable-uoa
}
src_install() {
gnome2_src_install
if use ldap; then
insinto /etc/openldap/schema
doins "${FILESDIR}"/calentry.schema
dosym /usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
fi
}
src_test() {
unset DBUS_SESSION_BUS_ADDRESS
unset ORBIT_SOCKETDIR
unset SESSION_MANAGER
unset DISPLAY
Xemake check
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-02-09 12:57 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-02-09 12:57 [gentoo-commits] gentoo-x86 commit in gnome-extra/evolution-data-server: evolution-data-server-3.12.11.ebuild metadata.xml ChangeLog evolution-data-server-3.12.9.ebuild Pacho Ramos (pacho)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox