[gentoo-commits] gentoo-x86 commit in app-i18n/imsettings: imsettings-1.6.8.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in app-i18n/imsettings: imsettings-1.6.8.ebuild ChangeLog

[Naohiro Aota (naota)]

naota       15/02/07 13:39:09

  Modified:             ChangeLog
  Added:                imsettings-1.6.8.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key F8551514)

Revision  Changes    Path
1.17                 app-i18n/imsettings/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/imsettings/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/imsettings/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/imsettings/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-i18n/imsettings/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	10 Jan 2014 10:13:52 -0000	1.16
+++ ChangeLog	7 Feb 2015 13:39:09 -0000	1.17
@@ -1,6 +1,11 @@
 # ChangeLog for app-i18n/imsettings
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-i18n/imsettings/ChangeLog,v 1.16 2014/01/10 10:13:52 naota Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/imsettings/ChangeLog,v 1.17 2015/02/07 13:39:09 naota Exp $
+
+*imsettings-1.6.8 (07 Feb 2015)
+
+  07 Feb 2015; Naohiro Aota <naota@gentoo.org> +imsettings-1.6.8.ebuild:
+  version bump
 
   10 Jan 2014; Naohiro Aota <naota@gentoo.org>
   +files/imsettings-1.5.0-gir-scanner.patch, imsettings-1.5.0.ebuild:



1.1                  app-i18n/imsettings/imsettings-1.6.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/imsettings/imsettings-1.6.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-i18n/imsettings/imsettings-1.6.8.ebuild?rev=1.1&content-type=text/plain

Index: imsettings-1.6.8.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-i18n/imsettings/imsettings-1.6.8.ebuild,v 1.1 2015/02/07 13:39:09 naota Exp $

EAPI=5

inherit eutils autotools

DESCRIPTION="Delivery framework for general Input Method configuration"
HOMEPAGE="http://tagoh.bitbucket.org/imsettings/"
SRC_URI="https://bitbucket.org/tagoh/imsettings/downloads/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc gconf gtk3 qt4 static-libs xfconf"

# X11 connections are required for test.
RESTRICT="test"

RDEPEND=">=dev-libs/check-0.9.4
	>=dev-libs/glib-2.32
	sys-apps/dbus
	>=x11-libs/gtk+-2.12:2
	>=x11-libs/libgxim-0.5.0
	>=x11-libs/libnotify-0.7
	x11-libs/libX11
	gconf? ( gnome-base/gconf )
	gtk3? ( x11-libs/gtk+:3 )
	qt4? ( dev-qt/qtcore:4 )
	xfconf? ( xfce-base/xfconf )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	dev-util/intltool
	doc? ( dev-util/gtk-doc )"

MY_XINPUTSH="90-xinput"

DOCS=( AUTHORS ChangeLog NEWS README )

src_prepare() {
	# Prevent automagic linking to libxfconf-0.
	if ! use gconf; then
		sed -i -e 's:gconf-2.0:dIsAbLe&:' configure || die
	fi
	if ! use gtk3; then
		sed -i -e 's:gtk+-3.0:dIsAbLe&:' configure || die
	fi
	if ! use qt4; then
		sed -i -e 's:use_qt="yes":use_qt="no":' configure || die
	fi
	if ! use xfconf; then
		sed -i -e 's:libxfconf-0:dIsAbLe&:' configure || die
	fi
}

src_configure() {
	econf \
		$(use_enable static-libs static) \
		--with-xinputsh="${MY_XINPUTSH}"
}

src_install() {
	default

	find "${ED}" -name '*.la' -exec rm -f '{}' +

	fperms 0755 /usr/libexec/xinputinfo.sh
	fperms 0755 "/etc/X11/xinit/xinitrc.d/${MY_XINPUTSH}"
}

pkg_postinst() {
	if [ ! -e "${EPREFIX}/etc/X11/xinit/xinputrc" ] ; then
		ln -sf xinput.d/xcompose.conf "${EPREFIX}/etc/X11/xinit/xinputrc"
	fi
}