[gentoo-commits] gentoo-x86 commit in net-analyzer/dsniff: ChangeLog dsniff-2.4_beta1-r8.ebuild

[gentoo-commits] gentoo-x86 commit in net-analyzer/dsniff: ChangeLog dsniff-2.4_beta1-r8.ebuild

[Jeroen Roovers (jer)]

jer         15/02/07 10:32:27

  Modified:             ChangeLog
  Added:                dsniff-2.4_beta1-r8.ebuild
  Log:
  Add simpler patch 23 (bug #506076 by Yun Zheng Hu).
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.59                 net-analyzer/dsniff/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/dsniff/ChangeLog?rev=1.59&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/dsniff/ChangeLog?rev=1.59&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/dsniff/ChangeLog?r1=1.58&r2=1.59

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/dsniff/ChangeLog,v
retrieving revision 1.58
retrieving revision 1.59
diff -u -r1.58 -r1.59
--- ChangeLog	7 Feb 2015 10:16:17 -0000	1.58
+++ ChangeLog	7 Feb 2015 10:32:27 -0000	1.59
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/dsniff
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/dsniff/ChangeLog,v 1.58 2015/02/07 10:16:17 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/dsniff/ChangeLog,v 1.59 2015/02/07 10:32:27 jer Exp $
+
+*dsniff-2.4_beta1-r8 (07 Feb 2015)
+
+  07 Feb 2015; Jeroen Roovers <jer@gentoo.org> +dsniff-2.4_beta1-r8.ebuild,
+  +files/2.4_beta1-urlsnarf-pcap_timestamps.patch:
+  Add simpler patch 23 (bug #506076 by Yun Zheng Hu).
 
 *dsniff-2.4_beta1-r7 (07 Feb 2015)
 



1.1                  net-analyzer/dsniff/dsniff-2.4_beta1-r8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/dsniff/dsniff-2.4_beta1-r8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/dsniff/dsniff-2.4_beta1-r8.ebuild?rev=1.1&content-type=text/plain

Index: dsniff-2.4_beta1-r8.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/dsniff/dsniff-2.4_beta1-r8.ebuild,v 1.1 2015/02/07 10:32:27 jer Exp $

EAPI=5
inherit autotools eutils flag-o-matic toolchain-funcs

DESCRIPTION="A collection of tools for network auditing and penetration testing"
HOMEPAGE="http://monkey.org/~dugsong/dsniff/"
SRC_URI="
	http://monkey.org/~dugsong/${PN}/beta/${P/_beta/b}.tar.gz
	mirror://debian/pool/main/d/${PN}/${PN}_2.4b1+debian-22.1.debian.tar.gz
"
LICENSE="BSD"

SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="X"

DEPEND="net-libs/libpcap
	>=net-libs/libnet-1.1.2.1-r1
	>=net-libs/libnids-1.21
	>=dev-libs/openssl-0.9.6e
	>=sys-libs/db-4.2.52_p4
	X? ( x11-libs/libXmu )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${P/_beta1/}"

src_prepare() {
	# replace Debian patch 23 with a simpler one (bug #506076)
	mv -v \
		"${WORKDIR}"/debian/patches/23_urlsnarf_timestamp.patch{,.old} || die
	cp -v \
		"${FILESDIR}"/${PV}-urlsnarf-pcap_timestamps.patch \
		"${WORKDIR}"/debian/patches/23_urlsnarf_timestamp.patch || die

	# Debian patchset, needs to be applied in the exact order that "series"
	# lists or patching will fail.
	# Bug #479882
	epatch $(
		for file in $(< "${WORKDIR}"/debian/patches/series ); do
			printf "%s/debian/patches/%s " "${WORKDIR}" "${file}"
		done
	)

	# Bug 125084
	epatch "${FILESDIR}"/${PV}-httppostfix.patch

	# various Makefile.in patches
	epatch "${FILESDIR}"/${PV}-make.patch

	# bug #538462
	epatch "${FILESDIR}"/${PV}-macof-size-calculation.patch

	eautoreconf
}

src_configure() {
	econf \
		$(use_with X x) \
		|| die "econf failed"
}

src_compile() {
	emake CC="$(tc-getCC)"
}

src_install() {
	emake install install_prefix="${D}"
	dodir /etc/dsniff
	cp "${D}"/usr/share/dsniff/{dnsspoof.hosts,dsniff.{magic,services}} \
		"${D}"/etc/dsniff/
	dodoc CHANGES README TODO
}