[gentoo-commits] gentoo-x86 commit in media-video/pitivi: pitivi-0.94.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in media-video/pitivi: pitivi-0.94.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       15/02/03 20:34:29

  Modified:             ChangeLog
  Added:                pitivi-0.94.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.37                 media-video/pitivi/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pitivi/ChangeLog?rev=1.37&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pitivi/ChangeLog?rev=1.37&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pitivi/ChangeLog?r1=1.36&r2=1.37

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/pitivi/ChangeLog,v
retrieving revision 1.36
retrieving revision 1.37
diff -u -r1.36 -r1.37
--- ChangeLog	2 Dec 2014 12:37:11 -0000	1.36
+++ ChangeLog	3 Feb 2015 20:34:29 -0000	1.37
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/pitivi
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/pitivi/ChangeLog,v 1.36 2014/12/02 12:37:11 pacho Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/pitivi/ChangeLog,v 1.37 2015/02/03 20:34:29 pacho Exp $
+
+*pitivi-0.94 (03 Feb 2015)
+
+  03 Feb 2015; Pacho Ramos <pacho@gentoo.org> +pitivi-0.94.ebuild:
+  Version bump
 
   02 Dec 2014; Pacho Ramos <pacho@gentoo.org>
   -files/pitivi-0.13.5-work-with-old-good.patch, -pitivi-0.14.1.ebuild,



1.1                  media-video/pitivi/pitivi-0.94.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pitivi/pitivi-0.94.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pitivi/pitivi-0.94.ebuild?rev=1.1&content-type=text/plain

Index: pitivi-0.94.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/pitivi/pitivi-0.94.ebuild,v 1.1 2015/02/03 20:34:29 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python3_4 )

inherit gnome2 python-single-r1 eutils virtualx multilib

DESCRIPTION="A non-linear video editor using the GStreamer multimedia framework"
HOMEPAGE="http://www.pitivi.org"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64"

IUSE="v4l test"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

COMMON_DEPEND="
	${PYTHON_DEPS}
	>=dev-python/pycairo-1.10[${PYTHON_USEDEP}]
	>=x11-libs/cairo-1.10
"
RDEPEND="${COMMON_DEPEND}
	dev-libs/glib:2

	>=dev-libs/gobject-introspection-1.34
	dev-python/dbus-python[${PYTHON_USEDEP}]
	>=dev-python/gst-python-1.1.90:1.0[${PYTHON_USEDEP}]
	dev-python/numpy[${PYTHON_USEDEP}]
	>=dev-python/pygobject-3.8:3[${PYTHON_USEDEP}]
	dev-python/pyxdg[${PYTHON_USEDEP}]

	gnome-base/librsvg:=

	>=media-libs/clutter-1.12:1.0[introspection]
	>=media-libs/clutter-gst-2:2.0[introspection]
	>=media-libs/clutter-gtk-1.4:1.0[introspection]
	>=media-libs/gnonlin-1.4:1.0
	>=media-libs/gstreamer-1.4:1.0[introspection]
	>=media-libs/gstreamer-editing-services-1.4:1.0[introspection]
	>=media-libs/gst-plugins-base-1.4:1.0
	>=media-libs/gst-plugins-good-1.4:1.0
	>=media-plugins/gst-plugins-libav-1.2:1.0

	x11-libs/libnotify[introspection]
	>=x11-libs/gtk+-3.8:3[introspection]

	v4l? ( >=media-plugins/gst-plugins-v4l2-1.4:1.0 )
"
DEPEND="${RDEPEND}
	dev-python/setuptools
	>=app-text/gnome-doc-utils-0.18.0
	>=dev-util/intltool-0.35.5
	sys-devel/gettext
	virtual/pkgconfig
	test? ( dev-python/mock[${PYTHON_USEDEP}] )
"

src_configure() {
	gnome2_src_configure \
		ITSTOOL="$(type -P true)" \
		--disable-static
}

src_test() {
	# Force Xvfb to be used
	unset DISPLAY
	unset DBUS_SESSION_BUS_ADDRESS
	export PITIVI_TOP_LEVEL_DIR="${S}"
	Xemake check
}

src_install() {
	gnome2_src_install
	python_fix_shebang "${D}"
}