[gentoo-commits] gentoo-x86 commit in dev-libs/libf2c: ChangeLog libf2c-20110801-r4.ebuild

["Justin Lecher (jlec)" <jlec@gentoo.org>]

jlec        15/02/02 08:28:51

  Modified:             ChangeLog
  Added:                libf2c-20110801-r4.ebuild
  Log:
  dev-libs/libf2c: Add patch for format-security, #538342; thanks Ted Tanberry for the patch
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.63                 dev-libs/libf2c/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libf2c/ChangeLog?rev=1.63&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libf2c/ChangeLog?rev=1.63&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libf2c/ChangeLog?r1=1.62&r2=1.63

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libf2c/ChangeLog,v
retrieving revision 1.62
retrieving revision 1.63
diff -u -r1.62 -r1.63
--- ChangeLog	3 Feb 2014 09:34:00 -0000	1.62
+++ ChangeLog	2 Feb 2015 08:28:51 -0000	1.63
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libf2c
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libf2c/ChangeLog,v 1.62 2014/02/03 09:34:00 jlec Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libf2c/ChangeLog,v 1.63 2015/02/02 08:28:51 jlec Exp $
+
+*libf2c-20110801-r4 (02 Feb 2015)
+
+  02 Feb 2015; Justin Lecher <jlec@gentoo.org> +libf2c-20110801-r4.ebuild,
+  +files/libf2c-20110801-format-security.patch:
+  Add patch for format-security, #538342; thanks Ted Tanberry for the patch
 
   03 Feb 2014; Justin Lecher <jlec@gentoo.org>
   -files/20070912-link-shared-libf2c-correctly.patch,



1.1                  dev-libs/libf2c/libf2c-20110801-r4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libf2c/libf2c-20110801-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libf2c/libf2c-20110801-r4.ebuild?rev=1.1&content-type=text/plain

Index: libf2c-20110801-r4.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libf2c/libf2c-20110801-r4.ebuild,v 1.1 2015/02/02 08:28:51 jlec Exp $

EAPI=5

inherit eutils multilib toolchain-funcs

DESCRIPTION="Library that converts FORTRAN to C source"
HOMEPAGE="http://www.netlib.org/f2c/"
SRC_URI="${HOMEPAGE}/${PN}.zip -> ${P}.zip"

LICENSE="HPND"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE="static-libs"

RDEPEND=""
DEPEND="${RDEPEND}
	app-arch/unzip"

S="${WORKDIR}"

src_prepare() {
	epatch \
		"${FILESDIR}"/20051004-add-ofiles-dep.patch \
		"${FILESDIR}"/20090407-link-shared-libf2c-correctly.patch \
		"${FILESDIR}"/${P}-main.patch\
		"${FILESDIR}"/${P}-64bit-long.patch \
		"${FILESDIR}"/${P}-format-security.patch
	sed -i -e "s/ld /$(tc-getLD) /" makefile.u || die
}

src_compile() {
	emake \
		-f makefile.u \
		libf2c.so \
		CFLAGS="${CFLAGS} -fPIC" \
		CC="$(tc-getCC)"

	# Clean up files so we can recompile without PIC for the static lib
	if use static-libs; then
		rm *.o || die "clean failed"
		emake \
			-f makefile.u \
			all \
			CFLAGS="${CFLAGS}" \
			CC="$(tc-getCC)"
	fi
}

src_install () {
	dolib libf2c.so.2
	dosym libf2c.so.2 /usr/$(get_libdir)/libf2c.so
	use static-libs && dolib.a libf2c.a
	doheader f2c.h
	dodoc README Notice
}