[gentoo-commits] gentoo-x86 commit in x11-wm/fluxbox: fluxbox-1.3.5-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in x11-wm/fluxbox: fluxbox-1.3.5-r1.ebuild ChangeLog

[Ian Delaney (idella4)]

idella4     15/01/26 02:37:31

  Modified:             ChangeLog
  Added:                fluxbox-1.3.5-r1.ebuild
  Log:
  revbump to -1.3.5; patch by D. Campbell, fixes bug #537356 made by co-maintainer
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

Revision  Changes    Path
1.321                x11-wm/fluxbox/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/fluxbox/ChangeLog?rev=1.321&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/fluxbox/ChangeLog?rev=1.321&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/fluxbox/ChangeLog?r1=1.320&r2=1.321

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v
retrieving revision 1.320
retrieving revision 1.321
diff -u -r1.320 -r1.321
--- ChangeLog	24 Jan 2015 03:11:20 -0000	1.320
+++ ChangeLog	26 Jan 2015 02:37:31 -0000	1.321
@@ -1,6 +1,12 @@
 # ChangeLog for x11-wm/fluxbox
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v 1.320 2015/01/24 03:11:20 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/ChangeLog,v 1.321 2015/01/26 02:37:31 idella4 Exp $
+
+*fluxbox-1.3.5-r1 (26 Jan 2015)
+
+  26 Jan 2015; Ian Delaney <idella4@gentoo.org> +fluxbox-1.3.5-r1.ebuild:
+  revbump to -1.3.5; patch by D. Campbell, fixes bug #537356 made by co-
+  maintainer
 
 *fluxbox-1.3.6-r1 (24 Jan 2015)
 



1.1                  x11-wm/fluxbox/fluxbox-1.3.5-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/fluxbox/fluxbox-1.3.5-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-wm/fluxbox/fluxbox-1.3.5-r1.ebuild?rev=1.1&content-type=text/plain

Index: fluxbox-1.3.5-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/fluxbox/fluxbox-1.3.5-r1.ebuild,v 1.1 2015/01/26 02:37:31 idella4 Exp $

EAPI=5
inherit eutils flag-o-matic toolchain-funcs prefix

IUSE="nls xinerama bidi +truetype +imlib +slit +toolbar vim-syntax"

DESCRIPTION="Fluxbox is an X11 window manager featuring tabs and an iconbar"

SRC_URI="mirror://sourceforge/fluxbox/${P}.tar.lzma"
HOMEPAGE="http://www.fluxbox.org"
SLOT="0"
LICENSE="MIT"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux"

RDEPEND="
	!!<=x11-misc/fbdesk-1.2.1
	!!<=x11-misc/fluxconf-0.9.9
	!!<x11-themes/fluxbox-styles-fluxmod-20040809-r1
	bidi? ( >=dev-libs/fribidi-0.19.2 )
	imlib? ( >=media-libs/imlib2-1.2.0[X] )
	truetype? ( media-libs/freetype )
	vim-syntax? ( app-vim/fluxbox-syntax )
	x11-libs/libXext
	x11-libs/libXft
	x11-libs/libXpm
	x11-libs/libXrandr
	x11-libs/libXrender
	xinerama? ( x11-libs/libXinerama )
	|| ( x11-misc/gxmessage x11-apps/xmessage )
"
DEPEND="
	${RDEPEND}
	bidi? ( virtual/pkgconfig )
	nls? ( sys-devel/gettext )
	x11-proto/xextproto
"

src_prepare() {
	# We need to be able to include directories rather than just plain
	# files in menu [include] items. This patch will allow us to do clever
	# things with style ebuilds.
	epatch "${FILESDIR}/gentoo_style_location-1.1.x.patch"
	# Fix the semantic issue of icon paths, bug #536370
	epatch "${FILESDIR}"/${PV}-generate_menu-printf-fix.patch

	eprefixify util/fluxbox-generate_menu.in

	epatch "${FILESDIR}"/osx-has-otool.patch

	# Add in the Gentoo -r number to fluxbox -version output.
	if [[ "${PR}" == "r0" ]] ; then
		suffix="gentoo"
	else
		suffix="gentoo-${PR}"
	fi
	sed -i \
		-e "s~\(__fluxbox_version .@VERSION@\)~\1-${suffix}~" \
		version.h.in || die "version sed failed"
}

src_configure() {
	use bidi && append-cppflags "$($(tc-getPKG_CONFIG) --cflags fribidi)"

	econf ${myconf} \
		$(use_enable bidi fribidi ) \
		$(use_enable imlib imlib2) \
		$(use_enable nls) \
		$(use_enable slit ) \
		$(use_enable toolbar ) \
		$(use_enable truetype xft) \
		$(use_enable xinerama) \
		--sysconfdir="${EPREFIX}"/etc/X11/${PN} \
		--with-style="${EPREFIX}"/usr/share/fluxbox/styles/Emerge
}

src_compile() {
	default

	ebegin "Creating a menu file (may take a while)"
	mkdir -p "${T}/home/.fluxbox" || die "mkdir home failed"
	# Call fluxbox-generate_menu through bash since it lacks +x
	# chmod 744 may be an equal fix
	MENUFILENAME="${S}/data/menu" MENUTITLE="Fluxbox ${PV}" \
		CHECKINIT="no. go away." HOME="${T}/home" \
		bash "${S}/util/fluxbox-generate_menu" -is -ds \
		|| die "menu generation failed"
	eend $?
}

src_install() {
	emake DESTDIR="${D}" STRIP="" install
	dodoc README* AUTHORS TODO* ChangeLog NEWS

	# Install the generated menu
	insinto /usr/share/fluxbox
	doins data/menu

	insinto /usr/share/xsessions
	doins "${FILESDIR}"/${PN}.desktop

	exeinto /etc/X11/Sessions
	newexe "${FILESDIR}"/${PN}.xsession fluxbox

	# Styles menu framework
	insinto /usr/share/fluxbox/menu.d/styles
	doins "${FILESDIR}"/styles-menu-fluxbox
	doins "${FILESDIR}"/styles-menu-commonbox
	doins "${FILESDIR}"/styles-menu-user
}