[gentoo-commits] gentoo-x86 commit in x11-misc/redshift: ChangeLog redshift-1.10.ebuild

[gentoo-commits] gentoo-x86 commit in x11-misc/redshift: ChangeLog redshift-1.10.ebuild

[Sebastian Pipping (sping)]

sping       15/01/26 00:18:48

  Modified:             ChangeLog
  Added:                redshift-1.10.ebuild
  Log:
  x11-misc/redshift: 1.10 (bug #537678)
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 0x401A1600)

Revision  Changes    Path
1.32                 x11-misc/redshift/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/ChangeLog?rev=1.32&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/ChangeLog?rev=1.32&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/ChangeLog?r1=1.31&r2=1.32

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v
retrieving revision 1.31
retrieving revision 1.32
diff -u -r1.31 -r1.32
--- ChangeLog	15 Dec 2014 21:10:23 -0000	1.31
+++ ChangeLog	26 Jan 2015 00:18:48 -0000	1.32
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/redshift
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v 1.31 2014/12/15 21:10:23 sping Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/ChangeLog,v 1.32 2015/01/26 00:18:48 sping Exp $
+
+*redshift-1.10 (26 Jan 2015)
+
+  26 Jan 2015; Sebastian Pipping <sping@gentoo.org> +redshift-1.10.ebuild:
+  Bump to 1.10 (bug #537678)
 
 *redshift-1.9.1-r2 (15 Dec 2014)
 



1.1                  x11-misc/redshift/redshift-1.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/redshift-1.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/redshift/redshift-1.10.ebuild?rev=1.1&content-type=text/plain

Index: redshift-1.10.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/redshift/redshift-1.10.ebuild,v 1.1 2015/01/26 00:18:48 sping Exp $

EAPI=5
PYTHON_COMPAT=( python{3_2,3_3,3_4} )

inherit systemd autotools eutils gnome2-utils python-r1

DESCRIPTION="A screen color temperature adjusting software"
HOMEPAGE="http://jonls.dk/redshift/"
SRC_URI="https://github.com/jonls/redshift/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="appindicator geoclue gtk nls"

COMMON_DEPEND=">=x11-libs/libX11-1.4
	x11-libs/libXxf86vm
	x11-libs/libxcb
	x11-libs/libdrm
	geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
	gtk? ( ${PYTHON_DEPS} )"
RDEPEND="${COMMON_DEPEND}
	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
		x11-libs/gtk+:3[introspection]
		dev-python/pyxdg[${PYTHON_USEDEP}] )"
DEPEND="${COMMON_DEPEND}
	>=dev-util/intltool-0.50
	nls? ( sys-devel/gettext )
	appindicator? ( dev-libs/libappindicator )
"

src_prepare() {
	epatch_user
	eautoreconf
}

src_configure() {
	python_export_best

	econf \
		--disable-silent-rules \
		$(use_enable nls) \
		--enable-drm \
		--enable-randr \
		--enable-vidmode \
		--disable-wingdi \
		\
		--disable-corelocation \
		--disable-geoclue \
		$(use_enable geoclue geoclue2) \
		\
		$(use_enable gtk gui) \
		--with-systemduserunitdir="$(systemd_get_userunitdir)" \
		--disable-quartz \
		--disable-ubuntu
}

_impl_specific_src_install() {
	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
			-C src/redshift-gtk install
}

src_install() {
	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install

	if use gtk; then
		python_foreach_impl _impl_specific_src_install
		python_replicate_script "${D}"/usr/bin/redshift-gtk
		dosym redshift-gtk /usr/bin/gtk-redshift
	fi
}

pkg_preinst() {
	use gtk && gnome2_icon_savelist
}

pkg_postinst() {
	use gtk && gnome2_icon_cache_update
}

pkg_postrm() {
	use gtk && gnome2_icon_cache_update
}