* [gentoo-commits] gentoo-x86 commit in www-apps/trac: trac-1.0.3.ebuild ChangeLog
@ 2015-01-18 12:36 Dirkjan Ochtman (djc)
0 siblings, 0 replies; only message in thread
From: Dirkjan Ochtman (djc) @ 2015-01-18 12:36 UTC (permalink / raw
To: gentoo-commits
djc 15/01/18 12:36:22
Modified: ChangeLog
Added: trac-1.0.3.ebuild
Log:
Version bump trac to 1.0.3
(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 30380381)
Revision Changes Path
1.148 www-apps/trac/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/ChangeLog?rev=1.148&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/ChangeLog?rev=1.148&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/ChangeLog?r1=1.147&r2=1.148
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v
retrieving revision 1.147
retrieving revision 1.148
diff -u -r1.147 -r1.148
--- ChangeLog 31 Dec 2014 16:25:35 -0000 1.147
+++ ChangeLog 18 Jan 2015 12:36:22 -0000 1.148
@@ -1,6 +1,11 @@
# ChangeLog for www-apps/trac
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v 1.147 2014/12/31 16:25:35 ago Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/ChangeLog,v 1.148 2015/01/18 12:36:22 djc Exp $
+
+*trac-1.0.3 (18 Jan 2015)
+
+ 18 Jan 2015; Dirkjan Ochtman <djc@gentoo.org> +trac-1.0.3.ebuild:
+ Version bump trac to 1.0.3
31 Dec 2014; Agostino Sarubbo <ago@gentoo.org> trac-1.0.2.ebuild:
Stable for ppc, wrt bug #533372
1.1 www-apps/trac/trac-1.0.3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/trac-1.0.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/trac/trac-1.0.3.ebuild?rev=1.1&content-type=text/plain
Index: trac-1.0.3.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/trac/trac-1.0.3.ebuild,v 1.1 2015/01/18 12:36:22 djc Exp $
EAPI=5
PYTHON_COMPAT=( python{2_6,2_7} )
PYTHON_REQ_USE='sqlite?'
DISTUTILS_SINGLE_IMPL=Yes
inherit distutils-r1 eutils user webapp
MY_PV=${PV/_beta/b}
MY_P=Trac-${MY_PV}
DESCRIPTION="Trac is a minimalistic web-based project management, wiki and bug/issue tracking system"
HOMEPAGE="http://trac.edgewall.com/ http://pypi.python.org/pypi/Trac"
SRC_URI="http://ftp.edgewall.com/pub/trac/${MY_P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="cgi fastcgi i18n mysql postgres +sqlite subversion"
REQUIRED_USE="|| ( mysql postgres sqlite )"
RDEPEND="
dev-python/setuptools[${PYTHON_USEDEP}]
dev-python/docutils[${PYTHON_USEDEP}]
dev-python/genshi[${PYTHON_USEDEP}]
dev-python/pygments[${PYTHON_USEDEP}]
dev-python/pytz[${PYTHON_USEDEP}]
i18n? ( >=dev-python/Babel-0.9.5[${PYTHON_USEDEP}] )
cgi? ( virtual/httpd-cgi )
fastcgi? ( virtual/httpd-fastcgi )
mysql? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
postgres? ( >=dev-python/psycopg-2[${PYTHON_USEDEP}] )
sqlite? (
>=dev-db/sqlite-3.3.4
)
subversion? ( dev-vcs/subversion[python,${PYTHON_USEDEP}] )
"
DEPEND="${RDEPEND}"
S="${WORKDIR}/${MY_P}"
WEBAPP_MANUAL_SLOT="yes"
pkg_setup() {
python-single-r1_pkg_setup
webapp_pkg_setup
enewgroup tracd
enewuser tracd -1 -1 -1 tracd
}
python_prepare_all() {
distutils-r1_python_prepare_all
}
src_test() {
local DISTUTILS_NO_PARALLEL_BUILD=1
distutils-r1_src_test
}
python_test() {
PYTHONPATH=. "${PYTHON}" trac/test.py || die "Tests fail with ${EPYTHON}"
}
python_test_all() {
if use i18n; then
make check
fi
}
# the default src_compile just calls setup.py build
# currently, this switches i18n catalog compilation based on presence of Babel
src_install() {
webapp_src_preinst
distutils-r1_src_install
# project environments might go in here
keepdir /var/lib/trac
# Use this as the egg-cache for tracd
dodir /var/lib/trac/egg-cache
keepdir /var/lib/trac/egg-cache
fowners tracd:tracd /var/lib/trac/egg-cache
# documentation
dodoc -r contrib
# tracd init script
newconfd "${FILESDIR}"/tracd.confd tracd
newinitd "${FILESDIR}"/tracd.initd tracd
if use cgi; then
cp contrib/cgi-bin/trac.cgi "${ED}${MY_CGIBINDIR}" || die
fi
if use fastcgi; then
cp contrib/cgi-bin/trac.fcgi "${ED}${MY_CGIBINDIR}" || die
fi
for lang in en; do
webapp_postinst_txt ${lang} "${FILESDIR}"/postinst-${lang}.txt
webapp_postupgrade_txt ${lang} "${FILESDIR}"/postupgrade-${lang}.txt
done
webapp_src_install
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2015-01-18 12:36 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2015-01-18 12:36 [gentoo-commits] gentoo-x86 commit in www-apps/trac: trac-1.0.3.ebuild ChangeLog Dirkjan Ochtman (djc)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox