[gentoo-commits] gentoo-x86 commit in dev-python/reportlab: reportlab-3.1.8-r2.ebuild ChangeLog

["Mike Gilbert (floppym)" <floppym@gentoo.org>]

floppym     15/01/13 03:14:38

  Modified:             ChangeLog
  Added:                reportlab-3.1.8-r2.ebuild
  Log:
  Sync deps with setup.py.
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.120                dev-python/reportlab/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/reportlab/ChangeLog?rev=1.120&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/reportlab/ChangeLog?rev=1.120&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/reportlab/ChangeLog?r1=1.119&r2=1.120

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/reportlab/ChangeLog,v
retrieving revision 1.119
retrieving revision 1.120
diff -u -r1.119 -r1.120
--- ChangeLog	13 Jan 2015 02:55:17 -0000	1.119
+++ ChangeLog	13 Jan 2015 03:14:38 -0000	1.120
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/reportlab
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/reportlab/ChangeLog,v 1.119 2015/01/13 02:55:17 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/reportlab/ChangeLog,v 1.120 2015/01/13 03:14:38 floppym Exp $
+
+*reportlab-3.1.8-r2 (13 Jan 2015)
+
+  13 Jan 2015; Mike Gilbert <floppym@gentoo.org> +reportlab-3.1.8-r2.ebuild:
+  Sync deps with setup.py.
 
 *reportlab-3.1.44-r1 (13 Jan 2015)
 



1.1                  dev-python/reportlab/reportlab-3.1.8-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/reportlab/reportlab-3.1.8-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/reportlab/reportlab-3.1.8-r2.ebuild?rev=1.1&content-type=text/plain

Index: reportlab-3.1.8-r2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/reportlab/reportlab-3.1.8-r2.ebuild,v 1.1 2015/01/13 03:14:38 floppym Exp $

EAPI="5"
PYTHON_COMPAT=( python{2_7,3_3,3_4} )
# Tests crash with pypy

inherit distutils-r1 flag-o-matic prefix

DESCRIPTION="Tools for generating printable PDF documents from any data source"
HOMEPAGE="http://www.reportlab.com/"
SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz
	http://www.reportlab.com/ftp/fonts/pfbfer-20070710.zip"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
IUSE="doc examples"

RDEPEND="
	>=dev-python/pillow-2.4.0[${PYTHON_USEDEP}]
	>=dev-python/pip-1.4.1[${PYTHON_USEDEP}]
	>=dev-python/setuptools-2.2[${PYTHON_USEDEP}]
	media-fonts/dejavu
	media-libs/libart_lgpl
	sys-libs/zlib
"
DEPEND="${RDEPEND}
	app-arch/unzip
"

DISTUTILS_NO_PARALLEL_BUILD=1

src_unpack() {
	unpack ${P}.tar.gz
	cd ${P}/src/reportlab/fonts || die
	unpack pfbfer-20070710.zip
}

python_prepare_all() {
	sed -i \
		-e "s|/usr/lib/X11/fonts/TrueType/|${EPREFIX}/usr/share/fonts/dejavu/|" \
		-e 's|/usr/local/Acrobat|/opt/Acrobat|g' \
		-e 's|%(HOME)s/fonts|%(HOME)s/.fonts|g' \
		src/reportlab/rl_config.py || die

	eprefixify setup.py
	distutils-r1_python_prepare_all
}

python_compile_all() {
	use doc && emake -C docs html
}

python_compile() {
	if ! python_is_python3; then
		local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
	fi
	distutils-r1_python_compile
}

python_test() {
	pushd tests > /dev/null || die
	"${PYTHON}" runAll.py || die "Testing failed with ${EPYTHON}"
	popd > /dev/null || die
}

python_install_all() {
	use doc && local HTML_DOCS=( docs/build/html/. )
	use examples && local EXAMPLES=( demos/. tools/pythonpoint/demos )

	distutils-r1_python_install_all
}