* [gentoo-commits] gentoo-x86 commit in media-gfx/digikam: ChangeLog digikam-4.6.0.ebuild
@ 2014-12-21 21:41 Andreas HAttel (dilfridge)
0 siblings, 0 replies; 2+ messages in thread
From: Andreas HAttel (dilfridge) @ 2014-12-21 21:41 UTC (permalink / raw
To: gentoo-commits
dilfridge 14/12/21 21:41:17
Modified: ChangeLog
Added: digikam-4.6.0.ebuild
Log:
Version bump
(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key EBE6A336BE19039C!)
Revision Changes Path
1.276 media-gfx/digikam/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/ChangeLog?rev=1.276&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/ChangeLog?rev=1.276&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/ChangeLog?r1=1.275&r2=1.276
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v
retrieving revision 1.275
retrieving revision 1.276
diff -u -r1.275 -r1.276
--- ChangeLog 21 Dec 2014 14:59:44 -0000 1.275
+++ ChangeLog 21 Dec 2014 21:41:17 -0000 1.276
@@ -1,6 +1,11 @@
# ChangeLog for media-gfx/digikam
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v 1.275 2014/12/21 14:59:44 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v 1.276 2014/12/21 21:41:17 dilfridge Exp $
+
+*digikam-4.6.0 (21 Dec 2014)
+
+ 21 Dec 2014; Andreas K. Huettel <dilfridge@gentoo.org> +digikam-4.6.0.ebuild:
+ Version bump
21 Dec 2014; Andreas K. Huettel <dilfridge@gentoo.org> -digikam-4.0.0.ebuild,
-digikam-4.2.0.ebuild, -digikam-4.4.0.ebuild, digikam-4.4.0-r1.ebuild:
1.1 media-gfx/digikam/digikam-4.6.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/digikam-4.6.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/digikam-4.6.0.ebuild?rev=1.1&content-type=text/plain
Index: digikam-4.6.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/digikam-4.6.0.ebuild,v 1.1 2014/12/21 21:41:17 dilfridge Exp $
EAPI=5
KDE_LINGUAS="af ar az be bg bn br bs ca cs csb cy da de el en_GB eo es et eu fa fi fo fr fy ga gl ha he hi hr hsb
hu id is it ja ka kk km ko ku lb lo lt lv mi mk mn ms mt nb nds ne nl nn nso oc pa pl pt pt_BR ro ru
rw se sk sl sq sr sr@Latn ss sv ta te tg th tr tt uk uz uz@cyrillic ven vi wa xh zh_CN zh_HK zh_TW zu"
KDE_HANDBOOK="optional"
CMAKE_MIN_VERSION="2.8"
KDE_MINIMAL="4.10"
KDE_DOC_DIRS="doc-digikam doc-showfoto"
inherit kde4-base
MY_PV=${PV/_/-}
MY_P=${PN}-${MY_PV}
DESCRIPTION="Digital photo management application for KDE"
HOMEPAGE="http://www.digikam.org/"
SRC_URI="mirror://kde/stable/${PN}/${MY_P}.tar.bz2"
LICENSE="GPL-2
handbook? ( FDL-1.2 )"
KEYWORDS="~amd64 ~x86"
SLOT="4"
IUSE="addressbook debug doc gphoto2 mysql semantic-desktop +thumbnails video"
CDEPEND="
|| (
( kde-apps/kdebase-kioslaves:4
kde-apps/libkdcraw:4=
kde-apps/libkexiv2:4=
kde-apps/libkipi:4
kde-apps/marble:4=[plasma] )
( $(add_kdebase_dep kdebase-kioslaves)
kde-base/libkdcraw:4=
kde-base/libkexiv2:4=
$(add_kdebase_dep libkipi)
kde-base/marble:4=[plasma] )
)
media-libs/jasper
media-libs/lcms:2
>=media-libs/lensfun-0.2.6
|| ( kde-apps/libkface:4 >=media-libs/libkface-4.6.0 )
>=media-libs/libkgeomap-4.6.0:=
media-libs/liblqr
>=media-libs/libpgf-6.12.27
media-libs/libpng:0=
>=media-libs/opencv-2.4.9
>=media-libs/tiff-3.8.2
virtual/jpeg
dev-qt/qtgui:4
|| ( dev-qt/qtsql:4[mysql] dev-qt/qtsql:4[sqlite] )
addressbook? ( $(add_kdebase_dep kdepimlibs) )
gphoto2? ( media-libs/libgphoto2:= )
mysql? ( virtual/mysql )
semantic-desktop? (
$(add_kdebase_dep baloo "" 4.12.0)
)
"
RDEPEND="${CDEPEND}
|| ( kde-apps/kreadconfig:4 $(add_kdebase_dep kreadconfig) )
media-plugins/kipi-plugins
video? (
|| (
kde-apps/ffmpegthumbs:4
kde-apps/mplayerthumbs:4
$(add_kdebase_dep mplayerthumbs)
$(add_kdebase_dep ffmpegthumbs)
)
)
"
DEPEND="${CDEPEND}
dev-cpp/eigen:3
dev-libs/boost
sys-devel/gettext
doc? ( app-doc/doxygen )
"
S="${WORKDIR}/${MY_P}/core"
RESTRICT=test
# bug 366505
src_prepare() {
# just to make absolutely sure
rm -rf "${WORKDIR}/${MY_P}/extra" || die
# prepare the handbook
mkdir doc-digikam doc-showfoto || die
echo "add_subdirectory( en )" > doc-digikam/CMakeLists.txt || die
mv "${WORKDIR}/${MY_P}/doc/${PN}/digikam" doc-digikam/en || die
echo "add_subdirectory( en )" > doc-showfoto/CMakeLists.txt || die
mv "${WORKDIR}/${MY_P}/doc/${PN}/showfoto" doc-showfoto/en || die
sed -i -e 's:../digikam/:../../doc-digikam/en/:g' doc-showfoto/en/index.docbook || die
# prepare the translations
mv "${WORKDIR}/${MY_P}/po" po || die
find po -name "*.po" -and -not -name "digikam.po" -exec rm {} +
echo "find_package(Msgfmt REQUIRED)" >> CMakeLists.txt || die
echo "find_package(Gettext REQUIRED)" >> CMakeLists.txt || die
echo "add_subdirectory( po )" >> CMakeLists.txt || die
kde4-base_src_prepare
if use handbook; then
echo "add_subdirectory( doc-digikam )" >> CMakeLists.txt
echo "add_subdirectory( doc-showfoto )" >> CMakeLists.txt
fi
}
src_configure() {
# LQR = only allows to choose between bundled/external
local mycmakeargs=(
-DENABLE_LCMS2=ON
-DFORCED_UNBUNDLE=ON
-DWITH_LQR=ON
-DWITH_LENSFUN=ON
$(cmake-utils_use_enable addressbook KDEPIMLIBSSUPPORT)
-DWITH_MarbleWidget=ON
$(cmake-utils_use_enable gphoto2 GPHOTO2)
$(cmake-utils_use_with gphoto2)
$(cmake-utils_use_enable thumbnails THUMBS_DB)
$(cmake-utils_use_enable mysql INTERNALMYSQL)
$(cmake-utils_use_enable mysql MYSQLSUPPORT)
$(cmake-utils_use_enable debug DEBUG_MESSAGES)
$(cmake-utils_use_enable semantic-desktop BALOOSUPPORT)
)
kde4-base_src_configure
}
src_compile() {
local mytargets="all"
use doc && mytargets+=" doc"
kde4-base_src_compile ${mytargets}
}
src_install() {
kde4-base_src_install
if use doc; then
# install the api documentation
insinto /usr/share/doc/${PF}/
doins -r ${CMAKE_BUILD_DIR}/api/html
fi
}
pkg_postinst() {
kde4-base_pkg_postinst
if use doc; then
einfo "The digikam api documentation has been installed at /usr/share/doc/${PF}/html"
fi
}
^ permalink raw reply [flat|nested] 2+ messages in thread* [gentoo-commits] gentoo-x86 commit in media-gfx/digikam: ChangeLog digikam-4.6.0.ebuild
@ 2014-12-21 21:46 Andreas HAttel (dilfridge)
0 siblings, 0 replies; 2+ messages in thread
From: Andreas HAttel (dilfridge) @ 2014-12-21 21:46 UTC (permalink / raw
To: gentoo-commits
dilfridge 14/12/21 21:46:01
Modified: ChangeLog digikam-4.6.0.ebuild
Log:
Pin a minimum kde-apps/libkface version
(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key EBE6A336BE19039C!)
Revision Changes Path
1.277 media-gfx/digikam/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/ChangeLog?rev=1.277&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/ChangeLog?rev=1.277&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/ChangeLog?r1=1.276&r2=1.277
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v
retrieving revision 1.276
retrieving revision 1.277
diff -u -r1.276 -r1.277
--- ChangeLog 21 Dec 2014 21:41:17 -0000 1.276
+++ ChangeLog 21 Dec 2014 21:46:01 -0000 1.277
@@ -1,6 +1,9 @@
# ChangeLog for media-gfx/digikam
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v 1.276 2014/12/21 21:41:17 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/ChangeLog,v 1.277 2014/12/21 21:46:01 dilfridge Exp $
+
+ 21 Dec 2014; Andreas K. Huettel <dilfridge@gentoo.org> digikam-4.6.0.ebuild:
+ Pin a minimum kde-apps/libkface version
*digikam-4.6.0 (21 Dec 2014)
1.2 media-gfx/digikam/digikam-4.6.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/digikam-4.6.0.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/digikam-4.6.0.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/digikam/digikam-4.6.0.ebuild?r1=1.1&r2=1.2
Index: digikam-4.6.0.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/digikam/digikam-4.6.0.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- digikam-4.6.0.ebuild 21 Dec 2014 21:41:17 -0000 1.1
+++ digikam-4.6.0.ebuild 21 Dec 2014 21:46:01 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/digikam-4.6.0.ebuild,v 1.1 2014/12/21 21:41:17 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/digikam/digikam-4.6.0.ebuild,v 1.2 2014/12/21 21:46:01 dilfridge Exp $
EAPI=5
@@ -45,7 +45,7 @@
media-libs/jasper
media-libs/lcms:2
>=media-libs/lensfun-0.2.6
- || ( kde-apps/libkface:4 >=media-libs/libkface-4.6.0 )
+ || ( >=kde-apps/libkface-14.12.0:4 >=media-libs/libkface-4.6.0 )
>=media-libs/libkgeomap-4.6.0:=
media-libs/liblqr
>=media-libs/libpgf-6.12.27
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2014-12-21 21:46 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-12-21 21:41 [gentoo-commits] gentoo-x86 commit in media-gfx/digikam: ChangeLog digikam-4.6.0.ebuild Andreas HAttel (dilfridge)
-- strict thread matches above, loose matches on Subject: below --
2014-12-21 21:46 Andreas HAttel (dilfridge)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox