[gentoo-commits] gentoo-x86 commit in app-admin/bcfg2: bcfg2-1.2.4-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in app-admin/bcfg2: bcfg2-1.2.4-r1.ebuild ChangeLog

[Michal Gorny (mgorny)]

mgorny      14/12/15 05:15:53

  Modified:             ChangeLog
  Added:                bcfg2-1.2.4-r1.ebuild
  Log:
  Convert to distutils-r1.
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.33                 app-admin/bcfg2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/bcfg2/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/bcfg2/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/bcfg2/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/bcfg2/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	23 Dec 2013 00:35:07 -0000	1.32
+++ ChangeLog	15 Dec 2014 05:15:53 -0000	1.33
@@ -1,6 +1,11 @@
 # ChangeLog for app-admin/bcfg2
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/bcfg2/ChangeLog,v 1.32 2013/12/23 00:35:07 tomwij Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/bcfg2/ChangeLog,v 1.33 2014/12/15 05:15:53 mgorny Exp $
+
+*bcfg2-1.2.4-r1 (15 Dec 2014)
+
+  15 Dec 2014; Michał Górny <mgorny@gentoo.org> +bcfg2-1.2.4-r1.ebuild:
+  Convert to distutils-r1.
 
   23 Dec 2013; Tom Wijsman <TomWij@gentoo.org>
   -files/bcfg2-1.2.2-CVE-2012-3366-Trigger-plugin.patch:



1.1                  app-admin/bcfg2/bcfg2-1.2.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/bcfg2/bcfg2-1.2.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/bcfg2/bcfg2-1.2.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: bcfg2-1.2.4-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/bcfg2/bcfg2-1.2.4-r1.ebuild,v 1.1 2014/12/15 05:15:53 mgorny Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE='ssl'

inherit distutils-r1

DESCRIPTION="Configuration management tool"
HOMEPAGE="http://bcfg2.org"
SRC_URI="ftp://ftp.mcs.anl.gov/pub/bcfg/${P}.tar.gz"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
IUSE="doc cheetah genshi server"

DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
RDEPEND="app-portage/gentoolkit[${PYTHON_USEDEP}]
	cheetah? ( dev-python/cheetah[${PYTHON_USEDEP}] )
	genshi? ( dev-python/genshi[${PYTHON_USEDEP}] )
	server? (
		dev-libs/libgamin[python,${PYTHON_USEDEP}]
		dev-python/lxml[${PYTHON_USEDEP}]
		dev-python/nose[${PYTHON_USEDEP}]
		virtual/fam )"

python_compile_all() {
	if use doc; then
		einfo "Building Bcfg2 documentation"
		sphinx-build doc doc_output || die
	fi
}

python_install() {
	distutils-r1_python_install \
		--record=PY_SERVER_LIBS

	if ! use server; then
		rm -f "${ED%/}"/usr/bin/bcfg2-* || die
		rm -f "${D%/}$(python_get_scriptdir)"/bcfg2-* || die
		rm -rf "${ED%/}"/usr/share/bcfg2 || die
		rm -rf "${ED%/}"/usr/share/man/man8 || die
	else
		newinitd "${FILESDIR}/${PN}-server-1.2.0.rc" bcfg2-server
	fi

	insinto /etc
	doins examples/bcfg2.conf

	if use doc; then
		cd doc_output || die
		docinto html
		dodoc -r [a-z]* _images _static
	fi
}

pkg_postinst () {
	if use server; then
		einfo "If this is a new installation, you probably need to run:"
		einfo "    bcfg2-admin init"
	fi
}