[gentoo-commits] gentoo-x86 commit in dev-qt/qtsql: qtsql-5.4.0.ebuild ChangeLog

["Michael Palimaka (kensington)" <kensington@gentoo.org>]

kensington    14/12/12 14:30:04

  Modified:             ChangeLog
  Added:                qtsql-5.4.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

Revision  Changes    Path
1.21                 dev-qt/qtsql/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtsql/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtsql/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtsql/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-qt/qtsql/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	15 Nov 2014 02:38:04 -0000	1.20
+++ ChangeLog	12 Dec 2014 14:30:04 -0000	1.21
@@ -1,6 +1,11 @@
 # ChangeLog for dev-qt/qtsql
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtsql/ChangeLog,v 1.20 2014/11/15 02:38:04 pesa Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtsql/ChangeLog,v 1.21 2014/12/12 14:30:04 kensington Exp $
+
+*qtsql-5.4.0 (12 Dec 2014)
+
+  12 Dec 2014; Michael Palimaka <kensington@gentoo.org> +qtsql-5.4.0.ebuild:
+  Version bump.
 
 *qtsql-4.8.6-r1 (15 Nov 2014)
 



1.1                  dev-qt/qtsql/qtsql-5.4.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtsql/qtsql-5.4.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qtsql/qtsql-5.4.0.ebuild?rev=1.1&content-type=text/plain

Index: qtsql-5.4.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-qt/qtsql/qtsql-5.4.0.ebuild,v 1.1 2014/12/12 14:30:04 kensington Exp $

EAPI=5

QT5_MODULE="qtbase"

inherit multilib qt5-build

DESCRIPTION="SQL abstraction library for the Qt5 tooolkit"

if [[ ${QT5_BUILD_TYPE} == live ]]; then
	KEYWORDS=""
else
	KEYWORDS="~amd64 ~x86"
fi

IUSE="freetds mysql oci8 odbc postgres +sqlite"

REQUIRED_USE="
	|| ( freetds mysql oci8 odbc postgres sqlite )
"

DEPEND="
	~dev-qt/qtcore-${PV}[debug=]
	freetds? ( dev-db/freetds )
	mysql? ( virtual/mysql:= )
	oci8? ( dev-db/oracle-instantclient-basic )
	odbc? ( || ( dev-db/unixODBC dev-db/libiodbc ) )
	postgres? ( virtual/postgresql:* )
	sqlite? ( dev-db/sqlite:3 )
"
RDEPEND="${DEPEND}"

QT5_TARGET_SUBDIRS=(
	src/sql
	src/plugins/sqldrivers
)

src_configure() {
	local myconf=(
		$(qt_use freetds  sql-tds    plugin)
		$(qt_use mysql    sql-mysql  plugin)
		$(qt_use oci8     sql-oci    plugin)
		$(qt_use odbc     sql-odbc   plugin)
		$(qt_use postgres sql-psql   plugin)
		$(qt_use sqlite   sql-sqlite plugin)
		$(use sqlite && echo -system-sqlite)
	)

	use mysql && myconf+=("-I${EPREFIX}/usr/include/mysql" "-L${EPREFIX}/usr/$(get_libdir)/mysql")
	use oci8 && myconf+=("-I${ORACLE_HOME}/include" "-L${ORACLE_HOME}/$(get_libdir)")
	use odbc && myconf+=("-I${EPREFIX}/usr/include/iodbc")
	use postgres && myconf+=("-I${EPREFIX}/usr/include/postgresql/pgsql")

	qt5-build_src_configure
}