* [gentoo-commits] gentoo-x86 commit in media-sound/pulseaudio: pulseaudio-5.0-r6.ebuild ChangeLog
@ 2014-12-04 19:54 Michal Gorny (mgorny)
0 siblings, 0 replies; 3+ messages in thread
From: Michal Gorny (mgorny) @ 2014-12-04 19:54 UTC (permalink / raw
To: gentoo-commits
mgorny 14/12/04 19:54:19
Modified: ChangeLog
Added: pulseaudio-5.0-r6.ebuild
Log:
QA: Replace unnecessary, blocker-causing alsa-plugins[pulseaudio] dependency with a safe postinst message.
(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)
Revision Changes Path
1.359 media-sound/pulseaudio/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.359&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.359&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?r1=1.358&r2=1.359
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v
retrieving revision 1.358
retrieving revision 1.359
diff -u -r1.358 -r1.359
--- ChangeLog 13 Nov 2014 12:21:33 -0000 1.358
+++ ChangeLog 4 Dec 2014 19:54:19 -0000 1.359
@@ -1,6 +1,12 @@
# ChangeLog for media-sound/pulseaudio
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.358 2014/11/13 12:21:33 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.359 2014/12/04 19:54:19 mgorny Exp $
+
+*pulseaudio-5.0-r6 (04 Dec 2014)
+
+ 04 Dec 2014; Michał Górny <mgorny@gentoo.org> +pulseaudio-5.0-r6.ebuild:
+ QA: Replace unnecessary, blocker-causing alsa-plugins[pulseaudio] dependency
+ with a safe postinst message.
13 Nov 2014; Pacho Ramos <pacho@gentoo.org> -pulseaudio-2.1-r1.ebuild,
-pulseaudio-4.0.ebuild:
1.1 media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild?rev=1.1&content-type=text/plain
Index: pulseaudio-5.0-r6.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild,v 1.1 2014/12/04 19:54:19 mgorny Exp $
EAPI="5"
inherit autotools bash-completion-r1 eutils flag-o-matic linux-info readme.gentoo systemd user versionator udev multilib-minimal
DESCRIPTION="A networked sound server with an advanced plugin system"
HOMEPAGE="http://www.pulseaudio.org/"
SRC_URI="http://freedesktop.org/software/pulseaudio/releases/${P}.tar.xz"
# libpulse-simple and libpulse link to libpulse-core; this is daemon's
# library and can link to gdbm and other GPL-only libraries. In this
# cases, we have a fully GPL-2 package. Leaving the rest of the
# GPL-forcing USE flags for those who use them.
LICENSE="!gdbm? ( LGPL-2.1 ) gdbm? ( GPL-2 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="+alsa +asyncns bluetooth +caps dbus doc equalizer +gdbm +glib gnome
gtk ipv6 jack libsamplerate lirc neon +orc oss qt4 realtime ssl systemd
system-wide tcpd test +udev +webrtc-aec +X xen zeroconf"
# See "*** BLUEZ support not found (requires D-Bus)" in configure.ac
REQUIRED_USE="bluetooth? ( dbus )"
# libpcre needed in some cases, bug #472228
RDEPEND="
|| (
elibc_glibc? ( virtual/libc )
elibc_uclibc? ( virtual/libc )
dev-libs/libpcre
)
>=media-libs/libsndfile-1.0.20[${MULTILIB_USEDEP}]
X? (
>=x11-libs/libX11-1.4.0[${MULTILIB_USEDEP}]
>=x11-libs/libxcb-1.6[${MULTILIB_USEDEP}]
x11-libs/libSM[${MULTILIB_USEDEP}]
x11-libs/libICE[${MULTILIB_USEDEP}]
x11-libs/libXtst[${MULTILIB_USEDEP}]
)
caps? ( >=sys-libs/libcap-2.22-r2[${MULTILIB_USEDEP}] )
libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
alsa? ( >=media-libs/alsa-lib-1.0.19 )
glib? ( >=dev-libs/glib-2.4.0[${MULTILIB_USEDEP}] )
zeroconf? ( >=net-dns/avahi-0.6.12[dbus] )
jack? ( >=media-sound/jack-audio-connection-kit-0.117 )
tcpd? ( sys-apps/tcp-wrappers[${MULTILIB_USEDEP}] )
lirc? ( app-misc/lirc )
dbus? ( >=sys-apps/dbus-1.0.0[${MULTILIB_USEDEP}] )
gtk? ( x11-libs/gtk+:3 )
gnome? ( >=gnome-base/gconf-2.4.0 )
bluetooth? (
net-wireless/bluez:=
>=sys-apps/dbus-1.0.0
media-libs/sbc
)
asyncns? ( net-libs/libasyncns[${MULTILIB_USEDEP}] )
udev? ( >=virtual/udev-143[hwdb(+)] )
realtime? ( sys-auth/rtkit )
equalizer? ( sci-libs/fftw:3.0 )
orc? ( >=dev-lang/orc-0.4.9 )
ssl? ( dev-libs/openssl )
>=media-libs/speex-1.2_rc1
gdbm? ( sys-libs/gdbm )
webrtc-aec? ( media-libs/webrtc-audio-processing )
xen? ( app-emulation/xen-tools )
systemd? ( sys-apps/systemd:0=[${MULTILIB_USEDEP}] )
dev-libs/json-c[${MULTILIB_USEDEP}]
abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20131008-r1
!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)] )
dev-libs/libltdl:0
"
# it's a valid RDEPEND, libltdl.so is used for native abi
DEPEND="${RDEPEND}
sys-devel/m4
doc? ( app-doc/doxygen )
test? ( dev-libs/check )
X? (
x11-proto/xproto[${MULTILIB_USEDEP}]
>=x11-libs/libXtst-1.0.99.2[${MULTILIB_USEDEP}]
)
dev-libs/libatomic_ops
virtual/pkgconfig
system-wide? ( || ( dev-util/unifdef sys-freebsd/freebsd-ubin ) )
dev-util/intltool
>=sys-devel/gettext-0.18.1
"
# alsa-utils dep is for the alsasound init.d script (see bug #155707)
# bluez dep is for the bluetooth init.d script
# PyQt4 dep is for the qpaeq script
RDEPEND="${RDEPEND}
equalizer? ( qt4? ( dev-python/PyQt4[dbus] ) )
system-wide? (
alsa? ( media-sound/alsa-utils )
bluetooth? ( net-wireless/bluez:= )
)
"
pkg_pretend() {
CONFIG_CHECK="~HIGH_RES_TIMERS"
WARNING_HIGH_RES_TIMERS="CONFIG_HIGH_RES_TIMERS:\tis not set (required for enabling timer-based scheduling in pulseaudio)\n"
check_extra_config
if linux_config_exists; then
local snd_hda_prealloc_size=$(linux_chkconfig_string SND_HDA_PREALLOC_SIZE)
if [ -n "${snd_hda_prealloc_size}" ] && [ "${snd_hda_prealloc_size}" -lt 2048 ]; then
ewarn "A preallocated buffer-size of 2048 (kB) or higher is recommended for the HD-audio driver!"
ewarn "CONFIG_SND_HDA_PREALLOC_SIZE=${snd_hda_prealloc_size}"
fi
fi
}
pkg_setup() {
linux-info_pkg_setup
enewgroup audio 18 # Just make sure it exists
if use system-wide; then
enewgroup pulse-access
enewgroup pulse
enewuser pulse -1 -1 /var/run/pulse pulse,audio
fi
}
src_prepare() {
# Skip test that cannot work with sandbox, bug #501846
sed -i -e '/lock-autospawn-test/d' src/Makefile.am || die
# Fix CVE-2014-3970, bug #512516 (from 'master')
epatch "${FILESDIR}/${P}-crash-udp.patch"
# module-switch-on-port-available: Don't switch profiles on uninitialized cards (from 'master')
epatch "${FILESDIR}/${P}-module-switch.patch"
# Fix module-zeroconf-publish crashes, bug #504612 (from 'master')
epatch "${FILESDIR}"/${P}-zeroconf-crash-{1,2,3}.patch
epatch_user
eautoreconf
}
multilib_src_configure() {
local myconf=()
if use gdbm; then
myconf+=( --with-database=gdbm )
#elif use tdb; then
# myconf+=( --with-database=tdb )
else
myconf+=( --with-database=simple )
fi
if use bluetooth; then
if has_version '<net-wireless/bluez-5'; then
myconf+=( --disable-bluez5 --enable-bluez4 )
else
myconf+=( --enable-bluez5 --disable-bluez4 )
fi
else
myconf+=( --disable-bluez5 --disable-bluez4 )
fi
myconf+=(
--enable-largefile
$(use_enable glib glib2)
--disable-solaris
$(use_enable asyncns)
$(use_enable oss oss-output)
$(use_enable alsa)
$(use_enable lirc)
$(use_enable neon neon-opt)
$(use_enable tcpd tcpwrap)
$(use_enable jack)
$(use_enable zeroconf avahi)
$(use_enable dbus)
$(use_enable gnome gconf)
$(use_enable gtk gtk3)
$(use_enable libsamplerate samplerate)
$(use_enable orc)
$(use_enable X x11)
$(use_enable test default-build-tests)
$(use_enable udev)
$(use_enable systemd)
$(use_enable systemd systemd-journal)
$(use_enable ipv6)
$(use_enable ssl openssl)
$(use_enable webrtc-aec)
$(use_enable xen)
$(use_with caps)
$(use_with equalizer fftw)
--disable-adrian-aec
--disable-esound
--localstatedir="${EPREFIX}"/var
--with-udev-rules-dir="${EPREFIX}/$(get_udevdir)"/rules.d
)
if ! multilib_is_native_abi; then
# disable all the modules and stuff
myconf+=(
--disable-oss-output
--disable-alsa
--disable-lirc
--disable-jack
--disable-avahi
--disable-gconf
--disable-gtk3
--disable-samplerate
--disable-bluez4
--disable-bluez5
--disable-udev
--disable-systemd
--disable-openssl
--disable-orc
--disable-webrtc-aec
--disable-xen
--without-fftw
# tests involve random modules, so just do them for the native
--disable-default-build-tests
# hack around unnecessary checks
# (results don't matter, we're not building anything using it)
ac_cv_lib_ltdl_lt_dladvise_init=yes
--with-database=simple
LIBSPEEX_CFLAGS=' '
LIBSPEEX_LIBS=' '
)
fi
ECONF_SOURCE=${S} \
econf "${myconf[@]}"
}
multilib_src_compile() {
if multilib_is_native_abi; then
emake
else
local targets=( libpulse.la libpulse-simple.la )
use glib && targets+=( libpulse-mainloop-glib.la )
emake -C src libpulse{,dsp,-simple,-mainloop-glib}.la
fi
}
src_compile() {
multilib-minimal_src_compile
if use doc; then
pushd doxygen
doxygen doxygen.conf
popd
fi
}
multilib_src_test() {
# We avoid running the toplevel check target because that will run
# po/'s tests too, and they are broken. Officially, it should work
# with intltool 0.41, but that doesn't look like a stable release.
if multilib_is_native_abi; then
emake -C src check
fi
}
multilib_src_install() {
if multilib_is_native_abi; then
emake -j1 DESTDIR="${D}" bashcompletiondir="$(get_bashcompdir)" install
else
local targets=( libpulse.la libpulse-simple.la )
use glib && targets+=( libpulse-mainloop-glib.la )
emake DESTDIR="${D}" install-pkgconfigDATA
emake DESTDIR="${D}" -C src \
install-libLTLIBRARIES \
install-padsplibLTLIBRARIES \
lib_LTLIBRARIES="${targets[*]}" \
install-pulseincludeHEADERS
fi
}
multilib_src_install_all() {
# Drop the script entirely if X is disabled
use X || rm "${ED}"/usr/bin/start-pulseaudio-x11
if use system-wide; then
newconfd "${FILESDIR}/pulseaudio.conf.d" pulseaudio
use_define() {
local define=${2:-$(echo $1 | tr '[:lower:]' '[:upper:]')}
use "$1" && echo "-D$define" || echo "-U$define"
}
unifdef $(use_define zeroconf AVAHI) \
$(use_define alsa) \
$(use_define bluetooth) \
$(use_define udev) \
"${FILESDIR}/pulseaudio.init.d-5" \
> "${T}/pulseaudio"
doinitd "${T}/pulseaudio"
systemd_dounit "${FILESDIR}/${PN}.service"
fi
use zeroconf && sed -i -e '/module-zeroconf-publish/s:^#::' "${ED}/etc/pulse/default.pa"
dodoc NEWS README todo
if use doc; then
pushd doxygen/html
dohtml *
popd
fi
# Create the state directory
use prefix || diropts -o pulse -g pulse -m0755
# We need /var/run/pulse, bug #442852
use system-wide && systemd_newtmpfilesd "${FILESDIR}/${PN}.tmpfiles" "${PN}.conf"
# Prevent warnings when system-wide is not used, bug #447694
use system-wide || rm "${ED}"/etc/dbus-1/system.d/pulseaudio-system.conf
prune_libtool_files --all
}
pkg_postinst() {
if use system-wide; then
elog "PulseAudio in Gentoo can use a system-wide pulseaudio daemon."
elog "This support is enabled by starting the pulseaudio init.d ."
elog "To be able to access that you need to be in the group pulse-access."
elog "If you choose to use this feature, please make sure that you"
elog "really want to run PulseAudio this way:"
elog " http://pulseaudio.org/wiki/WhatIsWrongWithSystemMode"
elog "For more information about system-wide support, please refer to:"
elog " http://pulseaudio.org/wiki/SystemWideInstance"
if use gnome ; then
elog
elog "By enabling gnome USE flag, you enabled gconf support. Please note"
elog "that you might need to remove the gnome USE flag or disable the"
elog "gconf module on /etc/pulse/system.pa to be able to use PulseAudio"
elog "with a system-wide instance."
fi
fi
if use equalizer && ! use qt4; then
elog "You've enabled the 'equalizer' USE-flag but not the 'qt4' USE-flag."
elog "This will build the equalizer module, but the 'qpaeq' tool"
elog "which is required to set equalizer levels will not work."
fi
if use alsa && ! has_version 'media-plugins/alsa-plugins[pulseaudio]'; then
elog
elog "You may want to install media-plugins/alsa-plugins[pulseaudio]"
elog "if you want ALSA-only apps to automatically use PulseAudio."
fi
}
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-sound/pulseaudio: pulseaudio-5.0-r6.ebuild ChangeLog
@ 2014-12-05 10:30 Pacho Ramos (pacho)
0 siblings, 0 replies; 3+ messages in thread
From: Pacho Ramos (pacho) @ 2014-12-05 10:30 UTC (permalink / raw
To: gentoo-commits
pacho 14/12/05 10:30:55
Modified: pulseaudio-5.0-r6.ebuild ChangeLog
Log:
Increase severity of the messages as people wanting to run pulseaudio[alsa] will need alsa-plugins most time if they don't want to see the many alsa-only apps to bypass pulseaudio
(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.2 media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild?r1=1.1&r2=1.2
Index: pulseaudio-5.0-r6.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- pulseaudio-5.0-r6.ebuild 4 Dec 2014 19:54:19 -0000 1.1
+++ pulseaudio-5.0-r6.ebuild 5 Dec 2014 10:30:55 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild,v 1.1 2014/12/04 19:54:19 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild,v 1.2 2014/12/05 10:30:55 pacho Exp $
EAPI="5"
inherit autotools bash-completion-r1 eutils flag-o-matic linux-info readme.gentoo systemd user versionator udev multilib-minimal
@@ -352,8 +352,8 @@
fi
if use alsa && ! has_version 'media-plugins/alsa-plugins[pulseaudio]'; then
- elog
- elog "You may want to install media-plugins/alsa-plugins[pulseaudio]"
- elog "if you want ALSA-only apps to automatically use PulseAudio."
+ ewarn
+ ewarn "You will need to install media-plugins/alsa-plugins[pulseaudio]"
+ ewarn "if you want ALSA-only apps to automatically use PulseAudio."
fi
}
1.360 media-sound/pulseaudio/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.360&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.360&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?r1=1.359&r2=1.360
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v
retrieving revision 1.359
retrieving revision 1.360
diff -u -r1.359 -r1.360
--- ChangeLog 4 Dec 2014 19:54:19 -0000 1.359
+++ ChangeLog 5 Dec 2014 10:30:55 -0000 1.360
@@ -1,6 +1,11 @@
# ChangeLog for media-sound/pulseaudio
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.359 2014/12/04 19:54:19 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.360 2014/12/05 10:30:55 pacho Exp $
+
+ 05 Dec 2014; Pacho Ramos <pacho@gentoo.org> pulseaudio-5.0-r6.ebuild:
+ Increase severity of the messages as people wanting to run pulseaudio[alsa]
+ will need alsa-plugins most time if they don't want to see the many alsa-only
+ apps to bypass pulseaudio
*pulseaudio-5.0-r6 (04 Dec 2014)
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-sound/pulseaudio: pulseaudio-5.0-r6.ebuild ChangeLog
@ 2014-12-06 12:01 Pacho Ramos (pacho)
0 siblings, 0 replies; 3+ messages in thread
From: Pacho Ramos (pacho) @ 2014-12-06 12:01 UTC (permalink / raw
To: gentoo-commits
pacho 14/12/06 12:01:58
Modified: pulseaudio-5.0-r6.ebuild ChangeLog
Log:
Add a reference for the future
(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.5 media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild?r1=1.4&r2=1.5
Index: pulseaudio-5.0-r6.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- pulseaudio-5.0-r6.ebuild 5 Dec 2014 23:31:04 -0000 1.4
+++ pulseaudio-5.0-r6.ebuild 6 Dec 2014 12:01:58 -0000 1.5
@@ -1,6 +1,6 @@
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild,v 1.4 2014/12/05 23:31:04 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-5.0-r6.ebuild,v 1.5 2014/12/06 12:01:58 pacho Exp $
EAPI="5"
inherit autotools bash-completion-r1 eutils flag-o-matic linux-info readme.gentoo systemd user versionator udev multilib-minimal
@@ -18,6 +18,7 @@
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+# +alsa-plugin as discussed in bug #519530
IUSE="+alsa +alsa-plugin +asyncns bluetooth +caps dbus doc equalizer +gdbm +glib
gnome gtk ipv6 jack libsamplerate lirc neon +orc oss qt4 realtime ssl systemd
system-wide tcpd test +udev +webrtc-aec +X xen zeroconf"
1.363 media-sound/pulseaudio/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.363&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.363&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/pulseaudio/ChangeLog?r1=1.362&r2=1.363
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v
retrieving revision 1.362
retrieving revision 1.363
diff -u -r1.362 -r1.363
--- ChangeLog 5 Dec 2014 23:31:04 -0000 1.362
+++ ChangeLog 6 Dec 2014 12:01:58 -0000 1.363
@@ -1,6 +1,9 @@
# ChangeLog for media-sound/pulseaudio
# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.362 2014/12/05 23:31:04 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.363 2014/12/06 12:01:58 pacho Exp $
+
+ 06 Dec 2014; Pacho Ramos <pacho@gentoo.org> pulseaudio-5.0-r6.ebuild:
+ Add a reference for the future
05 Dec 2014; Ulrich Müller <ulm@gentoo.org> pulseaudio-5.0-r6.ebuild:
[QA] Fix PDEPEND, bug 519530 comment 15.
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2014-12-06 12:02 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2014-12-05 10:30 [gentoo-commits] gentoo-x86 commit in media-sound/pulseaudio: pulseaudio-5.0-r6.ebuild ChangeLog Pacho Ramos (pacho)
-- strict thread matches above, loose matches on Subject: below --
2014-12-06 12:01 Pacho Ramos (pacho)
2014-12-04 19:54 Michal Gorny (mgorny)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox