[gentoo-commits] gentoo-x86 commit in www-client/opera: opera-26.0.1656.32.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in www-client/opera: opera-26.0.1656.32.ebuild ChangeLog

[Jeroen Roovers (jer)]

jer         14/12/03 15:31:34

  Modified:             ChangeLog
  Added:                opera-26.0.1656.32.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.821                www-client/opera/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/opera/ChangeLog?rev=1.821&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/opera/ChangeLog?rev=1.821&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/opera/ChangeLog?r1=1.820&r2=1.821

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/opera/ChangeLog,v
retrieving revision 1.820
retrieving revision 1.821
diff -u -r1.820 -r1.821
--- ChangeLog	23 Apr 2014 14:11:59 -0000	1.820
+++ ChangeLog	3 Dec 2014 15:31:34 -0000	1.821
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/opera
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/opera/ChangeLog,v 1.820 2014/04/23 14:11:59 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera/ChangeLog,v 1.821 2014/12/03 15:31:34 jer Exp $
+
+*opera-26.0.1656.32 (03 Dec 2014)
+
+  03 Dec 2014; Jeroen Roovers <jer@gentoo.org> +opera-26.0.1656.32.ebuild:
+  Version bump.
 
   23 Apr 2014; Jeroen Roovers <jer@gentoo.org> -opera-12.16_p1860.ebuild,
   opera-12.16_p1860-r1.ebuild:



1.1                  www-client/opera/opera-26.0.1656.32.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/opera/opera-26.0.1656.32.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/opera/opera-26.0.1656.32.ebuild?rev=1.1&content-type=text/plain

Index: opera-26.0.1656.32.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/opera/opera-26.0.1656.32.ebuild,v 1.1 2014/12/03 15:31:34 jer Exp $

EAPI=5
CHROMIUM_LANGS="
	af az be bg bn ca cs da de el en_GB en_US es_419 es fi fr_CA fr fy gd hi hr
	hu id it ja kk ko lt lv me mk ms nb nl nn pa pl pt_BR pt_PT ro ru sk sr sv
	sw ta te th tl tr uk uz vi zh_CN zh_TW zu
"
inherit chromium multilib unpacker

DESCRIPTION="A fast and secure web browser"
HOMEPAGE="http://www.opera.com/"
LICENSE="OPERA-2014"
SLOT="0"
SRC_URI_BASE="http://get.geo.opera.com/pub/"
SRC_URI="
	amd64? ( "${SRC_URI_BASE}${PN}/desktop/${PV}/linux/${PN}-stable_${PV}_amd64.deb" )
"
KEYWORDS="~amd64"

RDEPEND="
	dev-libs/expat
	dev-libs/glib:2
	dev-libs/nspr
	dev-libs/nss
	>=dev-libs/openssl-1.0.1:0
	gnome-base/gconf:2
	media-libs/alsa-lib
	media-libs/fontconfig
	media-libs/freetype
	net-misc/curl
	net-print/cups
	sys-apps/dbus
	sys-libs/libcap
	virtual/libudev
	x11-libs/cairo
	x11-libs/gdk-pixbuf
	x11-libs/gtk+:2
	x11-libs/libX11
	x11-libs/libXScrnSaver
	x11-libs/libXcomposite
	x11-libs/libXcursor
	x11-libs/libXdamage
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXi
	x11-libs/libXrandr
	x11-libs/libXrender
	x11-libs/libXtst
	x11-libs/pango[X]
"

QA_PREBUILT="*"
S=${WORKDIR}
OPERA_HOME="usr/$(get_libdir)/${PN}"

src_unpack() {
	unpack_deb ${A}
}

src_prepare() {
	mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
	rm -r usr/lib || die

	rm usr/bin/${PN} || die

	rm usr/share/doc/${PN}-stable/copyright || die
	mv usr/share/doc/${PN}-stable usr/share/doc/${PF} || die

	pushd "${OPERA_HOME}/localization" > /dev/null || die
	chromium_remove_language_paks
	popd > /dev/null || die

	sed -i \
		-e 's|^TargetEnvironment|X-&|g' \
		usr/share/applications/${PN}.desktop || die
}

src_install() {
	mv * "${D}" || die
	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
	dodir /usr/$(get_libdir)/${PN}/lib
	dosym /usr/$(get_libdir)/libudev.so /usr/$(get_libdir)/${PN}/lib/libudev.so.0
	fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
}