[gentoo-commits] gentoo-x86 commit in sci-electronics/eagle: ChangeLog eagle-7.2.0.ebuild

["Jason Zaman (perfinion)" <perfinion@gentoo.org>]

perfinion    14/12/01 19:49:33

  Modified:             ChangeLog
  Added:                eagle-7.2.0.ebuild
  Log:
  version bump to 7.2.0
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 0x7EF137EC935B0EAF)

Revision  Changes    Path
1.63                 sci-electronics/eagle/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/eagle/ChangeLog?rev=1.63&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/eagle/ChangeLog?rev=1.63&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/eagle/ChangeLog?r1=1.62&r2=1.63

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-electronics/eagle/ChangeLog,v
retrieving revision 1.62
retrieving revision 1.63
diff -u -r1.62 -r1.63
--- ChangeLog	15 Oct 2014 21:05:09 -0000	1.62
+++ ChangeLog	1 Dec 2014 19:49:33 -0000	1.63
@@ -1,6 +1,11 @@
 # ChangeLog for sci-electronics/eagle
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-electronics/eagle/ChangeLog,v 1.62 2014/10/15 21:05:09 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-electronics/eagle/ChangeLog,v 1.63 2014/12/01 19:49:33 perfinion Exp $
+
+*eagle-7.2.0 (01 Dec 2014)
+
+  01 Dec 2014; Jason Zaman <perfinon@gentoo.org> +eagle-7.2.0.ebuild:
+  version bump to 7.2.0
 
   15 Oct 2014; Pacho Ramos <pacho@gentoo.org> eagle-4.16_p2-r2.ebuild,
   eagle-5.11.0.ebuild, eagle-5.12.0.ebuild, eagle-6.6.0.ebuild,



1.1                  sci-electronics/eagle/eagle-7.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/eagle/eagle-7.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/eagle/eagle-7.2.0.ebuild?rev=1.1&content-type=text/plain

Index: eagle-7.2.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-electronics/eagle/eagle-7.2.0.ebuild,v 1.1 2014/12/01 19:49:33 perfinion Exp $

EAPI="5"

inherit eutils

DESCRIPTION="CadSoft EAGLE schematic and printed circuit board (PCB) layout editor"
HOMEPAGE="http://www.cadsoft.de"
SRC_URI="ftp://ftp.cadsoft.de/${PN}/program/${PV%\.[0-9]}/${PN}-lin-${PV}.run"

LICENSE="cadsoft"
SLOT="0"
KEYWORDS="~amd64 ~x86 -*"
IUSE="doc linguas_de linguas_zh"

QA_PREBUILT="opt/eagle/bin/eagle"

RDEPEND="
	sys-libs/glibc
	|| (
		(
			|| ( virtual/jpeg:62[abi_x86_32(-)]  media-libs/jpeg:62[abi_x86_32(-)] )
			>=media-libs/libpng-1.2.51:1.2[abi_x86_32(-)]
			>=dev-libs/openssl-0.9.8z_p1-r2:0.9.8[abi_x86_32(-)]
			>=sys-libs/zlib-1.2.8-r1[abi_x86_32(-)]
			>=media-libs/freetype-2.5.0.1[abi_x86_32(-)]
			>=media-libs/fontconfig-2.10.92[abi_x86_32(-)]
			x11-libs/libXext[abi_x86_32(-)]
			x11-libs/libX11[abi_x86_32(-)]
			>=x11-libs/libXrender-0.9.8[abi_x86_32(-)]
			>=x11-libs/libXrandr-1.4.2[abi_x86_32(-)]
			>=x11-libs/libXcursor-1.1.14[abi_x86_32(-)]
			>=x11-libs/libXi-1.7.2[abi_x86_32(-)]

		)
		amd64? (
			app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
			app-emulation/emul-linux-x86-xlibs[-abi_x86_32(-)]
		)
	)
"

# Append ${PV} since that's what upstream installs to
case "${LINGUAS}" in
	*de*)
		MY_LANG="de";;
	*)
		MY_LANG="en";;
esac

src_unpack() {
	# Extract the built-in .tar.bz2 file starting at __DATA__
	sed  -e '1,/^__DATA__$/d' "${DISTDIR}/${A}" | tar xj || die "unpacking failed"
}

src_install() {
	local installdir="/opt/eagle"

	# Set MY_LANG for this function only since UPDATE_zh and README_zh
	# don't exist
	[[ ${LINGUAS} == *zh* ]] && MY_INST_LANG="zh" || MY_INST_LANG="${MY_LANG}"

	insinto $installdir
	doins -r .

	fperms 0755 ${installdir}/bin/eagle

	# Install wrapper (suppressing leading tabs)
	# see bug #188368 or http://www.cadsoftusa.com/training/faq/#3
	exeinto /opt/bin
	newexe "${FILESDIR}/eagle_wrapper_script" eagle
	# Finally, append the path of the eagle binary respecting $installdir and any
	# arguments passed to the script (thanks Denilson)
	echo "${installdir}/bin/eagle" '"$@"' >> "${D}/opt/bin/eagle"

	# Install the documentation
	cd doc
	dodoc README_${MY_LANG} UPDATE_${MY_LANG} library_${MY_LANG}.txt
	doman eagle.1

	# Install extra documentation if requested
	if use doc; then
		dodoc {connect-device-split-symbol-${MY_INST_LANG},elektro-tutorial,manual_${MY_INST_LANG},tutorial_${MY_INST_LANG},layer-setup_designrules}.pdf
	fi
	# Remove docs left in $installdir
	rm -rf "${D}${installdir}/doc"
	cd "${S}"

	echo -e "ROOTPATH=${installdir}/bin\nPRELINK_PATH_MASK=${installdir}" > "${S}/90eagle-${PV}"
	doenvd "${S}/90eagle-${PV}"

	# Create desktop entry
	newicon bin/${PN}icon50.png ${PF}-icon50.png
	make_desktop_entry "${ROOT}/opt/bin/eagle" "CadSoft EAGLE Layout Editor" ${PF}-icon50 "Graphics;Electronics"
}

pkg_postinst() {
	elog "Run \`env-update && source /etc/profile\` from within \${ROOT}"
	elog "now to set up the correct paths."
	elog "You must first run eagle as root to invoke product registration."
	echo
	ewarn "Due to some necessary changes in the data structure, once you edit"
	ewarn "a file with version 7.x you will no longer be able to edit it"
	ewarn "with versions prior to 7.0!"
	ewarn
	ewarn "Please read /usr/share/doc/${PF}/UPDATE_${MY_LANG} if you are upgrading from 6.x/5.x/4.x."
}