public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
From: "Hans de Graaff (graaff)" <graaff@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] gentoo-x86 commit in dev-ruby/actionpack: ChangeLog actionpack-3.2.21.ebuild actionpack-4.1.8.ebuild actionpack-4.0.12.ebuild
Date: Mon, 17 Nov 2014 20:19:20 +0000 (UTC)	[thread overview]
Message-ID: <20141117201920.B4CC3A54B@oystercatcher.gentoo.org> (raw)

graaff      14/11/17 20:19:20

  Modified:             ChangeLog
  Added:                actionpack-3.2.21.ebuild actionpack-4.1.8.ebuild
                        actionpack-4.0.12.ebuild
  Log:
  Version bump for security bug 529635.
  
  (Portage version: 2.2.8-r2/cvs/Linux x86_64, signed Manifest commit with key 0x8883FA56A308A8D7!)

Revision  Changes    Path
1.295                dev-ruby/actionpack/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/actionpack/ChangeLog?rev=1.295&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/actionpack/ChangeLog?rev=1.295&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/actionpack/ChangeLog?r1=1.294&r2=1.295

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ruby/actionpack/ChangeLog,v
retrieving revision 1.294
retrieving revision 1.295
diff -u -r1.294 -r1.295
--- ChangeLog	7 Nov 2014 10:14:40 -0000	1.294
+++ ChangeLog	17 Nov 2014 20:19:20 -0000	1.295
@@ -1,6 +1,14 @@
 # ChangeLog for dev-ruby/actionpack
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/actionpack/ChangeLog,v 1.294 2014/11/07 10:14:40 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/actionpack/ChangeLog,v 1.295 2014/11/17 20:19:20 graaff Exp $
+
+*actionpack-4.1.8 (17 Nov 2014)
+*actionpack-4.0.12 (17 Nov 2014)
+*actionpack-3.2.21 (17 Nov 2014)
+
+  17 Nov 2014; Hans de Graaff <graaff@gentoo.org> +actionpack-3.2.21.ebuild,
+  +actionpack-4.0.12.ebuild, +actionpack-4.1.8.ebuild:
+  Version bump for security bug 529635.
 
   07 Nov 2014; Hans de Graaff <graaff@gentoo.org> -actionpack-3.2.19.ebuild,
   -actionpack-4.0.9.ebuild, -actionpack-4.0.10.ebuild,



1.1                  dev-ruby/actionpack/actionpack-3.2.21.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/actionpack/actionpack-3.2.21.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/actionpack/actionpack-3.2.21.ebuild?rev=1.1&content-type=text/plain

Index: actionpack-3.2.21.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/actionpack/actionpack-3.2.21.ebuild,v 1.1 2014/11/17 20:19:20 graaff Exp $

EAPI=5

USE_RUBY="ruby19 ruby20"

# The default test task tries to test activerecord with SQLite as well.
RUBY_FAKEGEM_TASK_TEST="test_action_pack"

RUBY_FAKEGEM_TASK_DOC=""
RUBY_FAKEGEM_DOCDIR="doc"
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"

RUBY_FAKEGEM_GEMSPEC="actionpack.gemspec"

inherit ruby-fakegem versionator

DESCRIPTION="Eases web-request routing, handling, and response"
HOMEPAGE="https://github.com/rails/rails"
SRC_URI="http://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"

LICENSE="MIT"
SLOT="$(get_version_component_range 1-2)"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE=""

RUBY_S="rails-${PV}/${PN}"

ruby_add_rdepend "
	~dev-ruby/activemodel-${PV}
	~dev-ruby/activesupport-${PV}
	>=dev-ruby/rack-cache-1.2
	>=dev-ruby/builder-3.0.0:3
	>=dev-ruby/rack-1.4.5:1.4
	>=dev-ruby/rack-test-0.6.1:0.6
	>=dev-ruby/journey-1.0.4:1.0
	>=dev-ruby/sprockets-2.2.1:2.2
	>=dev-ruby/erubis-2.7.0"

ruby_add_bdepend "
	test? (
		dev-ruby/mocha:0.13
		dev-ruby/bundler
		~dev-ruby/activerecord-${PV}
		~dev-ruby/actionmailer-${PV}
		>=dev-ruby/tzinfo-0.3.29:0
		>=dev-ruby/uglifier-1.0.3
	)"

all_ruby_prepare() {
	# Remove items from the common Gemfile that we don't need for this
	# test run. This also requires handling some gemspecs.
	sed -i -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|jquery-rails\|'mysql'\|journey\|ruby-prof\|benchmark-ips\|nokogiri\)/d" ../Gemfile || die

	sed -i -e '/rack-ssl/d' -e 's/~> 3.4/>= 3.4/' ../railties/railties.gemspec || die
	sed -i -e '/mail/d' ../actionmailer/actionmailer.gemspec || die

	sed -i -e '/bcrypt/ s/3.0.0/3.0/' ../Gemfile || die

	# Avoid fragile tests depending on hash ordering
	sed -i -e '/cookie_3=chocolate/ s:^:#:' test/controller/integration_test.rb || die
	sed -i -e '/test_to_s/,/end/ s:^:#:' test/template/html-scanner/tag_node_test.rb || die
	sed -i -e '/"name":"david"/ s:^:#:' test/controller/mime_responds_test.rb || die
	sed -i -e '/test_option_html_attributes_with_multiple_element_hash/, / end/ s:^:#:' test/template/form_options_helper_test.rb || die
	sed -i -e '/test_option_html_attributes_with_multiple_hashes/, / end/ s:^:#:' test/template/form_options_helper_test.rb || die

	# Avoid fragile test that gets more output than it expects.
	sed -i -e '/test_locals_option_to_assert_template_is_not_supported/,/end/ s:^:#:'  test/controller/render_test.rb || die

	# Avoid test broken by security updates in i18n.
	sed -i -e '/test_number_to_i18n_currency/,/end/ s:^:#:' test/template/number_helper_i18n_test.rb || die

	# Avoid test that chokes on bad UTF-8.
	sed -i -e '/test_handles_urls_with_bad_encoding/askip "gentoo"' test/dispatch/static_test.rb || die
}



1.1                  dev-ruby/actionpack/actionpack-4.1.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/actionpack/actionpack-4.1.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/actionpack/actionpack-4.1.8.ebuild?rev=1.1&content-type=text/plain

Index: actionpack-4.1.8.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/actionpack/actionpack-4.1.8.ebuild,v 1.1 2014/11/17 20:19:20 graaff Exp $

EAPI=5

USE_RUBY="ruby19 ruby20 ruby21"

RUBY_FAKEGEM_TASK_DOC=""
RUBY_FAKEGEM_DOCDIR="doc"
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"

RUBY_FAKEGEM_GEMSPEC="actionpack.gemspec"

inherit ruby-fakegem versionator

DESCRIPTION="Eases web-request routing, handling, and response"
HOMEPAGE="http://rubyforge.org/projects/actionpack/"
SRC_URI="http://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"

LICENSE="MIT"
SLOT="$(get_version_component_range 1-2)"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64"
IUSE=""

RUBY_S="rails-${PV}/${PN}"

ruby_add_rdepend "
	~dev-ruby/activesupport-${PV}
	~dev-ruby/actionview-${PV}
	>=dev-ruby/rack-1.5.2:1.5
	>=dev-ruby/rack-test-0.6.2:0.6"

ruby_add_bdepend "
	test? (
		dev-ruby/mocha:0.14
		dev-ruby/bundler
		~dev-ruby/activemodel-${PV}
		>=dev-ruby/rack-cache-1.2:1.2
	)"

all_ruby_prepare() {
	# Remove items from the common Gemfile that we don't need for this
	# test run. This also requires handling some gemspecs.
	sed -i -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|jquery-rails\|'mysql'\|journey\|ruby-prof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|debugger\|sprockets-rails\|redcarpet\|bcrypt\|uglifier\|minitest\)/ s:^:#:" ../Gemfile || die
}



1.1                  dev-ruby/actionpack/actionpack-4.0.12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/actionpack/actionpack-4.0.12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/actionpack/actionpack-4.0.12.ebuild?rev=1.1&content-type=text/plain

Index: actionpack-4.0.12.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/actionpack/actionpack-4.0.12.ebuild,v 1.1 2014/11/17 20:19:20 graaff Exp $

EAPI=5

USE_RUBY="ruby19 ruby20 ruby21"

# The default test task tries to test activerecord with SQLite as well.
RUBY_FAKEGEM_TASK_TEST="test_action_pack"

RUBY_FAKEGEM_TASK_DOC=""
RUBY_FAKEGEM_DOCDIR="doc"
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.rdoc"

RUBY_FAKEGEM_GEMSPEC="actionpack.gemspec"

inherit ruby-fakegem versionator

DESCRIPTION="Eases web-request routing, handling, and response"
HOMEPAGE="http://rubyforge.org/projects/actionpack/"
SRC_URI="http://github.com/rails/rails/archive/v${PV}.tar.gz -> rails-${PV}.tgz"

LICENSE="MIT"
SLOT="$(get_version_component_range 1-2)"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
IUSE=""

RUBY_S="rails-${PV}/${PN}"

ruby_add_rdepend "
	~dev-ruby/activesupport-${PV}
	>=dev-ruby/builder-3.1.0:3.1
	>=dev-ruby/rack-1.5.2:1.5
	>=dev-ruby/rack-test-0.6.2:0.6
	>=dev-ruby/erubis-2.7.0"

ruby_add_bdepend "
	test? (
		dev-ruby/mocha:0.13
		dev-ruby/bundler
		~dev-ruby/activemodel-${PV}
		~dev-ruby/activerecord-${PV}
		~dev-ruby/actionmailer-${PV}
		dev-ruby/sprockets-rails:2.0
		>=dev-ruby/tzinfo-0.3.37:0
		>=dev-ruby/uglifier-1.0.3
	)"

all_ruby_prepare() {
	# Remove items from the common Gemfile that we don't need for this
	# test run. This also requires handling some gemspecs.
	sed -i -e "/\(system_timer\|sdoc\|w3c_validators\|pg\|jquery-rails\|'mysql'\|journey\|ruby-prof\|benchmark-ips\|kindlerb\|turbolinks\|coffee-rails\|debugger\|sprockets-rails\|redcarpet\)/d" ../Gemfile || die

	sed -i -e '/rack-ssl/d' -e 's/~> 3.4/>= 3.4/' ../railties/railties.gemspec || die
	sed -i -e '/mail/d' ../actionmailer/actionmailer.gemspec || die

	sed -i -e '/bcrypt/ s/3.0.0/3.0/' ../Gemfile || die

	# Add back json in the Gemfile because we dropped some dependencies
	# earlier that implicitly required it.
	sed -i -e '$agem "json"' ../Gemfile || die

	# Avoid fragile test that gets more output than it expects.
	sed -i -e '/test_locals_option_to_assert_template_is_not_supported/,/end/ s:^:#:'  test/controller/render_test.rb || die
}





                 reply	other threads:[~2014-11-17 20:19 UTC|newest]

Thread overview: [no followups] expand[flat|nested]  mbox.gz  Atom feed

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=20141117201920.B4CC3A54B@oystercatcher.gentoo.org \
    --to=graaff@gentoo.org \
    --cc=gentoo-commits@lists.gentoo.org \
    --cc=gentoo-dev@lists.gentoo.org \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body. 
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox